TweetFollow Us on Twitter

Introduction to AppleScripting Microsoft Entourage

Volume Number: 23 (2007)
Issue Number: 05
Column Tag: Scripting

AppleScript Essentials

Introduction to AppleScripting Microsoft Entourage

by Ben Waldie

For some time now, we have been discussing scripting the Microsoft Office applications, partially in preparation for the forthcoming release of Office 2008, in which Microsoft has announced that Visual Basic macros will no longer be supported. So far, we have explored the AppleScript support in Microsoft Word, Excel, and PowerPoint, three applications that currently (in Office 2004) include Visual Basic macro support. This month, we are going to discuss the fourth major Office application, Entourage, a popular email and project management client.

Unlike the other Office applications, Entourage does not include Visual Basic macro support. So, when Office 2008 is released, there won't be any macros requiring conversion. However, Entourage does possess fairly comprehensive AppleScript support. Using AppleScript, it is possible to manipulate various types of elements in Entourage, including messages, contacts, events, tasks, notes, and more. In this month's column, we will explore ways of manipulating some of these elements. Let's get started.

Working with Messages

Probably the primary elements with which you will want to interact are messages. Using AppleScript, it is possible to create messages, read messages, send messages, move messages from one folder to another, and more.

In Entourage, there are two primary types of messages, incoming and outgoing. While each of these types possesses its own set of properties, both types inherit a number of common properties from the more generic message class.

Creating an Outgoing Message

To create a new outgoing message, use the make command, followed by the class outgoing message, and optionally, properties to be assigned to the message. For example:

set theSubject to "Some Subject"
set theBody to "Some Body"
tell application "Microsoft Entourage"
   make new outgoing message with properties 
{subject:theSubject, content:theBody}
end tell
--> outgoing message id 11285 of application "Microsoft Entourage"

Take note that, when creating a new outgoing message, it will not automatically be visible in Entourage's interface. Regardless, it is created. To make a newly created outgoing message visible in Entourage's interface, the message must be opened. Fortunately, the make command will return as its result a reference to the newly created message. This reference may be placed into a variable, which can then be opened using the open command, as demonstrated below.

set theSubject to "Some Subject"
set theBody to "Some Body"
tell application "Microsoft Entourage"
   set theMessage to make new outgoing message with properties
{subject:theSubject, content:theBody}
   open theMessage
end tell

Adding Recipients to a Message

In the examples that we have discussed above, we have specified certain properties for the outgoing message, which are assigned when the message is created. Specifically, we have specified a subject and a body for the message. However, an outgoing message cannot be sent without first assigning it recipients.

When assigning recipients to a message, each recipient must consist of two bits of information. The first bit of information is the address, and the second is the type of recipient (to, cc, bcc). The address of a recipient is broken down even further, into two more parts - an email address and a display name (i.e. first and last name of the recipient).

To accommodate this, Entourage's AppleScript support includes a recipient class, which possesses an address property and a recipient type property. The value of a recipient's address property translates to the address class in Entourage, which has a display name property and an address property of its own. Put together in AppleScript code, this all translates to the following for each recipient in the list of recipients:

{address:{display name:"RecipientName", 
address:"RecipientEmailAddress"}, 
recipient type:to recipient}

Now, let's put this together to assign recipients as a message is created. The following example code will create an outgoing message in Entourage, addressing it to Ben Waldie, and copying MacTech Editorial, the result of which is shown in figure 1.

set theSubject to "Some Subject"
set theBody to "Some Body"
tell application "Microsoft Entourage"
   set theRecipients to {{address:{display name:"Ben Waldie",
address:"ben@automatedworkflows.com"}, recipient type:to recipient},
{address:{display name:"MacTech Editorial", address:"editorial@mactech.com"},
recipient type:cc recipient}}
   set theMessage to make new outgoing message with properties 
{recipient:theRecipients, subject:theSubject, content:theBody}
   open theMessage
end tell


Figure 1. An Outgoing Message with Recipients

Adding Attachments to an Outgoing Message

Another common task when creating outgoing messages is adding attachments. One or more files may be added to an outgoing message as attachments by providing the paths to those files when the message is created, as follows:

set theSubject to "Some Subject"
set theBody to "Some Body"
set theAttachment to choose file with prompt "Select a file to attach:" without invisibles
tell application "Microsoft Entourage"
   set theRecipients to {{address:{display name:"Ben Waldie", 
address:"ben@automatedworkflows.com"}, recipient type:to recipient}, 
{address:{display name:"MacTech Editorial", 
address:"editorial@mactech.com"}, 
recipient type:cc recipient}}
   set theMessage to make new outgoing message with properties 
{recipient:theRecipients, subject:theSubject, 
content:theBody, attachments:theAttachment}
   open theMessage
end tell

In this case, we have only added a single attachment to an outgoing message. Adding multiple attachments is done in the same manner. Just specify a list of paths, rather than a single path. Figure 2 shows the result of the previous example code.


Figure 2. An Outgoing Message with an Attachment

Sending an Outgoing Message

Once you have created an outgoing message, you will most likely want to send it. Earlier, we discussed opening outgoing messages, since they are not visible by default. Well, if you are going to immediately send an outgoing message after creating it, then you might not need to open it. Regardless, to send a message, use the send command, followed by a list of the messages you want to send. For example:

send theMessage

Please note that, when first sending a message via AppleScript, Entourage will display a dialog notifying the user that a script is attempting to send a message (figure 3). The user must click a Send button before the script can proceed. Keep this in mind, and be prepared for this occurrence.


Figure 3. Entourage's Send Message Warning Dialog

Working with Incoming Messages

So far, we have been discussing ways of working with outgoing messages. Incoming messages possess most of the same properties that outgoing messages possess, so interacting with them is very similar.

To retrieve a list of currently selected incoming messages, reference the selection property of the application. For example:

tell application "Microsoft Entourage"
   selection
end tell
--> {incoming message id 136 of application "Microsoft Entourage"}

Once you have a reference to an incoming message, you can retrieve any of its properties. For example, the following code will retrieve the subject of a selected incoming message.

tell application "Microsoft Entourage"
   set theSelection to selection
   set theCurrentMessage to item 1 of theSelection
   subject of theCurrentMessage
end tell
--> "RE: Meeting Today!"

Forwarding a Message

To forward a message to another recipient, you can use Entourage's forward command. This command requires a reference to a message to be forwarded as its direct parameter. Optional parameters include a to recipient for the forwarded message, and whether the forwarded message's window should be opened in Entourage's interface. For example:

tell application "Microsoft Entourage"
   set theSelection to selection
   set theCurrentMessage to item 1 of theSelection
   forward theCurrentMessage to "ben@automatedworkflows.com" 
with opening window
end tell
--> window "FW: Meeting Today!" of application 
"Microsoft Entourage"

Take note that the result of the forward command in the example code above is a reference to the window of the forwarded message. This is because we specified that the forwarded message should be opened. If we had specified for the message not to be opened, then an outgoing message reference would have been returned instead. For example:

tell application "Microsoft Entourage"
   set theSelection to selection
   set theCurrentMessage to item 1 of theSelection
   forward theCurrentMessage to "ben@automatedworkflows.com" 
without opening window
end tell
--> outgoing message id 11277 of application 
"Microsoft Entourage"

Moving a Message to a Folder

You may have a need to move incoming messages from one folder to another via AppleScript. To do this, you can use the move command. When using this command, you must provide a reference to the message you want to move, along with a reference to the folder into which you would like the message to be moved. For example, the following code would move the currently selected message into a folder called "Some Folder".

tell application "Microsoft Entourage"
   set theSelection to selection
   set theCurrentMessage to item 1 of theSelection
   move theCurrentMessage to folder "Some Folder"
end tell

Keep in mind that since folders have a hierarchy in Entourage, then they must be addressed within this hierarchy via AppleScript. The following example code would move a message into a folder named "Another Folder", which resides inside of a folder named "Some Folder".

tell application "Microsoft Entourage"
   set theSelection to selection
   set theCurrentMessage to item 1 of theSelection
   move theCurrentMessage to folder "Another Folder" 
of folder "Some Folder"
end tell

Working with Contacts

Now that we have discussed ways of interacting with messages in Entourage, let's discuss ways of interacting with other scriptable elements. First, we will take a look at contacts.

To create a new contact in Entourage, use the make command, much in the same way that we discussed creating outgoing messages. For the sake of efficiency, you will probably want to apply properties to the contact as it is created. To do this, use the make command's optional with properties parameter.

The following example code demonstrates how this is done. This particular code will create a contact, complete with a first name, last name, company, job title, business address, business web page address, and email address. Figure 4 shows an example of the newly created contact.

tell application "Microsoft Entourage"
   make new contact with properties 
{first name:"Ben", last name:"Waldie", company:"Automated Workflows, LLC", 
job title:"President", business phone number:"610-935-0652", 
business address:{street address:"116 Cold Stream Road", 
city:"Phoenixville", state:"PA", zip:"19460", country:"USA"}, 
business web page:"http://www.automatedworkflows.com", 
email address:{{label:"Work", contents:"ben@automatedworkflows.com"}}}
end tell
--> contact id 18 of application "Microsoft Entourage"


Figure 4. A Newly Created Contact

Please note that, in the example code above, AppleScript records were used to assign values to certain contact properties. This is because these properties reference classes that contain properties of their own. For example, the business address property of a contact references a value of class postal address. The postal address class possesses street address, city, state, zip, and country properties.

Working with Events

AppleScript may also be used to interact with calendar events in Entourage. Like outgoing messages and contacts, events may be created using the make command. For example, the following code will create a new event for this year's Worldwide Developer's Conference in San Francisco. Figure 5 shows an example of the newly created event.

set theStartDate to date "Monday, June 11, 2007 12:00:00 AM"
set theEndDate to date "Friday, June 15, 2007 11:59:00 PM"
tell application "Microsoft Entourage"
   make new event with properties {subject:"WWDC", 
location:"Moscone West, San Francisco, CA",
content:"Apple's Worldwide Developer's Conference", 
start time:theStartDate, end time:theEndDate}
end tell
--> event id 50 of application "Microsoft Entourage"


Figure 5. A Newly Created Event

In Conclusion

Like the other Microsoft Office applications, Entourage has fairly comprehensive AppleScript support, and we have really only scratched the surface in this month's column. You are encouraged to explore some of the other things that can be done via scripting, such as interacting with tasks, triggering AppleScripts from Entourage rules, and more. Be sure to view Entourage's AppleScript dictionary for a complete list of its AppleScript terminology.

Another great way to get started with scripting Entourage is to download some of the many freeware and shareware AppleScripts for Entourage that have been written by third-party developers, such as Paul Berkowitz. Many of these scripts are available from the ScriptBuilders section of MacScripter.net. http://scriptbuilders.net//

Note to Readers

Many of you who are regular MacTech readers know that I have been writing monthly AppleScript columns for MacTech for several years now. In addition to writing for MacTech, I've also been busy running Automated Workflows, LLC, my AppleScript and workflow automation consulting firm. As my company has grown, so have my commitments. For this reason, I have decided that it is time to begin focusing more on my company. Therefore, this month's column will serve as my final regular MacTech column.

Throughout the years, I have received numerous emails from you, the readers. I want to thank you for your many nice comments and questions along the way. As always, my email inbox will remain open, and you are welcome to continue sending your comments and questions to me in the future at ben@automatedworkflows.com. I will also be attending WWDC 2007, and I hope to have the opportunity to meet some of you there, as well.

For a complete list of my MacTech columns, please be sure to visit the "Archives" section of the MacTech website. You can also find links to all of my MacTech columns, as well as many of my other AppleScript and Automator articles, tips, techniques, and books on my website at http://www.automatedworkflows.com.

Keep scripting!


Ben Waldie is the author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from http://www.spiderworks.com, as well as an AppleScript Training CD, available from http://www.vtc.com. Ben is also president of Automated Workflows, LLC, a company specializing in AppleScript and workflow automation consulting. For years, Ben has developed professional AppleScript-based solutions for businesses including Adobe, Apple, NASA, PC World, and TV Guide. For more information about Ben, please visit http://www.automatedworkflows.com, or email Ben at ben@automatedworkflows.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Latest Forum Discussions

See All

Bid farewell to Penacony as Honkai: Star...
Penacony has been a story of twists, exciting new characters, and strong allies, and soon Honkai: Star Rail will be finishing it with a bang. Version 2.3, fittingly titled Farewell Penacony, will be launching June 19th and will feature updates to... | Read more »
HoYoverse roll out their plans for Anime...
For those who are looking to book a getaway in July, you might give some thought to Los Angeles between the 4th and 7th, which just so happens to coincide with the Anime Expo 2024. Amongst all the storied attendees is HoYoverse, who will be... | Read more »
The first rule of Brok the InvestiGator...
Mobile gamers were recently able to get their hands on BROK the InvestiGator, a point-and-click following the adventures of the titular reptile, a detective who can solve crimes through wit or brawn. If you were one that chose the latter then... | Read more »
Diablo Immortal celebrates second annive...
It has been two years since Diablo Immortal launched and despite some very valid criticism of its business model, it has done pretty well for itself. The Tempest class also gives it a lot of grace. To celebrate this anniversary, the March of the... | Read more »
Pokemon GO pulls on its jersey for a foo...
There have been a lot of jokes about this, some by me, but Pokemon Go has genuinely done a lot of good by getting people out and about.Pokemon GO Fest 2024: Madrid is fast approaching, and Niantic has set up a new area in a bit to get people to... | Read more »
Stumble Guys dials up the calamity 1000%...
Credit where it is due, Stumble Guys has had a few top-class crossovers in its’ life; Dungeons and Dragons, Rabbids and SpongeBob Squarepants to name but a few. It is such a shame, though, that all of these have now been well and truly trounced... | Read more »
You’re going to need a bigger boat as wa...
I am sure we all know that Finding Nemo quote of fish being friends and not food, however, Play Together is going in a completely opposite direction with their latest update. Introducing the Monstrous Fish, these behemoths are proving themselves... | Read more »
Supercell's hotly anticipated Squad...
If you've ever picked up a mobile, even without looking at an App storefront, you will have heard of Supercell, the massive company behind Clash of Clans, Brawl Stars, and Clash Royale. Now, the catalogue grows as Squad Busters prepares to take... | Read more »
Top Mobile Game Discounts
Every day, we pick out a curated list of the best mobile discounts on the App Store and post them here. This list won't be comprehensive, but it every game on it is recommended. Feel free to check out the coverage we did on them in the links below... | Read more »
Osseous has a bone to pick with you as t...
We recently quelled the immense threat brought about by Zemouregal and the giant dragon Vorkath in Runescape, and you might think that earnt adventurers a little break, but no. Instead, Jagex has decided it is time to face off against an equally... | Read more »

Price Scanner via MacPrices.net

Could A Smarter Siri Infused With AI (‘Apple...
FEATURE – The iPhone is already smart, but it’s about to become more intelligent. AI — short for artificial intelligence — is widely expected to be the main topic of discussion at this year’s WWDC (... Read more
Update: For WWDC, Amazon has lowered prices o...
Amazon has every configuration and color of Apple’s M3 MacBook Airs now on sale for $170-$210 off MSRP, starting at only $899 shipped, as Apple holds their annual WWDC conference this week. Their... Read more
Deal Alert! 2nd-generation Apple AirPods on s...
Amazon has 2nd generation Apple AirPods on sale right now for only $79.99 shipped. That’s $50 (38%) off Apple’s MSRP. Their price is the lowest currently available for a new set of AirPods from any... Read more
13-inch M3 MacBook Airs on sale for $150-$200...
Amazon has every configuration and color of Apple’s 13″ M3 MacBook Air on sale for $150-$200 off MSRP, now starting at only $899 shipped. Their prices are the lowest available for these Airs among... Read more
Apple is now selling 13-inch M3 MacBook Airs...
Apple has Certified Refurbished 13″ M3 MacBook Airs now in stock for $170-$230 off MSRP, Certified Refurbished. Prices start at $929. These are the cheapest M3-powered MacBooks for sale at Apple and... Read more
Amazon is offering $150-$200 discounts on 15-...
Amazon is offering a $150-$200 discount on every configuration and color of Apple’s M3-powered 15″ MacBook Airs. Prices start at $1149 for models with 8GB of RAM and 256GB of storage: – 15″ M3... Read more
Apple is now selling 15-inch M3 MacBook Airs...
Apple has Certified Refurbished 15″ M3 MacBook Airs in stock today starting at only $1099 and ranging up to $260 off MSRP. These are the cheapest M3-powered 15″ MacBook Airs for sale today at Apple.... Read more
13-inch M3 MacBook Air prices drop to record...
B&H Photo is offering discounts on new 13-inch M3 MacBook Airs ranging up to $200 off MSRP ahead of Apple’s WWDC conference next week. Prices start at only $899! These are the lowest prices... Read more
Apple HomePods on rare sale for $20-$30 off M...
Best Buy is offering a $20-$30 discount on Apple HomePods this weekend on their online store. The HomePod mini is on sale for $79.99, $20 off MSRP, while Best Buy has the full-size HomePod on sale... Read more
Base 14-inch M3 MacBook Pro on sale for $1399...
Amazon and B&H Photo both have the base 14″ M3 MacBook Pro on sale for $200 off Apple’s MSRP, only $1399. Shipping is free at both retailers (free 1-2 day shipping at B&H): – 14″ M3 MacBook... Read more

Jobs Board

*Apple* Systems Administrator - JAMF - Activ...
…**Public Trust/Other Required:** None **Job Family:** Systems Administration **Skills:** Apple Platforms,Computer Servers,Jamf Pro **Experience:** 3 + years of Read more
*Apple* Systems Administrator - JAMF - Activ...
…**Public Trust/Other Required:** None **Job Family:** Systems Administration **Skills:** Apple Platforms,Computer Servers,Jamf Pro **Experience:** 3 + years of Read more
Operations Associate - *Apple* Blossom Mall...
Operations Associate - Apple Blossom Mall Location:Winchester, VA, United States (https://jobs.jcp.com/jobs/location/191170/winchester-va-united-states) - Apple Read more
Armed Security Officer - *Apple* Store - NA...
…provide services in which the client's health, safety, and security is our #1 priority. The Apple Store is located on the 2 nd floor of the 5 th Avenue Mall. Read more
Liquor Stock Clerk - S. *Apple* St. - Idaho...
Liquor Stock Clerk - S. Apple St. Boise Posting Begin Date: 2023/10/10 Posting End Date: 2024/10/14 Category: Retail Sub Category: Customer Service Work Type: Part Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.