TweetFollow Us on Twitter

Introduction to Scripting Microsoft Excel

Volume Number: 23 (2007)
Issue Number: 02
Column Tag: AppleScript Essentials

Introduction to Scripting Microsoft Excel

by Benjamin S. Waldie

With Office 2008 on the horizon, Microsoft has recently begun to push AppleScript as an alternative automation technology to Visual Basic macros in the Office applications. Moving forward, Visual Basic macros will not be supported in the release of Office 2008. Current AppleScript users are ahead of the curve. The Office applications have been AppleScriptable for quite some time, and AppleScript actually provides several advantages over Visual Basic. For one, AppleScripts can interact with multiple applications, including non-Microsoft applications, allowing even complex multi-application workflows to be automated.

Last month, we began discussing how to get started with scripting Microsoft Word. We explored various techniques for interacting with Word documents, as well as the content within those documents, all using AppleScript. This month, we're going to begin discussing another Office application, Microsoft Excel. Like Word, Excel contains a quite extensive AppleScript dictionary, allowing almost any task that can be performed manually to be automated using AppleScript.

Please note, all example code within this month's column was written and tested with Excel 2004 (version 11.x). If you are using another version of Excel, please be aware that the terminology may need to be adjusted in order to function properly. Let's get started.

Working with Workbooks

In Excel, the top-level class (beneath the application class) with which you will probably want to interact is a workbook. A workbook will contain one or more sheets, and those sheets will typically contain ranges of data. This data can be text, numbers, dates, and so forth. We will discuss each of these primary classes of Excel objects in this month's column, but we will begin with the workbook class.

Making a Workbook

Creating a workbook in Excel is similar to the process of creating a document in Word, or in many scriptable applications, for that matter. To do so, use the make command, as demonstrated below.

tell application "Microsoft Excel"
   make new workbook
end tell
--> workbook "Sheet1" of application "Microsoft Excel"

The make command's result will be a reference to the newly created workbook, which may be placed into an AppleScript variable, if desired, for future reference in your script.

Closing a Workbook

Closing a workbook is also very similar to closing a document in other scriptable applications. Use the close command, referencing the workbook you wish to close. Optionally, you may choose to specify whether the workbook should be saved during the close process, using the optional saving parameter. For example:

tell application "Microsoft Excel"
   close workbook 1 saving no
end tell

Opening a Workbook

To open a workbook, use the open command, followed by a reference to the workbook file you want to open. For example:

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
tell application "Microsoft Excel"
   open theWorkbookFile
end tell

One issue with the open command is that, unfortunately, it does not return a result. Therefore, if you want to perform further processing on the newly opened document, you will need to build a reference to it in another manner. One way to do this is to retrieve the workbook file's name, and then construct a reference to the workbook using that name, once it has been opened. This is demonstrated in the example code below.

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
set theWorkbookName to name of (info for theWorkbookFile)
tell application "Microsoft Excel"
   open theWorkbookFile
   set theWorkbook to workbook theWorkbookName
end tell
--> workbook "My Workbook.xls" of application "Microsoft Excel"

Another way that this can be achieved is by referencing the active workbook property of Excel's application class, once the workbook has been opened. This property references the currently active workbook, which should be the newly opened document.

set theWorkbookFile to choose file with prompt "Please select an Excel workbook file:"
set theWorkbookName to name of (info for theWorkbookFile)
tell application "Microsoft Excel"
   open theWorkbookFile
   set theWorkbook to active workbook
end tell
--> active workbook of application "Microsoft Excel"

When referencing the active workbook property, one thing to keep in mind is that, if another workbook is brought to the front, then your script may reference the incorrect workbook. Because of this, it is recommended to reference workbooks by name.

Saving a Workbook

To save an opened workbook to its existing path, use the save command, referencing the workbook to be saved. For example, the following code will save the currently active workbook to its current path.

tell application "Microsoft Excel"
   save active workbook
end tell

Excel also has a save workbook as command, which may be used to save a workbook into a new location, or in a different file format. The following example code makes use of this command, as well as some of its optional parameters, in order to save the currently active workbook to the desktop in comma separated format.

set theOutputPath to (path to desktop folder as string) & "My Saved Workbook.csv"
tell application "Microsoft Excel"
   tell active workbook
      save workbook as filename theOutputPath file format CSV file format
   end tell
end tell

Take some time to explore some of the other optional parameters for the save workbook as command, as well as some of the other available file formats, which can be found in Excel's AppleScript dictionary.

Working with Sheets

As previously mentioned, a workbook itself does not contain data in Excel. Rather, a workbook contains sheets, which contain the data. Most often, you will find yourself writing a script that will interact with a worksheet, a specific type of sheet in Excel. That's what we will be discussing here. Another type of sheet, which we will not discuss at this time, is a chart sheet.

Making a Worksheet

Like a workbook, a worksheet is created by using the make command. When using this command, be sure to specify a location for the new worksheet to be created, such as beginning, end, before worksheet 1, and so forth. For example, this code will create a new worksheet at the end of the existing worksheets within the currently active workbook.

tell application "Microsoft Excel"
   tell active workbook
      make new worksheet at end
   end tell
end tell
--> sheet "Sheet2" of active workbook of application "Microsoft Excel"

Selecting a Worksheet

At times, you may want to navigate to a specific worksheet in an Excel workbook. To do this, use the activate object command, and target the worksheet that you want to be displayed. For example:

tell application "Microsoft Excel"
   tell active workbook
      activate object worksheet "Sheet1"
   end tell
end tell

Working with Data

In an Excel worksheet, data is contained within cells, which are organized into rows and columns. Cells can be accessed by referencing the cell, row, column, or range class.

The Cell Class

To access a specific cell, use the cell class. For example, the following code references the first cell of a worksheet, found in column A, row 1.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      cell "A1"
   end tell
end tell
--> cell "A1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel" 

The Row Class

To access an entire row of cells, use the row class. For example, the following code references the first row of cells in a worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      row 1
   end tell
end tell
--> row "$1:$1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

The Column Class

To access an entire column of cells, use the column class. For example, the following code references the first column of cells in a worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      column 1
   end tell
end tell
--> column "$A:$A" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

The Range Class

Regardless of how you reference cells within a worksheet, you are really referencing what is known as a range. A range refers to either a single cell, or multiple cells within a worksheet, and the cell, row, and column classes all inherit the properties of the range class. There are numerous ways to directly reference a range. The following are some examples.

This code demonstrates how to reference a range that represents a single cell in a worksheet, in this case, the first cell in the first row, i.e. the intersection of column 1 and row 1.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      range "A1"
   end tell
end tell
--> cell "A1" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

This next example demonstrates how to reference a range that represents multiple cells within a worksheet, in this case, cells 2 through 5 of the first two rows.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
       range "B1:F2"
   end tell
end tell
--> range "B1:F2" of worksheet "Sheet1" of active workbook of application "Microsoft Excel"

Again, there are numerous ways to reference a range of cells, and Excel is pretty flexible. For a chart that outlines different methods, take a look at the AppleScript Reference Guide for Excel, mentioned later in this column.

The Used Range

In some cases, you may not know specifically which range you want to reference. For example, you may just want to reference all of the data contained within a specified worksheet. To do this, you can reference the used range property of the worksheet.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      used range
   end tell
end tell
--> used range of active sheet of active workbook ¬
of application "Microsoft Excel"

Properties of Ranges

We have discussed numerous ways to reference ranges of cells in Excel. However, what can you do with a range once you have constructed a reference to it? Well, one thing you can do is access its properties. Ranges have numerous properties, but perhaps the two that you may find most useful are the value and formula properties.

By referencing the value property of a range, you can retrieve the value of a specified set of cells in a worksheet. For example, the following code retrieves the values of the used range in a specified worksheet. Notice that the value is returned as a list of lists. Each list represents a row, and each list item represents a cell.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      value of used range
   end tell
end tell
--> {{1.0, 2.0, 3.0}, {4.0, 5.0, 6.0}}

The formula property of a range returns a similar result. For example:

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      formula of used range
   end tell
end tell
--> {{"1", "2", "3"}, {"4", "5", "6"}}

Of course, these properties are not read-only properties. So, it is also possible to modify them, if desired. For example, the following code demonstrates how to set the value of a single cell.

tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      set value of cell "A1" to "A"
   end tell
end tell
Likewise, the following code will set the value of a range of cells.
tell application "Microsoft Excel"
   tell worksheet "Sheet1" of active workbook
      set value of range "A1:C2" to {{"a", "b", "c"}, {"d", "e", "f"}}
   end tell
end tell

Pulling Things Together

Now, let's take a brief look at some sample code that makes use of several of the topics that we have discussed throughout this month's column. The following example code will retrieve the names of any visible items on the desktop. It will then create a workbook, and insert the list of item names into the active worksheet.

— Retrieve a list of items on the desktop
set theFileNames to list folder (path to desktop) without invisibles
— Convert the list of items to a list of lists
repeat with a from 1 to length of theFileNames
   set item a of theFileNames to {item a of theFileNames}
end repeat
— Build a new workbook in Excel, and add the data to the current worksheet
tell application "Microsoft Excel"
   set theWorkbook to make new workbook
   tell active sheet of theWorkbook
      set value of range ("A1:A" & (length of theFileNames)) to theFileNames
   end tell
end tell

In Closing

It may seem like we've only scratched the surface of scripting Excel, and we have. As mentioned at the beginning of this month's column, Excel contains quite an extensive AppleScript dictionary, and there is a lot that you can do with it from a scripting perspective. However, using the techniques we have discussed in this month's column, you should be able to piece together a script that can construct a workbook, create a worksheet, retrieve data from a range of cells in a worksheet, and more.

For more information about scripting Excel, be sure to download the Excel AppleScript Reference Guide that I mentioned earlier. This can be found on the Mactopia website at http://www.microsoft.com/mac/. It is located in the Resources > Developer Center > AppleScript Resources for Office 2004 section.

Until next time, keep scripting!


Ben Waldie is the author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from http://www.spiderworks.com, as well as an AppleScript Training CD, available from http://www.vtc.com. Ben is also president of Automated Workflows, LLC, a company specializing in AppleScript and workflow automation consulting. For years, Ben has developed professional AppleScript-based solutions for businesses including Adobe, Apple, NASA, PC World, and TV Guide. For more information about Ben, please visit http://www.automatedworkflows.com, or email Ben at ben@automatedworkflows.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

LaunchBar 6.18.5 - Powerful file/URL/ema...
LaunchBar is an award-winning productivity utility that offers an amazingly intuitive and efficient way to search and access any kind of information stored on your computer or on the Web. It provides... Read more
Affinity Designer 2.3.0 - Vector graphic...
Affinity Designer is an incredibly accurate vector illustrator that feels fast and at home in the hands of creative professionals. It intuitively combines rock solid and crisp vector art with... Read more
Affinity Photo 2.3.0 - Digital editing f...
Affinity Photo - redefines the boundaries for professional photo editing software for the Mac. With a meticulous focus on workflow it offers sophisticated tools for enhancing, editing and retouching... Read more
WhatsApp 23.24.78 - Desktop client for W...
WhatsApp is the desktop client for WhatsApp Messenger, a cross-platform mobile messaging app which allows you to exchange messages without having to pay for SMS. WhatsApp Messenger is available for... Read more
Adobe Photoshop 25.2 - Professional imag...
You can download Adobe Photoshop as a part of Creative Cloud for only $54.99/month Adobe Photoshop is a recognized classic of photo-enhancing software. It offers a broad spectrum of tools that can... Read more
PDFKey Pro 4.5.1 - Edit and print passwo...
PDFKey Pro can unlock PDF documents protected for printing and copying when you've forgotten your password. It can now also protect your PDF files with a password to prevent unauthorized access and/... Read more
Skype 8.109.0.209 - Voice-over-internet...
Skype is a telecommunications app that provides HD video calls, instant messaging, calling to any phone number or landline, and Skype for Business for productive cooperation on the projects. This... Read more
OnyX 4.5.3 - Maintenance and optimizatio...
OnyX is a multifunction utility that you can use to verify the startup disk and the structure of its system files, to run miscellaneous maintenance and cleaning tasks, to configure parameters in the... Read more
CrossOver 23.7.0 - Run Windows apps on y...
CrossOver can get your Windows productivity applications and PC games up and running on your Mac quickly and easily. CrossOver runs the Windows software that you need on Mac at home, in the office,... Read more
Tower 10.2.1 - Version control with Git...
Tower is a Git client for OS X that makes using Git easy and more efficient. Users benefit from its elegant and comprehensive interface and a feature set that lets them enjoy the full power of Git.... Read more

Latest Forum Discussions

See All

Pour One Out for Black Friday – The Touc...
After taking Thanksgiving week off we’re back with another action-packed episode of The TouchArcade Show! Well, maybe not quite action-packed, but certainly discussion-packed! The topics might sound familiar to you: The new Steam Deck OLED, the... | Read more »
TouchArcade Game of the Week: ‘Hitman: B...
Nowadays, with where I’m at in my life with a family and plenty of responsibilities outside of gaming, I kind of appreciate the smaller-scale mobile games a bit more since more of my “serious" gaming is now done on a Steam Deck or Nintendo Switch.... | Read more »
SwitchArcade Round-Up: ‘Batman: Arkham T...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for December 1st, 2023. We’ve got a lot of big games hitting today, new DLC For Samba de Amigo, and this is probably going to be the last day this year with so many heavy hitters. I... | Read more »
Steam Deck Weekly: Tales of Arise Beyond...
Last week, there was a ton of Steam Deck coverage over here focused on the Steam Deck OLED. | Read more »
World of Tanks Blitz adds celebrity amba...
Wargaming is celebrating the season within World of Tanks Blitz with a new celebrity ambassador joining this year's Holiday Ops. In particular, British footballer and movie star Vinnie Jones will be brightening up the game with plenty of themed in-... | Read more »
KartRider Drift secures collaboration wi...
Nexon and Nitro Studios have kicked off the fifth Season of their platform racer, KartRider Dift, in quite a big way. As well as a bevvy of new tracks to take your skills to, and the new racing pass with its rewards, KartRider has also teamed up... | Read more »
‘SaGa Emerald Beyond’ From Square Enix G...
One of my most-anticipated releases of 2024 is Square Enix’s brand-new SaGa game which was announced during a Nintendo Direct. SaGa Emerald Beyond will launch next year for iOS, Android, Switch, Steam, PS5, and PS4 featuring 17 worlds that can be... | Read more »
Apple Arcade Weekly Round-Up: Updates fo...
This week, there is no new release for Apple Arcade, but many notable games have gotten updates ahead of next week’s holiday set of games. If you haven’t followed it, we are getting a brand-new 3D Sonic game exclusive to Apple Arcade on December... | Read more »
New ‘Honkai Star Rail’ Version 1.5 Phase...
The major Honkai Star Rail’s 1.5 update “The Crepuscule Zone" recently released on all platforms bringing in the Fyxestroll Garden new location in the Xianzhou Luofu which features many paranormal cases, players forming a ghost-hunting squad,... | Read more »
SwitchArcade Round-Up: ‘Arcadian Atlas’,...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for November 30th, 2023. It’s Thursday, and unlike last Thursday this is a regular-sized big-pants release day. If you like video games, and I have to believe you do, you’ll want to... | Read more »

Price Scanner via MacPrices.net

Deal Alert! Apple Smart Folio Keyboard for iP...
Apple iPad Smart Keyboard Folio prices are on Holiday sale for only $79 at Amazon, or 50% off MSRP: – iPad Smart Folio Keyboard for iPad (7th-9th gen)/iPad Air (3rd gen): $79 $79 (50%) off MSRP This... Read more
Apple Watch Series 9 models are now on Holida...
Walmart has Apple Watch Series 9 models now on Holiday sale for $70 off MSRP on their online store. Sale prices available for online orders only, in-store prices may vary. Order online, and choose... Read more
Holiday sale this weekend at Xfinity Mobile:...
Switch to Xfinity Mobile (Mobile Virtual Network Operator..using Verizon’s network) and save $500 instantly on any iPhone 15, 14, or 13 and up to $800 off with eligible trade-in. The total is applied... Read more
13-inch M2 MacBook Airs with 512GB of storage...
Best Buy has the 13″ M2 MacBook Air with 512GB of storage on Holiday sale this weekend for $220 off MSRP on their online store. Sale price is $1179. Price valid for online orders only, in-store price... Read more
B&H Photo has Apple’s 14-inch M3/M3 Pro/M...
B&H Photo has new Gray and Black 14″ M3, M3 Pro, and M3 Max MacBook Pros on Holiday sale this weekend for $100-$200 off MSRP, starting at only $1499. B&H offers free 1-2 day delivery to most... Read more
15-inch M2 MacBook Airs are $200 off MSRP on...
Best Buy has Apple 15″ MacBook Airs with M2 CPUs in stock and on Holiday sale for $200 off MSRP on their online store. Their prices are among the lowest currently available for new 15″ M2 MacBook... Read more
Get a 9th-generation Apple iPad for only $249...
Walmart has Apple’s 9th generation 10.2″ iPads on sale for $80 off MSRP on their online store as part of their Cyber Week Holiday sale, only $249. Their prices are the lowest new prices available for... Read more
Space Gray Apple AirPods Max headphones are o...
Amazon has Apple AirPods Max headphones in stock and on Holiday sale for $100 off MSRP. The sale price is valid for Space Gray at the time of this post. Shipping is free: – AirPods Max (Space Gray... Read more
Apple AirTags 4-Pack back on Holiday sale for...
Amazon has Apple AirTags 4 Pack back on Holiday sale for $79.99 including free shipping. That’s 19% ($20) off Apple’s MSRP. Their price is the lowest available for 4 Pack AirTags from any of the... Read more
New Holiday promo at Verizon: Buy one set of...
Looking for more than one set of Apple AirPods this Holiday shopping season? Verizon has a great deal for you. From today through December 31st, buy one set of AirPods on Verizon’s online store, and... Read more

Jobs Board

Senior Software Engineer - *Apple* Fundamen...
…center of Microsoft's efforts to empower our users to do more. The Apple Fundamentals team focused on defining and improving the end-to-end developer experience in Read more
Omnichannel Associate - *Apple* Blossom Mal...
Omnichannel Associate - Apple Blossom Mall Location:Winchester, VA, United States (https://jobs.jcp.com/jobs/location/191170/winchester-va-united-states) - Apple Read more
Housekeeper, *Apple* Valley Villa - Cassia...
Apple Valley Villa, part of a senior living community, is hiring entry-level Full-Time Housekeepers to join our team! We will train you for this position and offer a Read more
Senior Manager, Product Management - *Apple*...
…Responsibilities** We are seeking an ambitious, data-driven thinker to assist the Apple Product Development team as our Wireless Product division continues to grow Read more
Mobile Platform Engineer ( *Apple* /AirWatch)...
…systems, installing and maintaining certificates, navigating multiple network segments and Apple /IOS devices, Mobile Device Management systems such as AirWatch, and Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.