TweetFollow Us on Twitter

An Introduction to Scripting Fetch

Volume Number: 22 (2006)
Issue Number: 5
Column Tag: Scripting

AppleScript Essentials

An Introduction to Scripting Fetch

by Benjamin S. Waldie

For the past several months, we have discussed ways to store and access data from AppleScript. We have talked about script properties, property list files, scriptable database applications, and more. In this month's column, I'd like to switch gears, and talk about a great application that I have been scripting quite a lot lately. That application is Fetch.Fetch is a popular FTP/SFTP client for the Macintosh. It is a commercial application, and a demonstration version is available for download from the Fetch Softworks website at <http://www.fetchsoftworks.com>. If you do not own a license for Fetch, then I encourage you to download a demonstration version, so that you may follow along with the various example scripts throughout this month's column.



Figure 1. Fetch's Well-Known Icon

All of the example code that we will discuss was written and tested with Fetch version 5.1b2. As when scripting any application, if you are using an older or newer version of Fetch, then you may notice some differences in the AppleScript terminology. If this occurs, please refer to Fetch's AppleScript dictionary for guidance in determining the proper syntax to use.

Connecting to a Server

The first thing that we are going to discuss, is the process of connecting to a remote server. For my testing, I enabled incoming FTP access in the Sharing system preference on another Mac OS X computer, on my local network. However, I could have just as easily chosen to access a remote server, such as the one hosting my website, or one of a client. For your testing, if you have a second machine running Mac OS X, then you can enable incoming FTP access (you'll probably want to ensure that your network is secure, or enable a firewall prior to doing this) for testing. Otherwise, you will need to find a server that you can access remotely via FTP or SFTP.

Making a new server connection in Fetch, is done by creating a new window, called a transfer window. See figure 2.



Figure 2. A Transfer Window Connection

Creating a transfer window is done with the use of the make command, as demonstrated in the example code below. You will want to replace my example IP address, username, password, and initial directory with ones that are relevant to the server to which you are attempting to connect.

set theServerAddress to "10.0.1.3"
set theUserName to "myUserName"
set thePassword to "myPassword"
set theDirectory to "Documents/FTP Main/"

tell application "Fetch"
   make new transfer window at beginning with properties {hostname:theServerAddress, 
   username:theUserName, password:thePassword, initial folder:theDirectory}
end tell
--> transfer window id 120663408 of application "Fetch"

As you can see from the code above, the result of making a new transfer window is a reference to the newly created window. Notice that the window is referenced by its ID. As you navigate to different folders on the remote server, the transfer window's name will change. Therefore, to refer to the newly created transfer window again later in your code, you may want to capture this result in a variable. For example:

tell application "Fetch"
   set theTransferWindow to make new transfer window at beginning with properties 
   {hostname:theServerAddress, username:theUserName, password:thePassword, initial 
   folder:theDirectory}
end tell

When a transfer window is made, its default authentication type is FTP. However, you may explicitly specify that a different type of authentication be used, such as SFTP. This can be done by specifying a value for the transfer window's authentication property, when the transfer window is created, as the following code demonstrates.

tell application "Fetch"
   make new transfer window at beginning with properties {hostname:theServerAddress, 
   username:theUserName, password:thePassword, initial folder:theDirectory, authentication:SFTP}
end tell

As previously mentioned, one way to refer to a transfer window in the future is to do so by setting a variable to the result when making a transfer window. This variable would include a reference to the transfer window using a unique ID. If you are working with an existing transfer window, you can find out its unique ID with the use of the following code:

tell application "Fetch"
   id of front transfer window
end tell
--> 120663408

Once you have a window's ID, you can refer to it later by that ID. For example:

tell transfer window id 96356736
   -- Add Code Here
end tell

You may also have the need to retrieve the name of a transfer window. However, as mentioned before, the name of the transfer window will change if you open a remote folder.

tell application "Fetch"
   name of transfer window 1
end tell
--> "10.0.1.3 -- FTP Main"

You can also refer to a transfer window by its index, or front to back order. For example, the following code would target the frontmost transfer window, which has an index of 1.

tell transfer window 1
   -- Add Code Here
end tell

Throughout this column, all of my example code will target a transfer window by its index.

Working with Remote Items (Part 1)

Now that we have discussed connecting to a server, let's begin to look at ways to interact with the remote items on that server. First, let's turn to remote folders.

Suppose you want to create a remote folder on the server. First, you will probably want to determine if the folder already exists. To do this, use the exists command. For example:

tell application "Fetch"
   tell transfer window 1
      remote folder "Job 1000" exists
   end tell
end tell
--> false

If the remote folder did not exist, then you can choose to create it. Like creating a server connection, you will use the make command to create a folder. The following example code demonstrates the proper syntax for performing this task. Figure 3 shows an example of a newly created remote folder.

tell application "Fetch"
   make remote folder at transfer window 1 with properties {name:"Job 1000"}
end tell



Figure 3. A Newly Created Remote Folder

Now that you have a remote folder, you may want to open it. To do this, use the open command, as demonstrated by the following code.

tell application "Fetch"
   tell transfer window 1
      open remote folder "Job 1000"
   end tell
end tell

Note that, after opening a folder, the name of the transfer window will be changed to reflect the currently opened folder. An example of this can be seen in figure 4.



Figure 4. An Opened Remote Folder

Uploading

We will return to interacting with remote items shortly. For now, we will discuss uploading items to the server.

To upload an item to a remote directory, you will make use of Fetch's put into command. The following example code demonstrates the proper use of this terminology. First, it will prompt the user to select a file. It will then upload that file to the currently opened remote folder on the server. Figure 5 shows an example of an uploaded item.

set thePath to choose file with prompt "Please select an item to upload:" without invisibles
tell application "Fetch"
   with timeout of 300 seconds
      put into transfer window 1 item thePath
   end timeout
end tell



Figure 5. An Uploaded Item

The put into command's only required parameter is the item parameter, which we have utilized in the previous code to indicate the path of the desired file to be uploaded. The put into command also offers the ability to specify a number of optional parameters , which can affect how the item is uploaded. For example, you might specify the resume parameter if you want to resume a previous upload. Or, you might specify the uniquename parameter, if you want Fetch to automatically assign a unique name to the item if an item with the same name that already exists. For a complete list of the put into command's optional parameters, please refer to Fetch's AppleScript dictionary.

Working with Remote Items (Part 2)

Whether or not you have uploaded items to the server yourself, there will probably be times when you will want, or need, to interact with remote items on a server. See figure 6.



Figure 6. A Folder of Remote Items

We have already discussed how to navigate folders on a server. Now, let's talk about how to get the contents of a folder. The following example code will retrieve the names of every remote item in the currently opened folder.

tell application "Fetch"
   tell transfer window 1
      name of every remote item
   end tell
end tell
--> {"Job Image 1.png", "Job Image 2.png", "Job Image 3.png"}

    NOTE: In the previous code, we referenced every remote item. A remote item can be either a file or a folder on the server. To target one or the other specifically, use either remote file or remote folder instead.

You can also retrieve numerous properties of remote items on a server, such as the remote item's path, modification date, permissions, and more. The following example code demonstrates how to retrieve the size of a remote item, in bytes.

tell application "Fetch"
   tell transfer window 1
      size of remote item "Job Image 1.png"
   end tell
end tell
--> 66242

As you work with remote items, you may also have the need to delete a remote item. This can be done by using the delete command. For example:

tell application "Fetch"
   tell transfer window 1
      delete remote item "Job Image 2.png"
   end tell
end tell

Downloading

We have covered uploading items to a server. Now, let's talk briefly about downloading items. To download an item, use the download command, and specify a folder into which the remote item should be downloaded. For example:

set theOutputFolder to path to desktop folder
tell application "Fetch"
   tell transfer window 1
      download remote item "Job Image 1.png" to theOutputFolder
   end tell
end tell
--> {file "Macintosh HD:Users:bwaldie:Desktop:Job Image 1.png"}

As you can see from the previous example code, the download command will result in a list of file references to the newly downloaded items.

Miscellaneous Tasks

When working with a transfer window, whether uploading, downloading, or otherwise, you may want to determine the status of the server connection. This can be done by accessing the transfer window's status property. For example:

tell application "Fetch"
   tell transfer window 1
      status
   end tell
end tell
--> "Connected."

The status property will return the text of the current status of the fetch window, as it appears visually at the bottom of the window itself. Other transfer window attributes, which can often be useful when scripting Fetch, are also accessible via properties. Such attributes include the elapsed transfer time, and the bytes transferred, of a current transfer.

Once you have completed your Fetch scripting, you may want to have your script close down the server connection. This can be done by using the close command to close the transfer window. For example:

tell application "Fetch"
   close transfer window 1
end tell

Recording and Next Steps

Now that we have discussed various ways to interact with Fetch via AppleScript, I should also mention that Fetch is one of those rare applications that supports recording! That is, you can click the Record button in a Script Editor window, perform tasks manually in Fetch, and those tasks will be translated into AppleScript code, and written for you automatically in the Script Editor window. See figure 7 for an example of a recorded Fetch script.



Figure 7. Recording Manual Fetch Activity

You may be asking "Why didn't he mention that Fetch was recordable in the first place?" Well, one reason I didn't mention this is because I wanted to show how easy it is to begin scripting Fetch without recording. Another reason is that there are limitations to recording AppleScript code in any application. A recorded script does not include variables, if/then statements, or repeat loops. Because of this, recorded scripts are typically not as efficient as scripts written from scratch. Recorded scripts also perform tasks exactly as you recorded them, and do not have the ability to analyze situations and take different courses of action. However, recording is still a good way to get started, and it can often be helpful in determining the proper syntax for performing that certain task when you just can't figure it out on your own. Furthermore, you always have the ability to go back and edit your recorded scripts, to make them more efficient, or to add logic to them.



Figure 8. Fetch Example Scripts

If you plan to begin scripting Fetch, another good place to start is to download the example scripts that are available from the Fetch Softworks website at <http://fetchsoftworks.com/downloads.html>. These example scripts will provide you with unlocked, editable sample code for performing tasks such as connecting to servers, uploading items, and more. See figure 8.

In Closing

Although this month's column focused specifically on using Fetch as a scriptable FTP/SFTP client, please be aware that it is not your only choice. There are other applications and tools that are used by AppleScript developers for transferring files across networks.

Transmit, available from Panic Software at <http://www.panic.com>, and Cyberduck, available at http://www.cyberduck.ch are two other popular FTP/SFTP clients for Macintosh, and are frequently utilized by scripters. URL Access Scripting, which is built into Mac OS X, can be used for performing uploads and downloads to remote servers. URL Access Scripting can be found in the System > Library > ScriptingAdditions folder in Mac OS X. Many AppleScript developers also choose to utilize the power of UNIX for performing network file transfers. The do shell script AppleScript command in Mac OS X can be used in conjunction with UNIX tools such as curl or ftp to perform such tasks.

Until next time, keep scripting!


Ben Waldie is the author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from http://www.spiderworks.com. Ben is also president of Automated Workflows, LLC, a company specializing in AppleScript, and workflow automation consulting. For years, Ben has developed professional AppleScript-based solutions for businesses including Adobe, Apple, NASA, PC World, and TV Guide. For more information about Ben, please visit http://www.automatedworkflows.com, or email Ben at applescriptguru@mac.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

coconutBattery 3.9.14 - Displays info ab...
With coconutBattery you're always aware of your current battery health. It shows you live information about your battery such as how often it was charged and how is the current maximum capacity in... Read more
Keynote 13.2 - Apple's presentation...
Easily create gorgeous presentations with the all-new Keynote, featuring powerful yet easy-to-use tools and dazzling effects that will make you a very hard act to follow. The Theme Chooser lets you... Read more
Apple Pages 13.2 - Apple's word pro...
Apple Pages is a powerful word processor that gives you everything you need to create documents that look beautiful. And read beautifully. It lets you work seamlessly between Mac and iOS devices, and... Read more
Numbers 13.2 - Apple's spreadsheet...
With Apple Numbers, sophisticated spreadsheets are just the start. The whole sheet is your canvas. Just add dramatic interactive charts, tables, and images that paint a revealing picture of your data... Read more
Ableton Live 11.3.11 - Record music usin...
Ableton Live lets you create and record music on your Mac. Use digital instruments, pre-recorded sounds, and sampled loops to arrange, produce, and perform your music like never before. Ableton Live... Read more
Affinity Photo 2.2.0 - Digital editing f...
Affinity Photo - redefines the boundaries for professional photo editing software for the Mac. With a meticulous focus on workflow it offers sophisticated tools for enhancing, editing and retouching... Read more
SpamSieve 3.0 - Robust spam filter for m...
SpamSieve is a robust spam filter for major email clients that uses powerful Bayesian spam filtering. SpamSieve understands what your spam looks like in order to block it all, but also learns what... Read more
WhatsApp 2.2338.12 - Desktop client for...
WhatsApp is the desktop client for WhatsApp Messenger, a cross-platform mobile messaging app which allows you to exchange messages without having to pay for SMS. WhatsApp Messenger is available for... Read more
Fantastical 3.8.2 - Create calendar even...
Fantastical is the Mac calendar you'll actually enjoy using. Creating an event with Fantastical is quick, easy, and fun: Open Fantastical with a single click or keystroke Type in your event details... Read more
iShowU Instant 1.4.14 - Full-featured sc...
iShowU Instant gives you real-time screen recording like you've never seen before! It is the fastest, most feature-filled real-time screen capture tool from shinywhitebox yet. All of the features you... Read more

Latest Forum Discussions

See All

The iPhone 15 Episode – The TouchArcade...
After a 3 week hiatus The TouchArcade Show returns with another action-packed episode! Well, maybe not so much “action-packed" as it is “packed with talk about the iPhone 15 Pro". Eli, being in a time zone 3 hours ahead of me, as well as being smart... | Read more »
TouchArcade Game of the Week: ‘DERE Veng...
Developer Appsir Games have been putting out genre-defying titles on mobile (and other platforms) for a number of years now, and this week marks the release of their magnum opus DERE Vengeance which has been many years in the making. In fact, if the... | Read more »
SwitchArcade Round-Up: Reviews Featuring...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for September 22nd, 2023. I’ve had a good night’s sleep, and though my body aches down to the last bit of sinew and meat, I’m at least thinking straight again. We’ve got a lot to look at... | Read more »
TGS 2023: Level-5 Celebrates 25 Years Wi...
Back when I first started covering the Tokyo Game Show for TouchArcade, prolific RPG producer Level-5 could always be counted on for a fairly big booth with a blend of mobile and console games on offer. At recent shows, the company’s presence has... | Read more »
TGS 2023: ‘Final Fantasy’ & ‘Dragon...
Square Enix usually has one of the bigger, more attention-grabbing booths at the Tokyo Game Show, and this year was no different in that sense. The line-ups to play pretty much anything there were among the lengthiest of the show, and there were... | Read more »
Valve Says To Not Expect a Faster Steam...
With the big 20% off discount for the Steam Deck available to celebrate Steam’s 20th anniversary, Valve had a good presence at TGS 2023 with interviews and more. | Read more »
‘Honkai Impact 3rd Part 2’ Revealed at T...
At TGS 2023, HoYoverse had a big presence with new trailers for the usual suspects, but I didn’t expect a big announcement for Honkai Impact 3rd (Free). | Read more »
‘Junkworld’ Is Out Now As This Week’s Ne...
Epic post-apocalyptic tower-defense experience Junkworld () from Ironhide Games is out now on Apple Arcade worldwide. We’ve been covering it for a while now, and even through its soft launches before, but it has returned as an Apple Arcade... | Read more »
Motorsport legends NASCAR announce an up...
NASCAR often gets a bad reputation outside of America, but there is a certain charm to it with its close side-by-side action and its focus on pure speed, but it never managed to really massively break out internationally. Now, there's a chance... | Read more »
Skullgirls Mobile Version 6.0 Update Rel...
I’ve been covering Marie’s upcoming release from Hidden Variable in Skullgirls Mobile (Free) for a while now across the announcement, gameplay | Read more »

Price Scanner via MacPrices.net

New low price: 13″ M2 MacBook Pro for $1049,...
Amazon has the Space Gray 13″ MacBook Pro with an Apple M2 CPU and 256GB of storage in stock and on sale today for $250 off MSRP. Their price is the lowest we’ve seen for this configuration from any... Read more
Apple AirPods 2 with USB-C now in stock and o...
Amazon has Apple’s 2023 AirPods Pro with USB-C now in stock and on sale for $199.99 including free shipping. Their price is $50 off MSRP, and it’s currently the lowest price available for new AirPods... Read more
New low prices: Apple’s 15″ M2 MacBook Airs w...
Amazon has 15″ MacBook Airs with M2 CPUs and 512GB of storage in stock and on sale for $1249 shipped. That’s $250 off Apple’s MSRP, and it’s the lowest price available for these M2-powered MacBook... Read more
New low price: Clearance 16″ Apple MacBook Pr...
B&H Photo has clearance 16″ M1 Max MacBook Pros, 10-core CPU/32-core GPU/1TB SSD/Space Gray or Silver, in stock today for $2399 including free 1-2 day delivery to most US addresses. Their price... Read more
Switch to Red Pocket Mobile and get a new iPh...
Red Pocket Mobile has new Apple iPhone 15 and 15 Pro models on sale for $300 off MSRP when you switch and open up a new line of service. Red Pocket Mobile is a nationwide service using all the major... Read more
Apple continues to offer a $350 discount on 2...
Apple has Studio Display models available in their Certified Refurbished store for up to $350 off MSRP. Each display comes with Apple’s one-year warranty, with new glass and a case, and ships free.... Read more
Apple’s 16-inch MacBook Pros with M2 Pro CPUs...
Amazon is offering a $250 discount on new Apple 16-inch M2 Pro MacBook Pros for a limited time. Their prices are currently the lowest available for these models from any Apple retailer: – 16″ MacBook... Read more
Closeout Sale: Apple Watch Ultra with Green A...
Adorama haș the Apple Watch Ultra with a Green Alpine Loop on clearance sale for $699 including free shipping. Their price is $100 off original MSRP, and it’s the lowest price we’ve seen for an Apple... Read more
Use this promo code at Verizon to take $150 o...
Verizon is offering a $150 discount on cellular-capable Apple Watch Series 9 and Ultra 2 models for a limited time. Use code WATCH150 at checkout to take advantage of this offer. The fine print: “Up... Read more
New low price: Apple’s 10th generation iPads...
B&H Photo has the 10th generation 64GB WiFi iPad (Blue and Silver colors) in stock and on sale for $379 for a limited time. B&H’s price is $70 off Apple’s MSRP, and it’s the lowest price... Read more

Jobs Board

Optometrist- *Apple* Valley, CA- Target Opt...
Optometrist- Apple Valley, CA- Target Optical Date: Sep 23, 2023 Brand: Target Optical Location: Apple Valley, CA, US, 92308 **Requisition ID:** 796045 At Target Read more
Senior *Apple* iOS CNO Developer (Onsite) -...
…Offense and Defense Experts (CODEX) is in need of smart, motivated and self-driven Apple iOS CNO Developers to join our team to solve real-time cyber challenges. Read more
*Apple* Systems Administrator - JAMF - Activ...
…**Public Trust/Other Required:** None **Job Family:** Systems Administration **Skills:** Apple Platforms,Computer Servers,Jamf Pro **Experience:** 3 + years of Read more
Child Care Teacher - Glenda Drive/ *Apple* V...
Child Care Teacher - Glenda Drive/ Apple ValleyTeacher Share by Email Share on LinkedIn Share on Twitter Share on Facebook Apply Read more
Machine Operator 4 - *Apple* 2nd Shift - Bon...
Machine Operator 4 - Apple 2nd ShiftApply now " Apply now + Start apply with LinkedIn + Apply Now Start + Please wait Date:Sep 22, 2023 Location: Swedesboro, NJ, US, Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.