TweetFollow Us on Twitter

Providing Progress Feedback During Script Execution

Volume Number: 22 (2006)
Issue Number: 1
Column Tag: Programming

AppleScript Essentials

Providing Progress Feedback During Script Execution

by Benjamin S. Waldie

Many AppleScripts do not provide progress updates to the user during processing. Most of the time, when a script is run, it simply performs the appropriate tasks "behind the scenes," so to speak. If run as an application, a script may appear in the Dock when launched. However, this hardly provides detailed information to the user about what is actually occurring. Sometimes, a script may not need to provide progress updates to the user. However, there are situations when providing such feedback is a good idea.

In this month's column, we will walk through the process of creating a script that will provide visual progress information to the user during processing. The script we will create will save selected email messages in Mail as text files into a user-specified output folder. Since the script will have the ability to process multiple selected email messages, we will write our code to provide a visual indication to the user of which message is currently being processed. Once you learn how to provide this type of feedback, then you can begin integrating this same technique into your other scripts, making them more user friendly.

If you followed along with some of my past AppleScript Essentials columns, then you are probably familiar with AppleScript Studio, a feature set of Xcode and Interface Builder, the Mac OS X developer tools that come with OS X. AppleScript Studio provides a way for developers to build AppleScript-based applications, complete with robust interfaces. In this month's column, we will use AppleScript Studio to add a progress interface to our script, complete with text feedback and a progress bar.

Displaying a Basic Progress Interface with AppleScript

Before we get started with AppleScript Studio, let's discuss how to provide progress information to the user in a non-AppleScript Studio-based script.

In some cases, taking the time to construct an AppleScript Studio application may not be the best solution. For example, your script may be very simple, or it may be an existing script that is too complex to warrant conversion to AppleScript Studio at this time. You may just want a quick and easy way to provide feedback to the user. In these types of situations, the easiest method is to make use of the display dialog command, which can be found in the User Interaction suite of the Standard Additions scripting addition that is installed with Mac OS X.

Using the display dialog command, you can configure a script to display text messages in a no-frills dialog window at various times during script execution. The following example code demonstrates how a display dialog command can be used to provide such feedback.

set theOutputFolder to (choose folder with prompt "Select an output folder:") as string
tell application "Mail"
   set theSelectedMessages to selection
   set theMessageCount to count theSelectedMessages
   repeat with a from 1 to theMessageCount
      display dialog "Processing message " & a & " of " & theMessageCount giving up after 
         1 with icon note
      set theMessageContent to content of item a of theSelectedMessages
      set theArchivePath to theOutputFolder & "Archived Message " & a & ".txt" as string
      set theArchiveFile to open for access theArchivePath with write permission
      set eof of theArchiveFile to 0
      write theMessageContent to theArchiveFile
      close access theArchiveFile
   end repeat
end tell

In the previous code, the first line of the script will prompt the user to select an output folder. Next, the script will retrieve a list of selected email messages in Mail. The script will then proceed to loop through each of these messages. During each repeat loop cycle, the script will retrieve the content of the current message, and save it into a file in the output folder chosen by the user.

As you can see, in order to provide visual feedback to the user during processing, I have made use of a display dialog command within the script's repeat loop. This will cause the script to display a message to the user each time the script begins processing one of the selected email messages. I have configured the display dialog command to indicate the current message count, as well as the total count of selected messages. See figure 1.


Figure 1. A Basic Script Progress Dialog

I have also configured the display dialog command to automatically dismiss the dialog after it has been displayed for 1 second. This will ensure that the script can proceed automatically with further execution, without the user being required to actually click a button in order to proceed.

Upon the successful execution of the previous code, the output folder specified by the user should contain text files containing the contents of the selected email messages. See figure 2.


Figure 2. Archived Email Messages

The display dialog command can also be used independently, rather than within a repeat loop to indicate various tasks that are being performed by the script.

Now that we have discussed providing basic progress information to the user, let's move on to AppleScript Studio. In the remainder of this month's column, we will walk through the process of creating a script that will perform the exact same function as the previous code, only with a more robust interface.

Building the AppleScript Studio Project

You may recall that the first step in building an AppleScript Studio project is to create a new project in Xcode. Begin by launching Xcode.

    Please note that the AppleScript Studio project covered in this article was developed using Mac OS X 10.4.2 and Xcode 2.1. Please be aware that new software versions often result in changes in AppleScript terminology. Therefore, if you are using software versions other than those that I have specified, your required terminology may differ slightly from that which I am using in this article.

    Create a new project by selecting New Project... from the File menu in Xcode. When prompted, select a project type of AppleScript Application from the list of available project templates, enter a project name of Archive Selected Messages, and specify an output folder for the project. Xcode will duplicate the AppleScript Application project template into the specified output folder, and open it for you. See figure 3.


Figure 3. Archive Selected Messages Project Window

Building the Interface

Next, we will create an interface for providing progress information during processing. Double click on the MainMenu.nib file within your Xcode project window. This will open the project's default view in the Interface Builder application.

Designing the Window

By default, the project's interface should already contain an empty window view. This window will be the basis for our interface. Click on the window, and give the window a name by entering Archive Selected Messages Progress into the Window Title field in the Inspector palette. See figure 4. If the Inspector palette is not visible, select Show Inspector from the Tools menu in Interface Builder.


Figure 4. Preparing the Progress Window

Once you have specified the title for the window, de-select the Visible at launch time checkbox in the Inspector palette. This will cause the window to be hidden when the project is first launched.

You may want to make some other adjustments to the window configuration at this time, as well. For example, you may want to disable the ability for the user to close or zoom the window. Refer to figure 4 for the settings that I have specified for my progress window.

Next, click on the Cocoa Controls and Indicators tab in the toolbar of the Palettes window. If the Palettes window is not visible, select Palettes > Show Palettes from the Tools menu. Next, locate an NSProgressIndicator progress bar interface element in the Palettes window, and drag it into your project's window. See figure 5.


Figure 5. Adding an NSProgressIndicator

Next, click on the Cocoa Text Controls button in the toolbar of the Palette window, and drag an NSTextField into your interface window. Enter some default text, such as Waiting to process... into the text field's contents.

Continue to arrange and design the interface, making sure to adhere to Apple's standards for human user interface guidelines, which can be found in the ADC Reference Library, both online and in Xcode's documentation. See figure 6 for an example of my completed interface design.


Figure 6. Example Progress Interface Design

Preparing the Interface for AppleScript Interaction

Once you have finished designing your progress interface, the elements that make up the interface must be prepared to interact with the AppleScript code within your project. To do this, you must assign AppleScript names to various interface elements, as well as configure certain elements of the interface to respond to event handlers.

First, we will assign an AppleScript name to the main window itself. To do this, click on the window to select it. Next, choose AppleScript from the popup button at the top of the Inspector palette, and enter the name Progress Window into the Name field. See figure 7. The process of assigning AppleScript names to the other interface elements will be the same.


Figure 7. Assigning an AppleScript Name to the Progress Window

Select the progress indicator bar and text field in the window, and assign AppleScript names of Progress Bar and Progress Text, respectively.

As the last step in configuring the progress interface, we must configure the solution to run our AppleScript code when launched. This will be done by enabling an event handler. To do this, first select File's Owner in the MainMenu.nib window. A list of available event handlers will be visible on the Inspector palette, beneath the Name field. Enable the launched event handler by selecting its checkbox in the list of event handlers. Next, link the event handler to the AppleScript code in your project by selecting the checkbox next to Archive Selected Messages.applescript in the Script area at the bottom of the Inspector palette, beneath the event handler list. See figure 8.


Figure 8. Enabling the Launched Event Handler

Adding the AppleScript code

Now that you have configured your interface, it is time to begin adding the AppleScript code into your project. Return to Xcode, and double click on Archive Selected Messages.applescript file in your project to begin editing the AppleScript code.

Preparing the Launched Event Handler

Since we configured our interface to respond to the launched event handler, we will need to add this handler to our project's code. If you saved your project's interface in Interface Builder, then this code may have been automatically inserted for you within your main project script in Xcode. If it does not exist, enter it as follows:

on launched theObject

end launched

Any code that is entered into this launched handler will be executed when our project application is launched. As we proceed, enter all code below within the launched handler.

Get the Output Folder

It is now time to begin adding the processing code to our project. Begin by entering the following code, which will prompt the user to select an output folder. Take note that this code is identical to that used in our non-AppleScript Studio example.

set theOutputFolder to (choose folder with prompt "Select an output folder:") as string

Get the Selected Messages

Next, add the following code, which will retrieve a list of any selected email messages in Mail, and will then count the detected messages.

tell application "Mail"
   set theSelectedMessages to selection
end tell
set theMessageCount to count theSelectedMessages

Show the Progress Window

You may recall that we configured our progress window to not be visible on launch. The following code will now make this window visible to the user.

set visible of window "Progress Window" to true

Prepare the Progress Bar

We are now ready to begin preparing the progress bar within our window. First, we will set the maximum value property of the progress bar to the number of detected email messages.

set maximum value of progress indicator "Progress Bar" of window 
   "Progress Window" to theMessageCount

Next, in order to ensure that our progress bar will display incremental progress, we will set the indeterminate property of the progress bar to a value of false. A progress bar with an indeterminate property value of true will appear as a blue and white striped bar, as can be seen in figure 6, and this is not desirable for providing incremental progress.

set indeterminate of progress indicator "Progress Bar" of window 
   "Progress Window" to false

Looping Through the Selected Messages

We will now add code to loop through the selected email messages. Enter the following code into the script:

repeat with a from 1 to theMessageCount

end repeat

Updating the Progress Text

The following code should be added immediately within the repeat statement. It will update the text field in our interface to indicate the current message being processed. As in our non-AppleScript Studio example, this text will tell the user the current message count, as well as the total message count.

set contents of text field "Progress Text" of window "Progress Window" to 
   "Processing message " & a & " of " & theMessageCount

Getting the Current Message's Contents

Next, add the code below, which will retrieve the content of the current email message.

tell application "Mail"
      set theMessageContent to content of item a of theSelectedMessages
end tell

Saving the Contents to a File

Again, using the exact code from our non-AppleScript Studio example, add the following to your script. This code will write the content of the current message to a text file in the specified output folder.

set theArchivePath to theOutputFolder & "Archived Message " & a & ".txt" as string
set theArchiveFile to open for access theArchivePath with write permission
set eof of theArchiveFile to 0
write theMessageContent to theArchiveFile
close access theArchiveFile

Updating the Progress Bar

Finally, for the last section of code within the repeat loop, add the following code. This code will set the content of the progress bar to the current repeat loop increment, thus increasing the progress bar's display to accurately reflect the current number of messages processed.

set content of progress indicator "Progress Bar" of window "Progress Window" to a
update window "Progress Window"

Please note that the last line in the preceding code will update the window, ensuring that the progress bar's interface is refreshed each time its content value is changed.

Completing the Code

To complete the handler, add a quit command at the end of the handler, just outside of the repeat statement. This will ensure that the application quits, once processing is complete.

quit

Next, wrap all of the code within the handler inside of a try statement, configured as follows:

try

on error theErrorMessage number theErrorNumber
   if theErrorNumber = -128 then quit
   error theErrorMessage number theErrorNumber
end try

This try statement will trap for a user cancelled error, error number -128, which would occur if the user clicks the Cancel button when prompted to select an output folder.

Now that your script is complete, the following example code shows how the completed launched handler should appear within your main project script.

on launched theObject
   try
      set theOutputFolder to (choose folder with prompt "Select an 
         output folder:") as string
      tell application "Mail"
         set theSelectedMessages to selection
      end tell
      set theMessageCount to count theSelectedMessages
      set visible of window "Progress Window" to true
      set maximum value of progress indicator "Progress Bar" of window 
         "Progress Window" to theMessageCount
      set indeterminate of progress indicator "Progress Bar" of window 
         "Progress Window" to false
      repeat with a from 1 to theMessageCount
         set contents of text field "Progress Text" of window "Progress Window" 
            to "Processing message " & a & " of " & theMessageCount
         tell application "Mail"
            set theMessageContent to content of item a of theSelectedMessages
         end tell
         set theArchivePath to theOutputFolder & "Archived Message " & a & ".txt" as string
         set theArchiveFile to open for access theArchivePath with write permission
         set eof of theArchiveFile to 0
         write theMessageContent to theArchiveFile
         close access theArchiveFile
         set content of progress indicator "Progress Bar" of window "Progress Window" to a
         update window "Progress Window"
      end repeat
      quit
   on error theErrorMessage number theErrorNumber
      if theErrorNumber = -128 then quit
      error theErrorMessage number theErrorNumber
   end try
end launched

Testing the Project

Now that our project is complete, it is ready for testing. To test the project, first launch Mail, and select multiple email messages. For best results, you may want to select a large number of messages, in order to ensure that the progress bar will increment properly. Next, select Build and Run from the Build menu in Xcode. If everything works as expected, your solution should launch, and you should be prompted to select an output folder. After choosing a folder, the project's interface should be displayed, and the selected messages should be processed and saved into the specified output folder.


Figure 9. The Completed Progress Interface

Other Options

In AppleScript Studio, a progress indicator may be displayed as a bar, as we have seen. However, a progress indicator may also be displayed as a spinner. See figure 10.


Figure 10. Example of a Progress Spinner

A progress spinner may be useful in situations where your code does not warrant providing incremental feedback to the user, yet you still wish to indicate that processing is occurring.

In Closing

The project discussed in this month's column should give you some basic ways to implement progress feedback in your scripts. Now, it is up to you to begin making your scripts more user friendly by providing such feedback to your users.

If you have difficulty getting any of the specified code to work, or if you prefer to review the actual project files, you may wish to download the example code. I have made the sample project discussed in this article available for download from my web site at the following URL:

http://www.automatedworkflows.com/files/demos/MacTECH.01.06.Example.zip

Until next time, keep scripting!


Ben Waldie is author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from http://www.spiderworks.com. Ben is also president of Automated Workflows, LLC, a firm specializing in AppleScript and workflow automation consulting. For years, Ben has developed professional AppleScript-based solutions for businesses including Adobe, Apple, NASA, PC World, and TV Guide. For more information about Ben, please visit http://www.automatedworkflows.com, or email Ben at applescriptguru@mac.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

MacPilot 15.0.2 - $15.96 (53% off)
MacPilot gives you the power of UNIX and the simplicity of Macintosh, which means a phenomenal amount of untapped power in your hands! Use MacPilot to unlock over 1,200 features, and access them all... Read more
Visual Studio Code 1.85.0 - Cross-platfo...
Visual Studio Code provides developers with a new choice of developer tool that combines the simplicity and streamlined experience of a code editor with the best of what developers need for their... Read more
Spotify 1.2.26.1187 - Stream music, crea...
Spotify is a streaming music service that gives you on-demand access to millions of songs. Whether you like driving rock, silky R&B, or grandiose classical music, Spotify's massive catalogue puts... Read more
Transmission 4.0.5 - Popular BitTorrent...
Transmission is a fast, easy, and free multi-platform BitTorrent client. Transmission sets initial preferences so things "just work", while advanced features like watch directories, bad peer blocking... Read more
Fantastical 3.8.9 - Create calendar even...
Fantastical is the Mac calendar you'll actually enjoy using. Creating an event with Fantastical is quick, easy, and fun: Open Fantastical with a single click or keystroke Type in your event details... Read more
Notion 3.0.0 - A unified workspace for m...
Notion is the unified workspace for modern teams. Features: Integration with Slack Documents Wikis Tasks Release notes were unavailable when this listing was updated. Download Now]]> Read more
GarageBand 10.4.10 - Complete recording...
GarageBand is the easiest way to create a great-sounding song on your Mac. Add realistic, impeccably produced and performed drum grooves to your song with Drummer. Easily shape the sound of any... Read more
Pacifist 4.1.0 - Install individual file...
Pacifist opens up .pkg installer packages, .dmg disk images, .zip, .tar. tar.gz, .tar.bz2, .pax, and .xar archives and more, and lets you extract or install individual files out of them. This is... Read more
Xcode 15.0.1 - Integrated development en...
Xcode includes everything developers need to create great applications for Mac, iPhone, iPad, and Apple Watch. Xcode provides developers a unified workflow for user interface design, coding, testing... Read more
Google Chrome 120.0.6099.62 - Modern and...
Google Chrome is a Web browser by Google, created to be a modern platform for Web pages and applications. It utilizes very fast loading of Web pages and has a V8 engine, which is a custom built... Read more

Latest Forum Discussions

See All

TouchArcade Game of the Week: ‘Sonic Dre...
I can still remember the time I played my first 3D Sonic game. It was at Hollywood Video (that’s a video rental store for you young ones out there) and my buddy was the manager, and he invited me and my friend to hang out in the store after they... | Read more »
SwitchArcade Round-Up: Strictly Limited...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for December 8th, 2023. In today’s article, we start off with a couple of news items. Nothing from The Game Awards, that’s a bit beyond the scope of what I usually do here. But I do have... | Read more »
Football Manager 2024 Interview – We Tal...
Last month, SEGA and Sports Interactive released Football Manager 2024 on Apple Arcade (Touch), Netflix (Mobile), consoles, PC, and even Game Pass. If you missed my detailed review covering many versions of the game, read it here. | Read more »
‘Shiren the Wanderer: The Mystery Dungeo...
Recently, my son and I were invited to attend a special hands-on preview event at Spike Chunsoft’s headquarters in Tokyo to play the upcoming Shiren the Wanderer: The Mystery Dungeon of Serpentcoil Island for Nintendo Switch, which is scheduled for... | Read more »
Apple Arcade Weekly Round-Up: Updates fo...
We just had a huge content drop on Apple Arcade earlier this week with Sonic Dream Team, Disney Dreamlight Valley, Puzzles and Dragons, and more hitting the service. Today (and as of a few days ago), many notable games on the service have gotten... | Read more »
‘Genshin Impact’ Version 4.3 Update “Ros...
Following two trailers during The Game Awards 2023, HoYoverse has more news today with the next major Genshin Impact (Free) update detailed for all platforms. | Read more »
Christmas comes to Pokemon Unite, closel...
It's time to swap your Pokeballs for snowballs as a new festive mode has launched in The Pokemon Company International’s 5v5 MOBA Pokemon Unite. The presents don't stop there, however, as a brand new challenger is entering the arena, all the way... | Read more »
What to expect in World of Tanks Blitz’s...
World of Tanks Blitz is updating that old story of Santa sneaking down your chimney and silently leaving presents like a jolly old ninja into something a little more modern. Vinnie Jones has traded the sleigh for a tank and is ringing in the... | Read more »
‘Arknights: Endfield’ From Gryphline Get...
Last year, Arknights developer Hypergryph announced Arknights: Endfield for mobile and PC platforms. Arknights: Endfield is a 3D real-time RPG with strategic elements set in the world of Arknights. | Read more »
‘Zenless Zone Zero’ TGA 2023 Trailer Con...
During The Game Awards 2023, HoYoverse had two trailers. The first was a quick recap video for Honkai Star Rail with a tease of things to come next year. It continues to look superb. The highlight was urban fantasy action RPG Zenless Zone Zero... | Read more »

Price Scanner via MacPrices.net

Update: Apple Watch Series 9 models now $70 o...
Walmart has Apple Watch Series 9 models on Holiday sale for $70 off MSRP on their online store this weekend (that’s $20 cheaper than their earlier price). Sale prices available for online orders only... Read more
Apple’s AirTags 4-Pack is on Holiday sale for...
Apple retailers have 4-pack AirTags on sale this weekend for $19 off MSRP as part of their Holiday sales. These make a great stocking stuffer: (1): Amazon has Apple AirTags 4 Pack on sale for $79.99... Read more
Sunday Sale: $100 off every Apple iPad mini 6
Amazon is offering Apple’s 8.3″ iPad minis for $100 off MSRP, including free shipping, as part of their Holiday sale this weekend. Prices start at $399. Amazon’s prices are the lowest currently... Read more
16-inch M3 Pro MacBook Pros (18GB/512GB) are...
Looking for the best price on a 16″ M3 Pro MacBook Pro this Holiday shopping season? B&H and Amazon are currently offering a $250 discount on the 16″ M3 Pro MacBook Pro (18GB RAM/512GB SSD),... Read more
Apple Watch SE models on Holiday sale for $50...
Walmart has Apple Watch SE GPS-only models on Holiday sale on their online store for $50 off MSRP this weekend. Sale prices for online orders only, in-store prices may vary. Order online, and choose... Read more
Apple Watch Series 9 models on Holiday sale t...
Walmart has Apple Watch Series 9 models on Holiday sale for $50 off MSRP on their online store this weekend. Sale prices available for online orders only, in-store prices may vary. Order online, and... Read more
Apple has the 13-inch M2 MacBook Air in stock...
Apple has Certified Refurbished 13″ M2 MacBook Airs available starting at only $929 and ranging up to $210 off MSRP. These are the cheapest M2-powered MacBooks for sale at Apple. Apple’s one-year... Read more
Apple’s 10th-generation iPads on Holiday sale...
Amazon has Apple’s 10th-generation WiFi iPads on sale for $100 off MSRP, starting at only $349, as part of their Holiday sales this weekend. With the discount, Amazon’s prices are the lowest we’ve... Read more
Apple Watch Series 9 models Holiday sale this...
Amazon has Apple Watch Series 9 models on sale for up to $90 off MSRP, each including free shipping, as part of their Holiday sale this weekend. Stock is likely to come and go at Amazon, so check... Read more
Apple Watch Ultra 2 models on Holiday sale th...
Amazon is offering a $50 discount on Apple Watch Ultra 2 models as part of their Holiday sale this weekend. Their price is now $749 for most models. Shipping is free. Amazon’s price is the lowest... Read more

Jobs Board

Principal Offering Sales - Modern Workplace...
…Job Description **Who you are** + **Drives Modern Workplace sale, focusing on Apple Managed Services across the enterprise globally.** + **Owns the Apple Read more
Material Handler 1 - *Apple* (1st shift) -...
Material Handler 1 - Apple (1st shift)Apply now " Apply now + Start apply with LinkedIn + Apply Now Start + Please wait Date:Dec 8, 2023 Location: Irwindale, CA, US, Read more
Macintosh/ *Apple* Systems Administrator, TS...
…to a team-based environment. + Perform systems administration support tasks for Apple MacOS and iOS operating systems. + TDY travel (approximately 25%) for Read more
Principal Offering Sales - Modern Workplace...
…Job Description **Who you are** + **Drives Modern Workplace sale, focusing on Apple Managed Services across the enterprise globally.** + **Owns the Apple Read more
*Apple* Systems Administrator - JAMF - Activ...
…**Public Trust/Other Required:** None **Job Family:** Systems Administration **Skills:** Apple Platforms,Computer Servers,Jamf Pro **Experience:** 3 + years of Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.