TweetFollow Us on Twitter

What's New With AppleScript In Tiger

Volume Number: 21 (2005)
Issue Number: 5
Column Tag: Programming

AppleScript Essentials

What's New With AppleScript In Tiger

by Benjamin S. Waldie

Lately, there has been a lot of buzz about Tiger, the latest version of Mac OS X. This new operating system version is full of new features and other goodies. With new applications and utilities like Dashboard, Spotlight, and Automator, Tiger is breathing still more new life into the steadily maturing Mac OS X.

While many of the new features in Tiger are geared toward the user level, there is also plenty that is new under the hood for developers. For AppleScripters, Tiger brings with it a number of bug fixes and new features with the latest release of AppleScript, version 1.10. In this month's article, we will walk through a number of these changes and enhancements.

AppleScript Bug Fixes

Like most operating system updates, Tiger offers AppleScript developers a number of bug fixes. Let's touch briefly on a few of these, and then we will move on to the exciting stuff, the new AppleScript-related features in the OS. In addition to a number of others, the following bug fixes have been introduced in Tiger:

  • Memory leaks in both AppleScript itself, as well as in the Standard Additions scripting addition have been fixed
  • AppleScript has been updated to allow for compiling larger scripts, as well as generating larger static lists.
  • In Mac OS X 10.3, retrieving the POSIX path of a string that is already in the POSIX file format would produce the incorrect result. This has now been fixed. For example:

Under Mac OS X 10.3, Panther:

POSIX path of "/Users/bwaldie/Desktop/"
--> "/:Users:bwaldie:Desktop:"

Under Mac OS X 10.4, Tiger:

POSIX path of "/Users/bwaldie/Desktop/"
--> "/Users/bwaldie/Desktop/"

A slew of other bug fixes have also been introduced with Tiger. For a comprehensive list of bug fixes, view the AppleScript Release Notes, available in the Apple Developer Connection Library. Also, if you encounter a bug with AppleScript, or any other Apple technology for that matter, be sure to submit it via the bug reporter website at http://bugreport.apple.com. You will need to have at least an online ADC membership to log into this website.

New AppleScript Features

While bug fixes are exciting in their own special way, the real fun comes with all of the new AppleScript features and additions in Tiger. Throughout the remainder of this month's article, we will discuss a handful of these new features. Let's start with Script Editor.

Script Editor Enhancements

With the release of Mac OS X 10.3, Apple introduced a new and improved Script Editor, version 2.0, a long awaited and much needed upgrade from its predecessor. With Tiger, Apple continues to expand the functionality in Script Editor with the release of version 2.1.

In the latest version of Script Editor, you will find an enhanced version of the Script Assistant, which helps to auto-complete your code as you type. Enabling this feature in Script Editor's preferences now no longer requires that you re-launch Script Editor to begin using the feature. In addition, the latest rendition of this feature is now able to auto-complete variables and handler names.


Figure 1. Handler Call Auto-Completion Using the Script Assistant

You may recall that Mac OS X 10.3 introduced the ability to save AppleScript files in bundle format. By saving a script as a bundle, required resources could be embedded directly into the script's bundle via the Finder, eliminating the need for the script to locate and access external required components. Script Editor 2.1 takes script bundles a step further, by allowing you to actually edit the contents of a bundle from directly within Script Editor.

When editing a script that has been saved as a bundle, click the Bundle Contents button in the script window's toolbar. The contents of the bundle will be displayed in a drawer attached to the window. New components can be added to the script bundle by simply dragging and dropping them directly into the bundle contents drawer. Bundle components may also be deleted, renamed, opened, and duplicated from within the drawer.


Figure 2. Bundle Contents Drawer

Possibly the most exciting and visible feature of the latest version of Script Editor is a new AppleScript dictionary browser layout. This new layout offers a completely redesigned way to navigate AppleScript dictionaries.


Figure 3. New Script Editor Dictionary Browser

Viewing an AppleScript dictionary in this new browser display may seem a little confusing at first glance. However, you will quickly find that the new format is actually quite easy to use, and contains a number of benefits over previous dictionary browsers. Before long, you will wonder how you ever worked without it.

At the top of the dictionary browser, you will find a toolbar, complete with navigation buttons and a search field for performing quick terminology searches. If desired, the toolbar may be custom configured, or hidden entirely.

With adjustable navigation panes, the dictionary browser window itself may be configured for navigation using columns, or in the familiar list view format of previous script editors. By collapsing and expanding the panes of the browser, you can design the layout to a look and feel that is comfortable for you. Once you have finished customizing the layout of the dictionary browser to your liking, select Save as Default from the Window menu, and all future dictionary browsers will open using your custom configuration.

While navigating a dictionary in column view, the dictionary's terminology will be displayed in suites by default. Selecting a suite will display a list of commands and classes within that suite. Optionally, you may choose to view a dictionary by its class containment or inheritance, allowing you to gain an understanding of the class hierarchy within the dictionary. This can be done by clicking the desired view button in the toolbar.


Figure 4. Viewing a Dictionary by Containment

As you explore the new dictionary browser, you will notice that each term in the navigation panes is preceded by a color-coded, labeled icon. These icons indicate the type of term. For example:

  • An orange square containing the letter S indicates a suite
  • A blue circle containing the letter C indicates a command
  • A purple square containing the letter C indicates a class
  • A purple square containing the letter P indicates a property
  • An orange square containing the letter E indicates an element

Another very exciting feature of Script Editor's new dictionary browser is that hyperlinks now provide quick and easy one-click navigation between related terms. For example, you can select a class in a dictionary, and click on one of its elements to go directly to that element.

In Tiger, developers can now even choose to enhance their product's AppleScript dictionaries by including comprehensive HTML-based documentation, which can even include example scripts and URL's, all contained and viewable within the dictionary itself! Hopefully, developers will be quick to adopt this new functionality. One application that is already taking advantage of this new capability is PreFab Software's UI Actions. The AppleScript dictionary for the latest release of UI Actions includes extensive documentation, along with sample code to get scripters up and running in no time.


Figure 5. PreFab UI Actions Dictionary with HTML Documentation

PreFab UI Actions provides AppleScript developers with a way to universally attach scripts to almost any application. UI Actions can be configured to trigger scripts when users click buttons in an application's interface, select menu items, open a window, and much more. Find out more about Prefab UI Actions, or download a 30-day trial version at http://www.prefab.com/uiactions/.

AppleScript Utility

Outside of Script Editor, Tiger also includes a number of other new AppleScript-related features. One such feature is a new AppleScript Utility application, which provides a central location for performing a number of system-wide AppleScript-related tasks, such as changing your default script editor, enabling GUI scripting or the Script Menu, or working with Folder Actions. This utility can be found in the Applications > AppleScript folder.


Figure 6. AppleScript Utility Application

New Standard Addition Commands

Tiger also brings with it some new and enhanced AppleScript terminology. Some of this new terminology can be found in the Standard Additions scripting addition.

In the User Interaction suite of the Standard Additions scripting addition, a command for displaying a new type of interface dialog has been added. A new display alert command will allow a system alert message to be displayed to the user. This command has a number of configurable parameters, including the text to be displayed, the level of the alert, and the names of the buttons. The following is an example of code that will display a basic alert dialog:

display alert "An error has occurred." message "Document could not be found." as warning


Figure 7. Display Alert Dialog

The display dialog command in the Standard Additions scripting addition has always been a popular way of displaying a basic message, or requesting text input from the user during the execution of a script, without the need to design a full-blown AppleScript Studio application. However, one thing that the display dialog command has lacked is the ability to hide text entered by the user... until now. Tiger features an updated display dialog command, which now includes a hidden answer parameter, allowing text entered by the user to be displayed as bullets. For example:

display dialog "Please enter your secret access key:" default answer "" with hidden answer


Figure 8. Display Dialog with a Hidden Answer

While other new commands and terminology are available in Tiger, the last one that I want to mention in this article is the new system info command. This command, which can be found in the Miscellaneous Commands suite in the Standard Additions scripting addition, will retrieve a variety of information about the current system configuration, including the system version, current user name, IP address, and more. For example:

system info
--> {AppleScript version:"1.10", AppleScript Studio version:"1.4", 
system version:"10.4", short user name:"bwaldie", long user name:"Ben Waldie", 
user ID:501, user locale:"en_US", home directory:alias "Macintosh HD:Users:bwaldie:", 
boot volume:"Macintosh HD", computer name:"Ben Waldie's iMac G5", host 
name:"ben-waldies-imac-g5.local", IPv4 address:"192.168.2.5", primary Ethernet 
address:"00:11:24:70:db:be", CPU type:"PowerPC 970", 
CPU speed:1599, physical memory:768}

System Events

You may already be familiar with the System Events application in Mac OS X. This application provides a central location for performing system-related tasks with AppleScript. In the past, System Events has been primarily used by developers to interact with non-scriptable application interfaces via a Processes Suite, also known as GUI scripting. In Tiger, System Events' AppleScript dictionary has been expanded with some new suites of classes and commands, which are sure to become quite popular as well.

A new QuickTime File Suite, Movie File Suite, and Audio File Suite offer developers a way to access basic information about digital media files, without the need to open those media files in an associated application, such as QuickTime or iTunes. For example, the following code will retrieve information about a specified movie file.

set theMovie to (choose file of type "MooV") as string
tell application "System Events"
   properties of contents of movie file theMovie
end tell

--> {modification time:date "Wednesday, January 31, 2001 12:30:38 AM", stored 
stream:false, auto present:false, time scale:600, preferred volume:255, class:movie 
data, auto quit when done:false, bounds:{0, 0, 240, 180}, resizable:stop, 
looping:false, natural dimensions:{0, 0, 240, 180}, presentation mode:stop, 
data size:5816280, href:"file://localhost/Users/bwaldie/Desktop/starwars.mov", 
creation time:date "Wednesday, January 31, 2001 12:30:34 AM", preferred rate:65536, 
auto play:false, duration:26152, preview duration:0, preview time:0}

A new XML Suite in System Events provides a way to extract data from an XML file, without the need to write complex parsing code, or resort to using a scripting addition. In addition, a new Property List Suite can be used to quickly and easily extract and set property item values in property list files. For example, the following code will determine whether tabbed browsing is enabled in Safari, by extracting the value of the appropriate property in Safari's property list file.

set thePropertyListFile to (path to preferences as string) & "com.apple.Safari.plist"
tell application "System Events"
   value of property list item "TabbedBrowsing" of contents of property list file 
      thePropertyListFile
end tell

--> true

Database Events

One feature that is sure to generate a lot of excitement in the AppleScript community is the new Database Events background application. This application, which is located in System > Library > CoreServices, can be used to programmatically generate SQL databases. This capability opens up a whole new world of possibilities for AppleScripters who need a place to store data when running a script. Rather than storing data in a property, or writing it to a text file, it can now be added to an SQL database, directly from AppleScript.

For example, the following code will create a new SQL database in memory, and add two records with fields containing user data. The script will then locate the record whose last name field matches my last name, "Waldie".

tell application "Database Events"
   set myDatabase to make new database with properties {name:"My Database"}
   tell myDatabase
      set myFirstRecord to make new record with properties {name:"User Entry"}
      tell myFirstRecord
         make new field with properties {name:"FirstName", value:"Ben"}
         make new field with properties {name:"LastName", value:"Waldie"}
      end tell
      set mySecondRecord to make new record with properties {name:"User Entry"}
      tell mySecondRecord
         make new field with properties {name:"FirstName", value:"John"}
         make new field with properties {name:"LastName", value:"Smith"}
      end tell
      return every record whose value of field "LastName" = "Waldie"
   end tell
end tell

--> {record id 137689274 of database "My Database" of application "Database Events"}

A database that is created or loaded in memory using Database Events will remain opened until it you close it using the close command, or until the Database Events application quits. When idle, Database Events will automatically quit after 5 minutes of inactivity. However, this amount of time may be extended or reduced by modifying the quit delay property of the Database Events application. For example, the following code sets Database Events to idle for 600 seconds, or 10 minutes, before quitting.

tell application "Database Events"
   set quit delay to 600
end tell

You may also choose to save a database using the save command in Database Events. By default, databases are saved into a Documents > Databases folder within your user folder. However, you may specify a different path, if desired, by specifying a folder path in the location property of a database. For example, the following code will create a database, and then save it to the desktop:

tell application "Database Events"
   set myDatabase to make new database with properties {name:"My Database", 
      location:path to desktop}
   save myDatabase
end tell

Database Events is shaping up to be a very useful tool for AppleScript developers. Personally, I have only just started using it, but I can already see new possibilities for how I store and access data from within my scripts.

AppleScript Studio

In addition to changes made to AppleScript in general in Tiger, AppleScript Studio has also undergone some changes as well. For developers creating projects in AppleScript Studio, you will find improvements to data views and drag and drop, support for compiled scripts in Xcode projects, an enhanced code assistant, an updated dictionary browser, and more.

Probably the most significant enhancement to AppleScript Studio, though, is the ability to create Automator actions. When creating a new project in Xcode, a new template exists for an AppleScript-based Automator action. Using this template, developers can quickly build customized Automator actions, primarily using AppleScript.

Next month's article will provide an introduction to AppleScript Studio, for those that have not yet gotten their feet wet. The following month, we will discuss the steps involved in building a custom AppleScript-based Automator action, using AppleScript Studio.

In Closing

As you can see, the AppleScript team at Apple has continued to add great new features and enhancements to AppleScript with yet another release of Mac OS X. The topics covered in this article really only scratch the surface of these changes. For a comprehensive list of enhancements and bug fixes, be sure to check out the AppleScript release notes and the AppleScript Studio release notes. These documents can be found in the Apple Developer Connection Library at http://developer.apple.com/releasenotes/applescript/.

Also, some features, like Database Events and System Events changes, have not been listed in the release notes. So, be sure to explore Tiger on your own, and begin learning about this, and other exciting new AppleScript capabilities.

Until next time, keep scripting!


Benjamin Waldie, author of the best selling books "AppleScripting the Finder" and the "Mac OS X Technology Guide to Automator", available from www.spiderworks.com, is president of Automated Workflows, LLC, a firm specializing in AppleScript and workflow automation consulting. For years, Benjamin has developed professional AppleScript-based solutions for businesses including Adobe Systems, Apple Computer, NASA, PC World, and TV Guide. In addition to his role as a consultant, Benjamin is an evangelist of AppleScript, and can frequently be seen presenting at Macintosh User Groups, Macworld, and other events. For additional information about Benjamin, please visit www.automatedworkflows.com, or email Benjamin at applescriptguru@mac.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Latest Forum Discussions

See All

Summon your guild and prepare for war in...
Netmarble is making some pretty big moves with their latest update for Seven Knights Idle Adventure, with a bunch of interesting additions. Two new heroes enter the battle, there are events and bosses abound, and perhaps most interesting, a huge... | Read more »
Make the passage of time your plaything...
While some of us are still waiting for a chance to get our hands on Ash Prime - yes, don’t remind me I could currently buy him this month I’m barely hanging on - Digital Extremes has announced its next anticipated Prime Form for Warframe. Starting... | Read more »
If you can find it and fit through the d...
The holy trinity of amazing company names have come together, to release their equally amazing and adorable mobile game, Hamster Inn. Published by HyperBeard Games, and co-developed by Mum Not Proud and Little Sasquatch Studios, it's time to... | Read more »
Amikin Survival opens for pre-orders on...
Join me on the wonderful trip down the inspiration rabbit hole; much as Palworld seemingly “borrowed” many aspects from the hit Pokemon franchise, it is time for the heavily armed animal survival to also spawn some illegitimate children as Helio... | Read more »
PUBG Mobile teams up with global phenome...
Since launching in 2019, SpyxFamily has exploded to damn near catastrophic popularity, so it was only a matter of time before a mobile game snapped up a collaboration. Enter PUBG Mobile. Until May 12th, players will be able to collect a host of... | Read more »
Embark into the frozen tundra of certain...
Chucklefish, developers of hit action-adventure sandbox game Starbound and owner of one of the cutest logos in gaming, has released their roguelike deck-builder Wildfrost. Created alongside developers Gaziter and Deadpan Games, Wildfrost will... | Read more »
MoreFun Studios has announced Season 4,...
Tension has escalated in the ever-volatile world of Arena Breakout, as your old pal Randall Fisher and bosses Fred and Perrero continue to lob insults and explosives at each other, bringing us to a new phase of warfare. Season 4, Into The Fog of... | Read more »
Top Mobile Game Discounts
Every day, we pick out a curated list of the best mobile discounts on the App Store and post them here. This list won't be comprehensive, but it every game on it is recommended. Feel free to check out the coverage we did on them in the links below... | Read more »
Marvel Future Fight celebrates nine year...
Announced alongside an advertising image I can only assume was aimed squarely at myself with the prominent Deadpool and Odin featured on it, Netmarble has revealed their celebrations for the 9th anniversary of Marvel Future Fight. The Countdown... | Read more »
HoYoFair 2024 prepares to showcase over...
To say Genshin Impact took the world by storm when it was released would be an understatement. However, I think the most surprising part of the launch was just how much further it went than gaming. There have been concerts, art shows, massive... | Read more »

Price Scanner via MacPrices.net

AT&T has the iPhone 14 on sale for only $...
AT&T has the 128GB Apple iPhone 14 available for only $5.99 per month for new and existing customers when you activate unlimited service and use AT&T’s 36 month installment plan. The fine... Read more
Amazon is offering a $100 discount on every M...
Amazon is offering a $100 instant discount on each configuration of Apple’s new 13″ M3 MacBook Air, in Midnight, this weekend. These are the lowest prices currently available for new 13″ M3 MacBook... Read more
You can save $300-$480 on a 14-inch M3 Pro/Ma...
Apple has 14″ M3 Pro and M3 Max MacBook Pros in stock today and available, Certified Refurbished, starting at $1699 and ranging up to $480 off MSRP. Each model features a new outer case, shipping is... Read more
24-inch M1 iMacs available at Apple starting...
Apple has clearance M1 iMacs available in their Certified Refurbished store starting at $1049 and ranging up to $300 off original MSRP. Each iMac is in like-new condition and comes with Apple’s... Read more
Walmart continues to offer $699 13-inch M1 Ma...
Walmart continues to offer new Apple 13″ M1 MacBook Airs (8GB RAM, 256GB SSD) online for $699, $300 off original MSRP, in Space Gray, Silver, and Gold colors. These are new MacBook for sale by... Read more
B&H has 13-inch M2 MacBook Airs with 16GB...
B&H Photo has 13″ MacBook Airs with M2 CPUs, 16GB of memory, and 256GB of storage in stock and on sale for $1099, $100 off Apple’s MSRP for this configuration. Free 1-2 day delivery is available... Read more
14-inch M3 MacBook Pro with 16GB of RAM avail...
Apple has the 14″ M3 MacBook Pro with 16GB of RAM and 1TB of storage, Certified Refurbished, available for $300 off MSRP. Each MacBook Pro features a new outer case, shipping is free, and an Apple 1-... Read more
Apple M2 Mac minis on sale for up to $150 off...
Amazon has Apple’s M2-powered Mac minis in stock and on sale for $100-$150 off MSRP, each including free delivery: – Mac mini M2/256GB SSD: $499, save $100 – Mac mini M2/512GB SSD: $699, save $100 –... Read more
Amazon is offering a $200 discount on 14-inch...
Amazon has 14-inch M3 MacBook Pros in stock and on sale for $200 off MSRP. Shipping is free. Note that Amazon’s stock tends to come and go: – 14″ M3 MacBook Pro (8GB RAM/512GB SSD): $1399.99, $200... Read more
Sunday Sale: 13-inch M3 MacBook Air for $999,...
Several Apple retailers have the new 13″ MacBook Air with an M3 CPU in stock and on sale today for only $999 in Midnight. These are the lowest prices currently available for new 13″ M3 MacBook Airs... Read more

Jobs Board

Relationship Banker - *Apple* Valley Financ...
Relationship Banker - Apple Valley Financial Center APPLE VALLEY, Minnesota **Job Description:** At Bank of America, we are guided by a common purpose to help Read more
IN6728 Optometrist- *Apple* Valley, CA- Tar...
Date: Apr 9, 2024 Brand: Target Optical Location: Apple Valley, CA, US, 92308 **Requisition ID:** 824398 At Target Optical, we help people see and look great - and Read more
Medical Assistant - Orthopedics *Apple* Hil...
Medical Assistant - Orthopedics Apple Hill York Location: WellSpan Medical Group, York, PA Schedule: Full Time Sign-On Bonus Eligible Remote/Hybrid Regular Apply Now Read more
*Apple* Systems Administrator - JAMF - Activ...
…**Public Trust/Other Required:** None **Job Family:** Systems Administration **Skills:** Apple Platforms,Computer Servers,Jamf Pro **Experience:** 3 + years of Read more
Liquor Stock Clerk - S. *Apple* St. - Idaho...
Liquor Stock Clerk - S. Apple St. Boise Posting Begin Date: 2023/10/10 Posting End Date: 2024/10/14 Category: Retail Sub Category: Customer Service Work Type: Part Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.