TweetFollow Us on Twitter

Using Repeat Loops in AppleScript

Volume Number: 20 (2004)
Issue Number: 12
Column Tag: Programming

AppleScript Essentials

by Benjamin S. Waldie

Should I Repeat Myself?

Using Repeat Loops in AppleScript

For the past couple of months, we have been talking about some basic Finder scripting. Now we are going to switch gears and get back to some basics of AppleScript. In this month's article, we will discuss the various types of repeat loops that you can use when you are scripting.

Why You Need Repeat Loops

Repeat loops are invaluable when writing AppleScript code, because you will frequently need to perform a single task more than once. While in some cases, you could simply write the same code over and over again in order to achieve the same result, in other instances, you cannot.

For example, let's say that you have a folder containing 10 files, and you want to rename all of them with a unique numeric extension from 1 to 10. You could write a repetitive AppleScript that would rename the files in this manner without a repeat loop. However, why would you want to do that? It would take a while to write, and it would be kind of a pain in the neck if you wanted to go back and change the code. For example, what if, after writing the code, you changed your mind and now you want the files to be named from 11 to 20? You would need to go back through all of your code and restructure it. Isn't one of the primary functions of AppleScript to automate things? So, why not automate your code?

In some cases, the only way to accomplish a task is to use a repeat loop. For example, let's say that you need a script that will rename files in a folder. However, the number of files in the folder may change each time the script is run. To do this, you would need to get a list of all of the files in the folder, and then use a repeat loop to go through and rename all of them.

As we continue, throughout this article, you will see how repeat loops can be extremely useful in all types of automated processes.

Types of Repeat Loops

There are several different types of repeat loops that can be used in AppleScript.

Repeat

In AppleScript, it is possible to loop indefinitely by using the repeat type of repeat loop, which is written as follows:

repeat
   -- DO SOMETHING
end repeat

Using the above example, the AppleScript code inside of the repeat loop will loop on forever. It will never stop unless an error occurs. You should take care when using this type of repeat loop, as you can sometimes box yourself into a corner with no way to get out. It is always good practice to provide some type of mechanism within your code in order to get yourself out of the repeat loop. This is typically done by using the exit repeat statement.

For example, let's say that you need to display a dialog prompting the user to enter a username. However, you want to make absolutely sure that the user types at least something into the dialog. This can be done with a combination of a repeat type of repeat loop and an exit repeat statement.

repeat
   display dialog "Please enter your username:" default answer ""
   set theUserName to text returned of result
   if theUserName <> "" then exit repeat
end repeat

As you can see in the example code above, the dialog will continue to be displayed until the user enters something into the prompt.

Repeat Times

Another type of repeat loop in AppleScript is the repeat times type of repeat loop, which is used to perform a loop for a specified number of times. For example, let's use the same scenario as above. However, instead of looping forever, let's say that you want to only give the user 3 chances to enter the username before an error will occur.

repeat 3 times
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
   if theUserName <> "" then exit repeat
end repeat
if theUserName = "" then display dialog "Invalid Entry!!!"

In the example code above, the user will only be prompted to enter the username a maximum of 3 times. If the user does not enter a username, then an error notification will be displayed.

Repeat While

The repeat while style of repeat loop is typically used to test for a specific scenario to occur. For example, we could use the repeat while type of repeat loop as another way to verify that a user enters something into our dialog example.

set theUserName to ""
repeat while theUserName = ""
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
end repeat

In the example above, the script will continue to loop until something is entered into the dialog. You could also use a repeat loop of this nature to loop until a file is detected in a certain folder. For example:

set theFilePath to (path to desktop as string) & "test.psd"
tell application "Finder"
   repeat while (file theFilePath exists) = false
   end repeat
end tell
display dialog "The Photoshop file has arrived!"

Repeat Until

The repeat until type of repeat loop is yet another type of repeat loop that is used to test for specific scenarios to occur. As you can see in the example code below, this type of repeat loop is very similar to the repeat while type of repeat loop.

set theUserName to ""
repeat until theUserName <> ""
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
end repeat

Reprat With

The repeat with type of repeat loop can actually be broken down another level, into two separate types of distinct repeat with loops.

The first type of repeat with loop will allow you to loop for a specified number of times, while dynamically incrementing an integer variable's count. This type of repeat with loop is formed as follows:

repeat with theIncrementValue from theStartingValue to theEndingValue
   -- DO SOMETHING
end repeat

In the code above, the variable theIncrementValue signifies the current increment of an integer value in the loop. The variable theStartingValue signifies an integer that should be used as the initial increment value, whereas the variable theEndingValue signifies an integer that should be used as the final increment value. When a repeat loop of this nature is executed, it will continue to loop, incrementing the variable theIncrementValue each time until it reaches the value of the theEndingValue.

Let's take a look at another example in order to help illustrate this process. In the following example, we are going to prompt the user to select a folder, and then loop a specified number of times, building a folder for each increment.

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 1 to 10
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

When executed, the code above will generate 10 folders, named from 1 to 10, in a user specified directory. You can see how using a repeat loop for this type of task can help to make your AppleScript code extremely efficient.

It is also possible to change the manner by which the increment in this type of repeat loop occurs. For example, you may not want to loop by 1's. Instead, you may want to loop by 2's. This can be done by adding an optional by parameter at the end of the initial repeat with statement. For example:

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 1 to 10 by 2
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

In the example above, the script increments by 2's rather than 1's. Therefore, instead of building 10 folders, the script will only build 5, and they will be named "1", "3", "5", "7", and "9".

When using this type of repeat with loop, it is not necessary to begin the loop with a starting increment of 1. For example, the following code will cause 10 folders to be created, named from 11 to 20.

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 11 to 20
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

It is also possible to cause the increment value to move in reverse, such as from 10 to 1. For example:

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 10 to 1 by -1
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

At the beginning of this section, I mentioned that there are actually two types of repeat with loops in AppleScript. The second type of repeat with loop is used to loop through a series of values in a list. It is formed as follows:

repeat with theCurrentValue in theListOfValues
   -- DO SOMETHING
end repeat

When using this type of repeat with loop, each time the code loops, the variable theCurrentValue will take on the value of the current item in the list variable theListOfValues. Let's take a look at this type of loop in action.

set theDestinationFolder to choose folder
set theListOfValues to {"apples", "oranges", "pears"}
tell application "Finder"
   repeat with theCurrentValue in theListOfValues
      make new folder at theDestinationFolder with properties {name:theCurrentValue}
   end repeat
end tell

In the example code above, the script will loop through the list variable theListOfValues, which, in this case, contains the names of three different types of fruit. Each time the code loops, the variable theCurrentValue will take on the current value from the variable theListOfValues. So, during the first loop, the variable theCurrentValue would take on a value of "apples", the second loop, it would take on a value of "oranges", and so forth.

In Closing

Hopefully, the various types of repeat loops specified in this article will be helpful to you as you begin writing more complex AppleScript code. By creating nested repeat loops of varying types, you can really create some complex and adventurous scripts.

If you are interested in learning more about repeat loops in AppleScript, I recommend checking out the AppleScript Language Guide, which can be found under AppleScript in the Developer Connection on Apple's web site - http://developer.apple.com/. You may also want to consider picking up a good introductory AppleScript book, such as Danny Goodman's AppleScript Handbook.

Until next time, keep scripting!


Benjamin Waldie is president of Automated Workflows, LLC, a firm specializing in AppleScript and workflow automation consulting. In addition to his role as a consultant, Benjamin is an evangelist of AppleScript, and can frequently be seen presenting at Macintosh User Groups, Seybold Seminars, and MacWorld. For additional information about Benjamin, please visit http://www.automatedworkflows.com , or email Benjamin at applescriptguru@mac.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Latest Forum Discussions

See All

Combo Quest (Games)
Combo Quest 1.0 Device: iOS Universal Category: Games Price: $.99, Version: 1.0 (iTunes) Description: Combo Quest is an epic, time tap role-playing adventure. In this unique masterpiece, you are a knight on a heroic quest to retrieve... | Read more »
Hero Emblems (Games)
Hero Emblems 1.0 Device: iOS Universal Category: Games Price: $2.99, Version: 1.0 (iTunes) Description: ** 25% OFF for a limited time to celebrate the release ** ** Note for iPhone 6 user: If it doesn't run fullscreen on your device... | Read more »
Puzzle Blitz (Games)
Puzzle Blitz 1.0 Device: iOS Universal Category: Games Price: $1.99, Version: 1.0 (iTunes) Description: Puzzle Blitz is a frantic puzzle solving race against the clock! Solve as many puzzles as you can, before time runs out! You have... | Read more »
Sky Patrol (Games)
Sky Patrol 1.0.1 Device: iOS Universal Category: Games Price: $1.99, Version: 1.0.1 (iTunes) Description: 'Strategic Twist On The Classic Shooter Genre' - Indie Game Mag... | Read more »
The Princess Bride - The Official Game...
The Princess Bride - The Official Game 1.1 Device: iOS Universal Category: Games Price: $3.99, Version: 1.1 (iTunes) Description: An epic game based on the beloved classic movie? Inconceivable! Play the world of The Princess Bride... | Read more »
Frozen Synapse (Games)
Frozen Synapse 1.0 Device: iOS iPhone Category: Games Price: $2.99, Version: 1.0 (iTunes) Description: Frozen Synapse is a multi-award-winning tactical game. (Full cross-play with desktop and tablet versions) 9/10 Edge 9/10 Eurogamer... | Read more »
Space Marshals (Games)
Space Marshals 1.0.1 Device: iOS Universal Category: Games Price: $4.99, Version: 1.0.1 (iTunes) Description: ### IMPORTANT ### Please note that iPhone 4 is not supported. Space Marshals is a Sci-fi Wild West adventure taking place... | Read more »
Battle Slimes (Games)
Battle Slimes 1.0 Device: iOS Universal Category: Games Price: $1.99, Version: 1.0 (iTunes) Description: BATTLE SLIMES is a fun local multiplayer game. Control speedy & bouncy slime blobs as you compete with friends and family.... | Read more »
Spectrum - 3D Avenue (Games)
Spectrum - 3D Avenue 1.0 Device: iOS Universal Category: Games Price: $2.99, Version: 1.0 (iTunes) Description: "Spectrum is a pretty cool take on twitchy/reaction-based gameplay with enough complexity and style to stand out from the... | Read more »
Drop Wizard (Games)
Drop Wizard 1.0 Device: iOS Universal Category: Games Price: $1.99, Version: 1.0 (iTunes) Description: Bring back the joy of arcade games! Drop Wizard is an action arcade game where you play as Teo, a wizard on a quest to save his... | Read more »

Price Scanner via MacPrices.net

Apple’s M4 Mac minis on sale for record-low p...
B&H Photo has M4 and M4 Pro Mac minis in stock and on sale right now for up to $150 off Apple’s MSRP, each including free 1-2 day shipping to most US addresses. Prices start at only $469: – M4... Read more
Deal Alert! Mac Studio with M4 Max CPU on sal...
B&H Photo has the standard-configuration Mac Studio model with Apple’s M4 Max CPU in stock today and on sale for $300 off MSRP, now $1699 (10-Core CPU and 32GB RAM/512GB SSD). B&H also... Read more

Jobs Board

All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.