TweetFollow Us on Twitter

Using Repeat Loops in AppleScript

Volume Number: 20 (2004)
Issue Number: 12
Column Tag: Programming

AppleScript Essentials

by Benjamin S. Waldie

Should I Repeat Myself?

Using Repeat Loops in AppleScript

For the past couple of months, we have been talking about some basic Finder scripting. Now we are going to switch gears and get back to some basics of AppleScript. In this month's article, we will discuss the various types of repeat loops that you can use when you are scripting.

Why You Need Repeat Loops

Repeat loops are invaluable when writing AppleScript code, because you will frequently need to perform a single task more than once. While in some cases, you could simply write the same code over and over again in order to achieve the same result, in other instances, you cannot.

For example, let's say that you have a folder containing 10 files, and you want to rename all of them with a unique numeric extension from 1 to 10. You could write a repetitive AppleScript that would rename the files in this manner without a repeat loop. However, why would you want to do that? It would take a while to write, and it would be kind of a pain in the neck if you wanted to go back and change the code. For example, what if, after writing the code, you changed your mind and now you want the files to be named from 11 to 20? You would need to go back through all of your code and restructure it. Isn't one of the primary functions of AppleScript to automate things? So, why not automate your code?

In some cases, the only way to accomplish a task is to use a repeat loop. For example, let's say that you need a script that will rename files in a folder. However, the number of files in the folder may change each time the script is run. To do this, you would need to get a list of all of the files in the folder, and then use a repeat loop to go through and rename all of them.

As we continue, throughout this article, you will see how repeat loops can be extremely useful in all types of automated processes.

Types of Repeat Loops

There are several different types of repeat loops that can be used in AppleScript.

Repeat

In AppleScript, it is possible to loop indefinitely by using the repeat type of repeat loop, which is written as follows:

repeat
   -- DO SOMETHING
end repeat

Using the above example, the AppleScript code inside of the repeat loop will loop on forever. It will never stop unless an error occurs. You should take care when using this type of repeat loop, as you can sometimes box yourself into a corner with no way to get out. It is always good practice to provide some type of mechanism within your code in order to get yourself out of the repeat loop. This is typically done by using the exit repeat statement.

For example, let's say that you need to display a dialog prompting the user to enter a username. However, you want to make absolutely sure that the user types at least something into the dialog. This can be done with a combination of a repeat type of repeat loop and an exit repeat statement.

repeat
   display dialog "Please enter your username:" default answer ""
   set theUserName to text returned of result
   if theUserName <> "" then exit repeat
end repeat

As you can see in the example code above, the dialog will continue to be displayed until the user enters something into the prompt.

Repeat Times

Another type of repeat loop in AppleScript is the repeat times type of repeat loop, which is used to perform a loop for a specified number of times. For example, let's use the same scenario as above. However, instead of looping forever, let's say that you want to only give the user 3 chances to enter the username before an error will occur.

repeat 3 times
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
   if theUserName <> "" then exit repeat
end repeat
if theUserName = "" then display dialog "Invalid Entry!!!"

In the example code above, the user will only be prompted to enter the username a maximum of 3 times. If the user does not enter a username, then an error notification will be displayed.

Repeat While

The repeat while style of repeat loop is typically used to test for a specific scenario to occur. For example, we could use the repeat while type of repeat loop as another way to verify that a user enters something into our dialog example.

set theUserName to ""
repeat while theUserName = ""
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
end repeat

In the example above, the script will continue to loop until something is entered into the dialog. You could also use a repeat loop of this nature to loop until a file is detected in a certain folder. For example:

set theFilePath to (path to desktop as string) & "test.psd"
tell application "Finder"
   repeat while (file theFilePath exists) = false
   end repeat
end tell
display dialog "The Photoshop file has arrived!"

Repeat Until

The repeat until type of repeat loop is yet another type of repeat loop that is used to test for specific scenarios to occur. As you can see in the example code below, this type of repeat loop is very similar to the repeat while type of repeat loop.

set theUserName to ""
repeat until theUserName <> ""
   display dialog "Please enter your name:" default answer ""
   set theUserName to text returned of result
end repeat

Reprat With

The repeat with type of repeat loop can actually be broken down another level, into two separate types of distinct repeat with loops.

The first type of repeat with loop will allow you to loop for a specified number of times, while dynamically incrementing an integer variable's count. This type of repeat with loop is formed as follows:

repeat with theIncrementValue from theStartingValue to theEndingValue
   -- DO SOMETHING
end repeat

In the code above, the variable theIncrementValue signifies the current increment of an integer value in the loop. The variable theStartingValue signifies an integer that should be used as the initial increment value, whereas the variable theEndingValue signifies an integer that should be used as the final increment value. When a repeat loop of this nature is executed, it will continue to loop, incrementing the variable theIncrementValue each time until it reaches the value of the theEndingValue.

Let's take a look at another example in order to help illustrate this process. In the following example, we are going to prompt the user to select a folder, and then loop a specified number of times, building a folder for each increment.

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 1 to 10
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

When executed, the code above will generate 10 folders, named from 1 to 10, in a user specified directory. You can see how using a repeat loop for this type of task can help to make your AppleScript code extremely efficient.

It is also possible to change the manner by which the increment in this type of repeat loop occurs. For example, you may not want to loop by 1's. Instead, you may want to loop by 2's. This can be done by adding an optional by parameter at the end of the initial repeat with statement. For example:

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 1 to 10 by 2
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

In the example above, the script increments by 2's rather than 1's. Therefore, instead of building 10 folders, the script will only build 5, and they will be named "1", "3", "5", "7", and "9".

When using this type of repeat with loop, it is not necessary to begin the loop with a starting increment of 1. For example, the following code will cause 10 folders to be created, named from 11 to 20.

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 11 to 20
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

It is also possible to cause the increment value to move in reverse, such as from 10 to 1. For example:

set theDestinationFolder to choose folder
tell application "Finder"
   repeat with theIncrementValue from 10 to 1 by -1
      make new folder at theDestinationFolder with properties {name:theIncrementValue as string}
   end repeat
end tell

At the beginning of this section, I mentioned that there are actually two types of repeat with loops in AppleScript. The second type of repeat with loop is used to loop through a series of values in a list. It is formed as follows:

repeat with theCurrentValue in theListOfValues
   -- DO SOMETHING
end repeat

When using this type of repeat with loop, each time the code loops, the variable theCurrentValue will take on the value of the current item in the list variable theListOfValues. Let's take a look at this type of loop in action.

set theDestinationFolder to choose folder
set theListOfValues to {"apples", "oranges", "pears"}
tell application "Finder"
   repeat with theCurrentValue in theListOfValues
      make new folder at theDestinationFolder with properties {name:theCurrentValue}
   end repeat
end tell

In the example code above, the script will loop through the list variable theListOfValues, which, in this case, contains the names of three different types of fruit. Each time the code loops, the variable theCurrentValue will take on the current value from the variable theListOfValues. So, during the first loop, the variable theCurrentValue would take on a value of "apples", the second loop, it would take on a value of "oranges", and so forth.

In Closing

Hopefully, the various types of repeat loops specified in this article will be helpful to you as you begin writing more complex AppleScript code. By creating nested repeat loops of varying types, you can really create some complex and adventurous scripts.

If you are interested in learning more about repeat loops in AppleScript, I recommend checking out the AppleScript Language Guide, which can be found under AppleScript in the Developer Connection on Apple's web site - http://developer.apple.com/. You may also want to consider picking up a good introductory AppleScript book, such as Danny Goodman's AppleScript Handbook.

Until next time, keep scripting!


Benjamin Waldie is president of Automated Workflows, LLC, a firm specializing in AppleScript and workflow automation consulting. In addition to his role as a consultant, Benjamin is an evangelist of AppleScript, and can frequently be seen presenting at Macintosh User Groups, Seybold Seminars, and MacWorld. For additional information about Benjamin, please visit http://www.automatedworkflows.com , or email Benjamin at applescriptguru@mac.com.

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

OnyX 3.8.6 - Maintenance and optimizatio...
OnyX is a multifunction utility that you can use to verify the startup disk and the structure of its system files, to run miscellaneous maintenance and cleaning tasks, to configure parameters in the... Read more
Bean 3.3.3 - Fast and uncluttered word p...
Bean is no longer being actively developed, but will be updated as necessary to patch bugs and maintain OS X compatibility Bean is lean, fast, and uncluttered. If you get depressed at the thought of... Read more
Acorn 6.6.2 - Bitmap image editor.
Acorn is a new image editor built with one goal in mind - simplicity. Fast, easy, and fluid, Acorn provides the options you'll need without any overhead. Acorn feels right, and won't drain your bank... Read more
Tor Browser 10.0 - Anonymize Web browsin...
The Tor Browser Bundle is an easy-to-use portable package of Tor, Vidalia, Torbutton, and a Firefox fork preconfigured to work together out of the box. It contains a modified copy of Firefox that... Read more
EtreCheck Pro 6.3.2 - For troubleshootin...
EtreCheck is an app that displays the important details of your system configuration and allow you to copy that information to the Clipboard. It is meant to be used with Apple Support Communities to... Read more
Macs Fan Control 1.5.8.22 - Monitor and...
Macs Fan Control allows you to monitor and control almost any aspect of your computer's fans, with support for controlling fan speed, temperature sensors pane, menu-bar icon, and autostart with... Read more
Iridient Developer 3.4 - Powerful image-...
Iridient Developer (was RAW Developer) is a powerful image-conversion application designed specifically for OS X. Iridient Developer gives advanced photographers total control over every aspect of... Read more
Motion 5.4.7 - Create and customize Fina...
Motion is designed for video editors, Motion 5 lets you customize Final Cut Pro titles, transitions, and effects. Or create your own dazzling animations in 2D or 3D space, with real-time feedback as... Read more
calibre 5.0.1 - Complete e-book library...
Calibre is a complete e-book library manager. Organize your collection, convert your books to multiple formats, and sync with all of your devices. Let Calibre be your multi-tasking digital librarian... Read more
Compressor 4.4.8 - Adds power and flexib...
Compressor adds power and flexibility to Final Cut Pro X export. Customize output settings, work faster with distributed encoding, and tap into a comprehensive set of delivery features. Features:... Read more

Latest Forum Discussions

See All

Blastomancer is a comfortable puzzle gam...
Blastomancer arrived on Google Play for Android at the weekend. It’s a 2D puzzle game involving cartoon stick figure wizards and lots of bombs. [Read more] | Read more »
Undercrawl is a procedurally generated r...
Undercrawl is a roguelike dungeon crawler from indie developer Monster Shop Games. It's a genre that's popular in gaming in general but features even more frequently on mobile devices since the shorter, 'run' style of playthrough suits playing in... | Read more »
Distract Yourself With These Great Mobil...
There’s a lot going on right now, and I don’t really feel like trying to write some kind of pithy intro for it. All I’ll say is lots of people have been coming together and helping each other in small ways, and I’m choosing to focus on that as I... | Read more »
BTS Universe Story, the social game that...
Netmarble's highly anticipated social game, BTS Universe Story, is available now for iOS and Android. It's the second collaboration between the hugely successful mobile developer and the K-pop superstars following BTS World. [Read more] | Read more »
The 5 Best Mobile Games Like Hades
Supergiant Games finally released Hades upon the world this week, and we’re loving it. The game plays to all of the studio’s strengths while still retaining a strong sense of identity. It also just so happens to play rather well using the Steam... | Read more »
A Year of Apple Arcade: The Good, The Ba...
Apple Arcade has persisted for just over a year at this point, and although that means I've been busy ranking and re-ranking every game on the service for just about as long, I haven't done much reflection on the service as a whole. [Read more] | Read more »
Animal Restaurant anniversary event team...
Animal idle simulator Animal Restaurant is celebrating its first-year anniversary with a crossover event with popular YouTube series Aaron’s Animals. [Read more] | Read more »
Raziel: Dungeon Arena is a hack 'n...
Raziel: Dungeon Arena is available now on mobile and will appeal to fans of both comic books and old school dungeon crawlers. Not only will you hack 'n' slash your way through mobs of enemies but there's also fully-narrated animated comic to enjoy... | Read more »
Steam Link Spotlight - Hades
Steam Link Spotlight is a feature where we look at PC games that play exceptionally well using the Steam Link app. Our last entry was on Disco Elysium. Read about how it plays using Steam Link over here. | Read more »
Microsoft has acquired ZeniMax Media and...
In the latest of a series of blockbuster moves, Microsoft has now acquired Zenimax Media and its subsidiary, Bethesda Softworks, for $7.5 billion. [Read more] | Read more »

Price Scanner via MacPrices.net

AT&T now offering $1000 discount on Apple...
AT&T is offering a $1000 discount on any Apple iPhone 11 Pro or 11 Pro Max with trade-in and new line of service. Discount applied monthly over a 30 month period. Eligible iPhone trade-ins are... Read more
New 2020 12.9″ iPad Pros on sale for up to $8...
Apple reseller Expercom has new 2020 Apple 12.9″ iPad Pros on sale today for $60-$85 off MSRP, with prices starting at $939. Not every model is in stock, but you can still order an iPad at these... Read more
Apple offers clearance 2019 27″ 5K iMacs for...
Apple has Certified Refurbished 2019 27″ 5K iMacs available starting at $1439 and up to $520 off their original MSRP. Apple’s one-year warranty is standard and shipping is free. The following... Read more
Weekend’s Best MacBook Deal: These 2020 13″ M...
Apple has a full line of Certified Refurbished 2020 13″ 1.4GHz 4-Core Touch Bar MacBook Pros available starting at $1099 and up to $230 off original MSRP. Apple’s one-year warranty is included,... Read more
Clearance 8-core iMac Pro available for $3819...
Apple has Certified Refurbished, clearance, 27″ 3.2GHz 8-Core iMac Pros available $3819 including free shipping. Their price is $1180 off the original MSRP of new models. A standard Apple one-year... Read more
How The Upcoming Mac Transition To Apple Sili...
FEATURE: 09.25.20 – Apple’s plan to transition all of its desktop and notebook computers away from Intel processors to Apple silicon, chips designed by the company itself, has been eclipsed by the... Read more
New low price! Apple Watch SE for only $269
B&H Photo is reporting limited stock of Apple’s new Apple Watch SE GPS models for $10 off MSRP and including free shipping. Their $269 price for the 40mm model is the lowest price we’ve seen so... Read more
Lowest price anywhere: New 13″ 2.0GHz MacBook...
Amazon has new 2020 13″ 2.0GHz/512GB MacBook Pros with 10th generation Intel processors back in stock on sale today for $200 off Apple’s MSRP. Shipping is free. Be sure to purchase the MacBook Pro... Read more
Apple Pro Display XDR with Nano-Texture Glass...
Amazon Apple Premier Partner GatorTec has the Apple Pro Display XDR with Nano-Texture Glass on sale for $5599 shipped, on Amazon. Their price is $400 off Apple’s MSRP, and it’s the cheapest price... Read more
Get a 2019 13″ MacBook Air for only $779 toda...
Apple has clearance, Certified Refurbished, 2019 13″ 1.6GHz/128GB MacBook Airs available again for $779. Each MacBook features a new outer case, comes with a standard Apple one-year warranty, and is... Read more

Jobs Board

Senior Product Manager, *Apple* Platforms -...
…technical/operational expertise of our employees. **Role Details:** The Senior Product Manager, Apple Platform will report to the Senior Director of Product and Read more
Tier 2 Technical Support Analyst - ( *Apple*...
…Support Analystiwho will analyze and determine user software needs on all Apple devices (first support contact), Windows devices, and support printers in the Read more
Medical Assistant - Internal Medicine *Apple...
Schedule & Location Full Time Day (80 Hours every two weeks) Apple Hill Medical Center 25 Monument Road York PA Job Description: Under the general supervision of the Read more
*Apple* Technology Journalist - Valnet Freel...
…freelance basis. Valnet Inc. is looking for journalists with strong knowledge of Apple technology for our website MakeUseOf.com MakeUseOf is one of the largest Read more
Bookseller- *Apple* Shop Support - Penn Sta...
…combination of education, certification and experience will be considered. + A+ and/or Apple certified or able to achieve certification within 60 days required. + Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.