Volume Number: 15 (1999)
Issue Number: 2
Column Tag: Tips & Tidbits

Feb 99 Tips

by Jeff Clites <online@mactech.com>

AppleEvents are the standard for interprocess communication on the Macintosh, and they should be part of any programmer's arsenal. Unfortunately, they can be as confusing as they are powerful when you are first trying to learn about them. MacPerl has several different levels at which you can work with AppleEvents, and you can take advantage of this in a number of ways - as a place to experiment while you are learning, as an AppleScript replacement for automation tasks which require a little more processing power, or as a rapid prototyping tool while you are developing your AE code for use in another application.

The following script demonstrates three different ways you can accomplish the same task using AppleEvents in MacPerl. Each retrieves the list of AppleScripts attached to a specified folder, both sending the request event and processing the reply.

#!perl -wl
use strict;
my $folder   = 'MacHD:Desktop Folder:test folder:';

# print the results of each of the three methods 
(they should be the same)
printf("%s:\n%s\n\n%s:\n%s\n\n%s:\n%s\n\n",
   'AppleScript',              join("\n", getscripts_as()),
   'Apple Events',             join("\n", getscripts_ae()),
   'Simple Apple Events',      join("\n", getscripts_ae_simple()),
);

# Retrieve the list of attached scripts...

# ...by compiling an AppleScript
sub getscripts_as
{
   my $reply = MacPerl::DoAppleScript(<<EOS);
   tell application "Folder Actions"
      attached scripts alias "$folder"
   end tell
EOS

   # the reply is a list within a list, so this must be unwound
   $reply =~ s/^{{(.*)}}$/$1/;
   
   # the resulting string is split up into an array and returned
   return($reply =~ /alias "([^"]+)"(?:, |$)/g);
}


# ...by sending an AppleEvent built using the AEGizmos notation, 
# and retrieving the reply using standard Toolbox functions
use Mac::AppleEvents;
use Mac::Files;

sub getscripts_ae
{
   my($evt, $rep, $dobj, $data, @alis);

   $evt = AEBuildAppleEvent(
                  qw(faco lact sign ssrv 0 0), 
                  "'--':alis(\@\@)",
                  NewAliasMinimal($folder)) or die $^E;

   $rep  = AESend($evt, kAEWaitReply) or die $^E;
   $dobj = AEGetParamDesc($rep, keyDirectObject);
   $data = AEGetNthDesc($dobj, 1);

   for (1 .. AECountItems($data))
   {
      my $desc = AEGetNthDesc($data, $_);
      push @alis, scalar ResolveAlias($desc->data);
      AEDisposeDesc($desc);
   }

   for ($evt, $rep, $dobj, $data) {AEDisposeDesc $_}

   return(@alis);
}


# ...by using MacPerl's simplified AppleEvent interface to send and receive 
use Mac::AppleEvents::Simple qw(:all);
use Mac::Files;

sub getscripts_ae_simple
{
   my($evt, $data, @alis);

   $evt = do_event(
                  qw(faco lact ssrv), 
                  "'--':alis(\@\@)",
                  NewAliasMinimal($folder)) or die $^E;

   $data = $evt->data;
   @alis = Mac::AppleEvents::Simple::get($data);
   AEDisposeDesc($data);

   return(@alis);
}

__END__

There is a new MacPerl module under development, called Mac::Glue, which will simplify the process even more, and almost completely hide the details behind perl-style functions. Although it is currently in the alpha stages, you will soon be able to use the following syntax (or something very similar) to achieve the same result:

use Mac::Glue::Folder_Actions qw(:all);

sub getscripts_glue 
{
   my($f, $data, @alis);

   $f = new Mac::Glue::Folder_Actions;
   $data = $f->attached_scripts($folder)->data;
   @alis = Mac::AppleEvents::Simple::get($data);
   AEDisposeDesc($data);
   return(@alis);
}

Chris Nandor <pudge@pobox.com>