TweetFollow Us on Twitter

Split Button
Volume Number:7
Issue Number:6
Column Tag:HyperChat

Splitting Your Sides

By Carl J. Manaster, Globe, AZ

Note: Source code files accompanying article are located on MacTech CD-ROM or source code disks.

[Carl is a mining engineer and programmer whose appreciation for environments such as HyperCard and THINK Pascal is enhanced by painful memories of dBase and FORTRAN.]

Objectives

It’s endemic among HyperCard fans to try to “fill in” the gaps left by Apple. Such supplements often take the form of XCMDs and XFCNs, offering everything from standard file calls to color windows. Occasionally, the purists among us like to write these extensions in HyperTalk itself, keeping it “all in the family,” as it were. (Also, having once used TCL or MacApp, it’s hard to imagine going back to writing Pascal without such crutches - and they don’t help with code resources!)

One thing missing from HyperCard is polygonal buttons - arbitrary shapes that behave like a button. The need for these has been apparent since the first release and its Clip Art stack, where the user clicks on certain parts of the pictures to travel to related cards. Since it’s all done with transparent (rectangular) buttons, there’s a great deal of “slop” space, where a click that ought to be on a hat (for instance) is really in the rectangle of the man.

There are doubtless XCMDs available that solve this problem, and I’ve seen at least one article describing a HyperTalk-based solution; here is another.

The Basic Solution

My solution is to place buttons over each side of the polygon, and split the message chain along each button’s diagonal. The message to do this is in the stack’s script:

--1

--message split
--syntax: split(orientation,¬
----------------topMessage,bottomMessage)
--where: orientation is “/” or “\”
--topMessage is message to be called if click
------------------was in top half of target
--bottomMessage is message to be called if click
--------------------was in bottom half of target

on split
  put param(2) into topMessage
  put param(3) into bottomMessage
  put (the bottom of the target) - ¬
 (the clickV) into vDiff
  if param(1) is “/”
  then put (the clickH) - (the left of¬
 the target) into hDiff
  else put (the right of the target) - ¬
 (the clickH) into hDiff
  put vDiff * (the width of the target)¬
 > hDiff * (the height of the target)¬
 into doTop
  if doTop
  then send topMessage to target
  else send bottomMessage to target
end split

Each button’s mouseUp script calls split with the appropriate orientation and messages, thereby simulating two adjacent triangular buttons with differing mouseUp messages. With this script and the button tool, buttons can be placed around a polygon to simulate polygonal buttons.

Figure 1 - How a Split Button Simulates a Pair of Triangular Buttons

Getting Fancy

The obvious next step is to make it easier to generate polygonal buttons. The script in Listing #1, makePolyButton, does this. It tracks and records clicks until one is close to the first vertex, outlining the polygon as it is defined.

Figure 2 - Original Image with Polygonal Outline

Once all the vertices of the polygon have been entered, the maximum and minimum horizontal and vertical coördinates are determined, as well as the next-to-maximum and next-to-minimum.

A button is created whose sides are the next-to-extreme coördinates of the polygon’s vertices; most mouseUp messages reaching it will be within the polygon but not within any of the buttons around its edge.

Figure 3 - Polygon with Interior Button

Lastly, for each side of the polygon, a button is created whose mouseUp handler uses the split message to choose between the two messages that are passed to makePolyButton as parameters.

Figure 4 - Polygon with Border Buttons

Limitations and Flaws

Like most solutions, this one is imperfect; here are some of the problems associated with my implementation of polygonal buttons:

No AutoHilite or Outline

Because polygonal buttons have no single data structure where they are defined, autoHiliting is out of the question. Outlining is not impossible - a script could be written that included:

--2

choose line tool
if the script of the target¬
contains “split” and the script of¬
the target contains “/” then drag 

but it would not behave like normal outlining: painting would obscure it; moving the button would neither erase the old outline nor draw the new one; even if this were solved, erasing the old could mess up the paint layer with traces of white It is best to accept that outlining is not a feature of these polygonal buttons.

Sharp Corners Confuse

It is possible to generate polygons that are not modelled well with this technique. Indeed, the polygon used in Figures 2-4 shows some space that will report an “inside” message when certain “outside” areas are clicked (the upper right corner of the interior button, whose message is “inside”, extends beyond where border buttons cover it.) Similar mis-routing of the message chain can occur when the angles of a polygon are too sharp, and one border button overlaps another. This problem can be overcome by tweaking with the button tool, but even without such tweaking there is much less slop space than with plain, rectangular buttons.

Conclusions

The Spectrum of Solutions

There are countless ways in which a polygon may be made to act as a button in HyperCard; the methods differ in degree of resolution. The trade-off is between accuracy of representation on the one hand and programming demands, memory, and speed on the other. The roughest solution is to use rectangular buttons that more-or-less cover the polygon. At the fine end of the spectrum lie solutions such as pixel-sized buttons to fill the polygon, XCMDs, and complex scripts that rely on globals or fields to keep track of the polygon’s vertices.

Split buttons fall somewhere in the middle of the spectrum. The marginal costs over using rectangular buttons (a little programming, slightly more difficulty creating, moving, and deleting, and one more handler in the message chain) are relatively small, and the gains are significant. The accuracy is not as good as the pixel-perfect solutions (both HyperCard- and XCMD- based), but much less programming is required, and split buttons should be much faster than the HyperCard-based solutions.

This via media is realized by using each button to focus information, like relying on an airplane to get across the country and then getting to your house by car. The rough end of the spectrum relies on HyperCard to do all of the work (flying home on a 747); the fine end solutions do all of the work themselves (driving cross-country); split buttons rely on HyperCard for what it’s good at - the rough determination of which rectangular button contained the click - and concentrate on further distilling the information.

Because split buttons represent a compromise, they will not be appropriate for every stack calling for polygonal buttons. Because they represent a good compromise, however, they may find many applications.

LISTING #1 - makePolyButton script
--message makePolyButton
--syntax: makePolyButton(inMessage,outMessage)
----------inMessage is message to be called by 
----------------clicks within the polyButton
----------outMessage is message to be called by 
----------------clicks outside the polyButton

on makePolyButton inMessage,outMessage
 put empty into pointList
 choose line tool
 set the cursor to cross
 wait until the mouseClick
 put the clickLoc into pointList

 repeat
 wait until the mouseClick
 put return & the clickLoc after pointList
 put the number of lines of pointList¬
 into count
 drag from (line count-1 of pointList)¬
 to (line count of pointList)
 if abs(item 1 of last line of pointList¬
 - item 1 of first line of pointList)<2¬
 and abs(item 2 of last line of pointList¬
 - item 2 of first line of pointList)<2¬
 then exit repeat
 end repeat

 put line 1 of pointList into¬
 last line of pointList
 put the number of card buttons into cbCount
 set lockScreen to true
 doMenu revert
 choose button tool

 put item 1 of line 1 of pointList into maxV
 put item 1 of line 2 of pointList into maxPenV
 put item 1 of line 1 of pointList into minV
 put item 1 of line 2 of pointList into minPenV

 put item 2 of line 1 of pointList into maxH
 put item 2 of line 2 of pointList into maxPenH
 put item 2 of line 1 of pointList into minH
 put item 2 of line 2 of pointList into minPenH

 repeat with i=2 to count

 get item 1 of line i of pointList
 if it > maxPenV then--find the largest
 if it > maxV then --and second largest v
 put maxV into maxPenV
 put it into maxV
 else
 put it into maxPenV
 end if
 end if

 if it < minPenV then   --find the smallest
 if it < minV then --and second smallest v
 put minV into minPenV
 put it into minV
 else
 put it into minPenV
 end if
 end if

 get item 2 of line i of pointList
 if it > maxPenH then--find the largest
 if it > maxH then --and second largest h
 put maxH into maxPenH
 put it into maxH
 else
 put it into maxPenH
 end if
 end if

 if it < minPenH then--find the smallest
 if it < minH then --and second smallest h
 put minH into minPenH
 put it into minH
 else
 put it into minPenH
 end if
 end if

 end repeat

 add 1 to cbCount--create the interior button
 doMenu “new button”
 set the style of card button cbCount¬
 to transparent
 set the showName of card button cbCount¬
 to false
 set the autoHilite of card button cbCount¬
 to false
 set the rect of card button cbCount¬
 to minPenV,minPenH,maxPenV,maxPenH
 put “on mouseUp” into theScript
 put return & inMessage after theScript
 put return & “end mouseUp” after theScript
 set the script of card button cbCount¬
 to theScript
 repeat with i=1 to count-1
 add 1 to cbCount--create the edge buttons
 set the cursor to busy
 put line i of pointList into firstPoint
 put line (i+1) of pointList into secondPoint
 doMenu “new button”
 set the name of card button cbCount¬
 to “split” && i

 --determine the coördinates of the button:
 if (item 1 of firstPoint) < (item 1¬
 of secondPoint) then
 put item 1 of firstPoint into top
 put item 1 of secondPoint into bottom
 else
 put item 1 of secondPoint into top
 put item 1 of firstPoint into bottom
 end if
 if (item 2 of firstPoint) > (item 2¬
 of secondPoint) then
 put item 2 of firstPoint into right
 put item 2 of secondPoint into left
 else
 put item 2 of secondPoint into right
 put item 2 of firstPoint into left
 end if

 set the rect of card button cbCount¬
 to top,left,bottom,right
 set the style of card button cbCount¬
 to transparent
 set the showName of card button cbCount¬
 to false
 set the autoHilite of card button cbCount¬
 to false

 --determine the orientation of the
 --”split” of the button:

 put “on mouseUp” into theScript

 if (item 1 of firstPoint) > (item 1¬
 of secondPoint) then
 if (item 2 of firstPoint) > (item 2¬
 of secondPoint) then
 put return & “split “ & quote & “\”¬
 & quote & “,” & inMessage & “,” &¬
 outMessage after theScript
 else
 put return & “split “ & quote & “/”¬
 & quote & “,” & inMessage & “,” &¬
 outMessage after theScript
 end if
 else
 if (item 2 of firstPoint) > (item 2¬
 of secondPoint) then
 put return & “split “ & quote & “/”¬
 & quote & “,” & outMessage & “,” &¬
 inMessage after theScript
 else
 put return & “split “ & quote & “\”¬
 & quote & “,” & outMessage & “,” &¬
 inMessage after theScript
 end if
 end if

 put return & “end mouseUp” after theScript

 set the script of card button cbCount¬
 to theScript
 end repeat

 choose browse tool
end makePolyButton
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Notion 2.1.3 - A unified workspace for m...
Notion is the unified workspace for modern teams. Features: Integration with Slack Documents Wikis Tasks More improvements to editing Browse through a page’s images from one place Choose a type... Read more
Cocktail 15.3.7 - General maintenance an...
Cocktail is a general purpose utility for macOS that lets you clean, repair and optimize your Mac. It is a powerful digital toolset that helps hundreds of thousands of Mac users around the world get... Read more
Dropbox 158.4.4564 - Cloud backup and sy...
Dropbox is a file hosting service that provides cloud storage, file synchronization, personal cloud, and client software. It is a modern workspace that allows you to get to all of your files, manage... Read more
WhatsApp 2.2236.10 - Desktop client for...
WhatsApp is the desktop client for WhatsApp Messenger, a cross-platform mobile messaging app which allows you to exchange messages without having to pay for SMS. WhatsApp Messenger is available for... Read more
VOX 3.5.2 - Music player that supports m...
VOX just sounds better! The beauty is in its simplicity, yet behind the minimal exterior lies a powerful music player with a ton of features and support for all audio formats you should ever need.... Read more
TeamViewer 15.34.4 - Establish remote co...
TeamViewer gives you remote control of any computer or Mac over the Internet within seconds, or can be used for online meetings. Find out why more than 200 million users trust TeamViewer! Free for... Read more
ClamXAV 3.5 - Virus checker based on Cla...
ClamXAV is a popular virus checker for OS X. Time to take control ClamXAV keeps threats at bay and puts you firmly in charge of your Mac’s security. Scan a specific file or your entire hard drive.... Read more
Ableton Live 11.2 - Record music using d...
Ableton Live lets you create and record music on your Mac. Use digital instruments, pre-recorded sounds, and sampled loops to arrange, produce, and perform your music like never before. Ableton Live... Read more
Viber 18.5.0 - Send messages and make fr...
Viber lets you send free messages and make free calls to other Viber users, on any device and network, in any country! Viber syncs your contacts, messages and call history with your mobile device, so... Read more
CrossOver 22.0.1 - Run Windows apps on y...
CrossOver can get your Windows productivity applications and PC games up and running on your Mac quickly and easily. CrossOver runs the Windows software that you need on Mac at home, in the office,... Read more

Latest Forum Discussions

See All

TouchArcade Game of the Week: ‘Tallowmer...
With its pre-determined launch date of September 30th it didn’t quite make it in time for our weekly round-up of new game releases, but darn it, I just don’t care. I’m not letting that technicality keep me from picking Tallowmere 2 as our Game of... | Read more »
SwitchArcade Round-Up: Reviews Featuring...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for September 30th, 2022. In today’s article, our pal Mikhail has another review for us. Gosh, that guy needs a day off! He’s taking a look at Let’s Build a Zoo, and it’s not exactly the... | Read more »
Seven Knights 2 recieves global update i...
Netmarble has announced the latest global update for mobile role-playing game Seven Knights 2. The update will bring brand new characters, some very rewarding events, and reworks to a few old favourite heroes. [Read more] | Read more »
‘GRIS+’ Is This Week’s New Apple Arcade...
Nomada Studio and Devolver Digital’s brilliant GRIS+ () has joined Apple Arcade today as an App Store Great. If you’ve not played it yet, GRIS debuted on PC and Nintendo Switch before seeing PS4 and mobile releases later on. I reviewed the iOS... | Read more »
SwitchArcade Round-Up: Reviews Featuring...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for September 29th, 2022. In today’s article, we have a bunch of new releases to check out with the spearhead being The Elder Scrolls V: Skyrim Anniversary Edition. There’s a little here... | Read more »
‘Residual’ Controller Fix Update Release...
A few weeks back developer OrangePixel released their newest game on mobile called Residual. This is a roguelike survival game where you play as a pilot who crash lands on a procedurally generated planet, filled with all sorts of crazy creatures and... | Read more »
‘Queen’s Wish 2: The Tormentor’ Launchin...
We learned back in July that Spiderweb Software’s latest game Queen’s Wish 2: The Tormentor would be heading to desktop platforms in August, which is exactly what happened, and at that time we were guessing that the iOS version of the game would... | Read more »
‘Kingdom Rush Vengeance’ Primal Ravage U...
Ironhide Game Studio’s Kingdom Rush Vengeance ($4.99) has gotten quite a few updates over the years on iOS, Android, and PC. | Read more »
Interactive Film The Gallery screens at...
The FMV/interactive film hybrid video game genre has been around for a while but doesn’t seem to have that many games out there, but they just might get some more exposure as The Gallery has landed a spot in the Dinar Film Festival 2022. [Read... | Read more »
Terraria’s Massive Labor of Love Update...
Re-Logic’s action platforming sandbox game Terraria ($4.99) has just been updated on mobile and console platforms with its newest major update titled the ‘Labor of Love’ update. | Read more »

Price Scanner via MacPrices.net

Apple has M1 Mac minis in stock again startin...
Apple has restocked a full line of M1-powered Mac minis available in their Certified Refurbished section starting at only $589 and up to $140 off MSRP. Each mini comes with Apple’s one-year warranty... Read more
13″ M1 MacBook Airs with 16GB of RAM availabl...
Apple has 13″ M1 MacBook Airs (8-Core CPU/7-Core GPU) in stock today with 16GB of RAM for $190 off MSRP, Certified Refurbished. Apple includes a standard one-year warranty with these models, each... Read more
Update: 13-inch Apple M2 MacBook Airs now on...
Amazon has 13″ MacBook Airs with M2 CPUs in stock today and on sale for $150 off MSRP. Shipping is free. Their prices are now $150 off Apple’s MSRP, and they are the lowest prices available for these... Read more
Save $240 on a 14″ 8-core CPU M1 Pro MacBook...
Apple has the 14″ M1 Pro MacBook Pro with 32GB of RAM and a 512GB SSD (Space Gray) in stock for $2159, Certified Refurbished. Regular price for this configuration is $2399, so their savings amounts... Read more
Save $170 on this 13″ M2 MacBook Pro with 16G...
Apple has 13″ M2 MacBook Pros with 16GB of RAM and 512GB SSDs in stock today for $170 off MSRP ($1529), Certified Refurbished. These are the cheapest 13″ M2 MacBook Pros with this configuration... Read more
This Apple retailer is offering a $350 discou...
Apple retailer Expercom is offering a $350 instant discount on select upgraded 16″ Apple MacBook Pros through October 4, 2022. Shipping is free. Their sale price applies to the following... Read more
Clearance 27″ 5K Apple iMacs are on sale star...
Other World Computing has dropped prices on Apple refurbished, factory-sealed, recently-discontinued 27″ 5K iMacs with models now on sale for up to $950 off Apple’s MSRP, starting at only $849. Their... Read more
Get a new Mac for up to $400 off MSRP at Appl...
Need a new Apple Mac for school? Whether you’re a student, teacher, or staff member, you can use your .edu email address when ordering at Apple Education to take up to $400 off the price of a new Mac... Read more
13-inch Apple MacBook Airs with M2 processors...
Amazon has 13″ MacBook Airs with M2 CPUs in stock today and on sale for $1099. Shipping is free. Their prices are $100 off Apple’s MSRP, and they are the lowest prices available for M2-powered Macs... Read more
AR Glasses That Work With Apple’s Hardware? T...
NEWS – Lenovo has created quite the spectacle(s) with its latest product. “Apple Glass” — the purported name of Apple’s forthcoming AR glasses — is not expected to be released until 2025 (at the... Read more

Jobs Board

*Apple* Electronic Repair Technician - PlanI...
…a highly motivated individual to join our Production Department as an Apple Electronic Repair Technician. The computer repair technician will diagnose, assemble, Read more
( *Apple* ) Production Designer/Artist - TEKs...
…Art Ops team supports production, asset management, quality control, and global publishing for Apple Media Products, like Apple Music. The Art Ops team is Read more
Operations Associate - *Apple* Blossom Mall...
Operations Associate - Apple Blossom Mall Location:Winchester, VA, United States (https://jobs.jcp.com/jobs/location/191170/winchester-va-united-states) - Apple Read more
Cashier - *Apple* Blossom Mall - JCPenney (...
Cashier - Apple Blossom Mall Location:Winchester, VA, United States (https://jobs.jcp.com/jobs/location/191170/winchester-va-united-states) - Apple Blossom Mall Read more
Sephora Beauty Advisor - *Apple* Blossom Ma...
Sephora Beauty Advisor - Apple Blossom Mall Location:Winchester, VA, United States (https://jobs.jcp.com/jobs/location/191170/winchester-va-united-states) - Apple Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.