TweetFollow Us on Twitter

Dialog Quake
Volume Number:6
Issue Number:4
Column Tag:Assembly Lab

Dialog Quake For April Fools

By Mike Scanlin, Mountain View, CA

It started off much like any other day. By 11 AM it was obvious that today would be little different. Our accountant, who is annoying to begin with, was being especially antagonistic today. There I was peacefully coding away when all of a sudden about 210 little 3-hole punch droppings come floating down to land on my computer, on my desk, in my open drawers, etc. I turn around and see our accountant standing on tippy-toes peering over my five foot divider with a manly swoosh and a silly grin on his face saying “Gotcha, Prophead! Ha, ha, ha ” So I say to myself “Looks like Goobs’ immaturity is flaring up this morning. Hope it goes away by noon.” I manage to get in a couple of serene hours of blissful programming before Goobs’ maturity level nose dives to the 3rd grade for the second time that day. Just as I was typing in an especially efficient arithmetic shift right instruction about 29 triangular pieces of yellow paper sift through the air and land on their smaller round brothers. And I hear the maniacal laughter of an obviously sexually frustrated person behind me “Gotcha again, Dweeb. Heh, heh, heh ” I look up the number for Rent-An-Accountant but the line is busy. I brush the yellow triangles off my keyboard and make an optimization that has to do with the number three. Like any child not getting the attention it wants, Goobs resorts to more direct methods of assault. If you’ve ever been in the middle of a tricky piece of self-modifying, recursive, threaded code while having soccer balls and volleyballs bounced off your head then you can appreciate the kind of nuisance a bored accountant can be. I was counting the microseconds until 5 PM. It came. Goobs left. I laughed. I laughed again. Little did Goobs, the living embodiment of a feeble minded user, realize that the one thing you don’t want to do in a software company is mess with a hacker.

DIALOG QUAKE

I needed to do something to his system that would be annoying but not render it useless. I considered installing TMON on his system and turning on heap scramble but he works with multi-megabyte data files over a network and I figured that would make his system too unusable. Besides, he’s slow enough anyways that he wouldn’t realize I had done anything. It had to be more obvious. I thought about remapping his keyboard but that would definitely make it unusable. After experimenting with patches to _NewControl and _SizeControl that made all of his scroll bars 6 pixels wide I decided to go with a patch to _ModalDialog instead (there were problems with some applications in resizing their controls behind their back -- it did look cool in the Finder, though). The code that follows is an INIT written in Lightspeed C 3.0 (actually, Lightspeed Asm 3.0) that patches _ModalDialog. The effect of this patch is that all modal dialogs will shake around a bit. This patch does not make modal dialogs useless, but it does make them somewhat difficult to use (How’s your mouse coordination, Goobs?).

The _ModalDialog patch is a pre-patch and a tail patch. Once the patch has been installed, a call to _ModalDialog will temporarily patch _GetNextEvent, set up the tail patch, call the real _ModalDialog, return to the tail patch, remove the _GetNextEvent patch and exit normally (if anyone can use the word “patch” more times in a sentence, please let me know). All of the real work is done by the _GetNextEvent patch.

The new _GetNextEvent calls the existing _GetNextEvent and then does some additional work. It keeps track of a counter so that a random amount of time passes between calls to _MoveWindow (to give the movement more of a jagged, quake-like feel). The window is moved by a random amount in both directions in the range -7 to +7. There is a mildly interesting problem in generating this range of random numbers. It would be easier to generate the range -8 to +7 because that is the range that can be expressed with 4 bit signed number. However, I needed a mean of zero in my randomness so that the window wouldn’t have a tendency to shake itself off the screen. One solution would be to generate the range 0 to 14 (with a DIVU instruction) and subtract 7 but like most conscientious programmers, I stay as far away as possible from 150 cycle instructions. Here’s what I ended up doing (say there are random bits in D0):

;1

;preserve the sign bit and the low 3 bits
 andi #0x8007,D0
;if it’s positive, then we’re done (0..+7)
 bpl.s  @1
;clear the sign bit
 bclr #15,D0
;negate it (0..-7)
 neg  D0
@1

If anyone has a better way, please write in.

SATISFACTION

It was thoroughly satisfying to watch Goobs try and use his system the next day. Every time he went to print something he’d come over and whine that I had to fix his computer. I hadn’t yet admitted that I had done anything to his system and when I saw a shaking dialog on his screen I said “Looks like a virus to me. What’s it worth to you?” After his relentless whimpering I told him “You need to replace the Easy Access file in your System Folder with a newer version because the old version isn’t 32 bit clean or 100% compatible with Color Quickdraw and can cause problems with dialogs.” Wouldn’t you know it, that fixed the problem.

Hackers of the world, unite! You have nothing to loose but your sense of humor.

CREDITS

However much I would like to take all the credit for the ideas and the code presented here, I cannot. Were it not for my boss, Andy Jeffrey, none of this would have been possible. Thank you for having a sense of humor and maybe with a lot of hard work I can be just like you someday.


/* DialogQuakeINIT.c      5 June 89
 *
 * written by Mike Scanlin
 * inspiration by Andy Jeffrey
 * unwilling testing by Mr. “Goobs” Galvan
 *
 * INIT that installs a patch on _ModalDialog that
 * will, when _ModalDialog is called, install a
 * tail patch on _GetNextEvent that causes the
 * frontmost window to move around a bit (making
 * it hard to click on items with any real
 * accuracy). The patch to _GetNextEvent is
 * removed before _ModalDialog returns and the
 * patch to _ModalDialog can be removed by typing
 * cmd-option-shift-tab while a modal dialog is
 * frontmost.
 */
/* traps we patch */
#define ModalDialog0xA991
#define GetNextEvent 0xA970

/* uses a bit of self-modifying code */
#define JMP 0x4EF9

#define TAB_KEY  0x09
#define memFullErr -108

void  main(void);

void  main()
{
 asm  {
/* the next 20 or so lines are the only ones that
 * get executed during installation. They get some
 * space in the system heap for the patches and
 * then patch _ModalDialog. */
 
/* save register */
 move.l D4,-(SP)
 
/* get the old trap address */
 move #ModalDialog,D0
 _GetTrapAddress

/* set the address for the JMP instruction that
 * calls the original trap */
 lea  @origMD,A1
 move.l A0,(A1)

/* get some space in the system heap for our 
 * patches (note that this space is for both
 * patches) */
 lea  @last,A0
 lea  @modalDialogPatch,A1
 suba.l A1,A0
 move.l A0,D0
 move.l D0,D4
 _NewPtrSYS

/* if there’s not enough memory then abort installation */
 cmpi #memFullErr,D0
 beq.s  @noPatch
 
/* save address for _BlockMove */  
 move.l A0,-(SP)

/* set the trap address to the space we just got */
 move #ModalDialog,D0
 _SetTrapAddress

/* now move our patch into place */
 lea  @modalDialogPatch,A0
 move.l (SP)+,A1
 move.l D4,D0
 _BlockMove
 
@noPatch

/* restore register and exit installation code */
 move.l (SP)+,D4
 rts

/********************************************
 * Here’s the new _ModalDialog. It first installs
 * a tail patch on _GetNextEvent and then calls
 * the existing _ModalDialog. On exit this patch
 * will unpatch the _GetNextEvent patch.
 *******************************************/
@modalDialogPatch

/* save the original _GetNextEvent address */
 move #GetNextEvent,D0
 _GetTrapAddress

/* set the address for the JMP instruction that
 * calls the original trap */
 lea  @origGNE,A1
 move.l A0,(A1)

/* patch _GetNextEvent */
 lea  @getNextEventPatch,A0
 move #GetNextEvent,D0
 _SetTrapAddress

/* pop the original return address and save it */
 lea  @exitMD,A0
 move.l (SP)+,(A0)

/* set the return address to our patch */
 pea  @tailMDPatch
 
/* the nops get filled with the address of the
 * original _ModalDialog */
 dcJMP
@origMD nop
 nop

/* _ModalDialog returns here */

@tailMDPatch

/* remove the patch to _GetNextEvent */
 lea  @origGNE,A0
 move.l (A0),A0
 move #GetNextEvent,D0
 _SetTrapAddress

/* return to the place that called _ModalDialog */
 dcJMP
@exitMD nop
 nop
 
/********************************************
 * Here’s the new _GetNextEvent. If a random
 * amount of time has passed then call 
 * _MoveWindow to move the frontmost window
 * (a modal dialog) in a random direction.
 *******************************************/
@getNextEventPatch

/* pop the original return address and save it */
 lea  @exitGNE,A0
 move.l (SP)+,(A0)

/* save pointer to the event record so we can get
 * to it when the real _GetNextEvent returns */
 lea  @eventRecPtr,A0
 move.l (SP),(A0)

/* set the return address to our patch */
 pea  @tailGNEPatch
 
/* the nops get filled with the address of the
 * original _GetNextEvent */
 dcJMP
@origGNEnop
 nop

/* _GetNextEvent returns here */
@tailGNEPatch

/* save registers */
 movem.lD0-D2/A0-A2,-(SP)

/* if they don’t want us around, then exit */
 lea  @noMoreHassle,A0
 tst  (A0)
 bne  @goodBye

/* check if the event is a keyDown event */
 
 lea  @eventRecPtr,A0
 move.l (A0),A0
 move OFFSET(EventRecord,what)(A0),D0
 cmpi #keyDown,D0
 bne.s  @noKeyDown

/* it’s a keydown, but is it the special remove-us key? */
 move.l OFFSET(EventRecord,message)(A0),D0
 cmpi.b #TAB_KEY,D0
 bne.s  @noKeyDown
 move OFFSET(EventRecord,modifiers)(A0),D0
 andi #cmdKey + optionKey + shiftKey,D0
 eori #cmdKey + optionKey + shiftKey,D0
 bne.s  @noKeyDown

/* they don’t like us any more so remove ourself.
 * First beep to let them know that we got the
 * message to go away */
 move #1,-(SP)
 _SysBeep

/* set a flag so we know not to bother the nice
 * user any more */
 lea  @noMoreHassle,A0
 move #1,(A0)

/* move the frontmost window to a nice place in
 * case it was partially moved off the screen by
 * _MoveWindow */
 move.l WindowList,-(SP)
 move #30,-(SP)
 move #30,-(SP)
 bra.s  @moveToUpperLeft

@noKeyDown

/* has the timer expired? */
 lea  @timer,A0
 subi #1,(A0)
 bpl.s  @goodBye

/* reset the timer to wait a random amount of time
 * before expiring again */
 subq #2,SP
 _Random
 move (SP)+,D0

/* note: make the 0x3F smaller to move the window more often */
 andi #0x3F,D0
 lea  @timer,A0
 move D0,(A0)

/* push a WindowPtr for _MoveWindow. Note: this
 * does not check for Ghost Windows */
 move.l WindowList,A2
 move.l A2,-(SP)

/* get a couple of random numbers in the range [-7..+7] */
 subq #2,SP
 _Random
 move (SP)+,D1
 move D1,D2
 asr  #8,D1
 andi #0x8007,D1
 bpl.s  @2
 bclr #15,D1
 neg  D1
@2 ext  D2
 andi #0x8007,D2
 bpl.s  @3
 bclr #15,D2
 neg  D2
@3

/* push a random h coordinate */
 
 move OFFSET(GrafPort,portBits)+
 OFFSET(BitMap,bounds)+
 OFFSET(Rect,left)(A2),D0
 neg  D0
 add  D1,D0
 move D0,-(SP)
 
/* push a random v coordinate */
 
 move OFFSET(GrafPort,portBits)+
 OFFSET(BitMap,bounds)+
 OFFSET(Rect,top)(A2),D0
 neg  D0
 add  D2,D0
 move D0,-(SP)
 
@moveToUpperLeft
 sf-(SP)
 _MoveWindow
 
@goodBye

/* restore registers */
 movem.l(SP)+,D0-D2/A0-A2
 
/* return to _ModalDialog */
 dcJMP
@exitGNEnop
 nop

/* variables */
@noMoreHassle  dc0
@eventRecPtrdc.l 0
@timer  dc0

@last
 }
}

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

FileMaker Pro 19.4.2 - Quickly build cus...
FileMaker Pro is the tool you use to create a custom app. You also use FileMaker Pro to access your app on a computer. Start by importing data from a spreadsheet or using a built-in Starter app to... Read more
Adobe Illustrator 26.0.3 - Professional...
You can download Adobe Illustrator for Mac as a part of Creative Cloud for only $20.99/month. Adobe Illustrator for Mac is the vector graphics classics in the design industry. It is a digital... Read more
WhatRoute 2.4.9 - Geographically trace o...
WhatRoute is designed to find the names of all the routers an IP packet passes through on its way from your Mac to a destination host. It also measures the round-trip time from your Mac to the router... Read more
Notion 2.0.20 - A unified workspace for...
Notion is the unified workspace for modern teams. Notion Features: Integration with Slack Documents Wikis Tasks Release notes were unavailable when this listing was updated. Download Now]]> Read more
Monterey Cache Cleaner 17.0.2 - Clear ca...
Monterey Cache Cleaner is an award-winning general-purpose tool for macOS X. MCC makes system maintenance simple with an easy point-and-click interface to many macOS X functions. Novice and expert... Read more
Firetask Pro 4.6.8 - Innovative task man...
Firetask Pro represents the next generation of easy-to-use, project-oriented task management apps. By combining David Allen's powerful Getting Things Done (GTD®) approach with classical task... Read more
Smultron 13.0.4 - Easy-to-use, powerful...
Smultron 13 is the text editor for all of us. Smultron is powerful and confident without being complicated. Its elegance and simplicity helps everyone being creative and to write and edit all sorts... Read more
Box Sync 4.0.8057 - Online synchronizati...
Box Sync gives you a hard-drive in the Cloud for online storage. Note: You must first sign up to use Box. What if the files you need are on your laptop -- but you're on the road with your iPhone? No... Read more
Audio Hijack 3.8.10 - Record and enhance...
Audio Hijack (was Audio Hijack Pro) drastically changes the way you use audio on your computer, giving you the freedom to listen to audio when you want and how you want. Record and enhance any audio... Read more
Direct Mail 6.0.1 - Create and send grea...
Direct Mail is an easy-to-use, fully-featured email marketing app purpose-built for macOS. Create, send, and track great looking email campaigns that get results. Start your newsletter by selecting... Read more

Latest Forum Discussions

See All

Hopefully Not Jared’s Last Show – The To...
My suspicions from last week were correct, and after my two kids tested positive for Covid last week both my wife and I have now tested positive as well. It seems you just can’t escape this stuff lately. Thankfully the two little ones are pretty... | Read more »
TouchArcade Game of the Week: ‘Micro RPG...
I feel like idle games are one of those perfect fits for the mobile platform. Not that they replace more involved gaming experiences when you’re in the mood for that, but they do fit in alongside other types of games just fine as a “go to" when you... | Read more »
‘Phantom Blade: Executioners’ Closed Bet...
Phantom Blade: Executioners is holding a small-scale technical test that lets players get first dibs on the KungFuPunk action RPG. Offered to selected players only, S-Game’s first Closed Beta Test will provide players with limited edition in-game... | Read more »
New ‘Warhammer 40,000: Tacticus’ Video S...
Back in September Snowprint Studios, who you may know from their previous Legend of Solgard or Rivengard, announced that they’d partnered up with Games Workshop to put out a new tactical game in the Warhammer 40,000 universe titled Warhammer 40,000... | Read more »
SwitchArcade Round-Up: ‘Pokemon Legends:...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for January 28th, 2022. We’ve got a bunch of new releases to look at today, with a few big hitters, a few mid-level diversions, and a healthy supply of compost. Since it’s Friday, we... | Read more »
Phantom Blade: Executioners, S-Game...
S-Game has kicked off its first Closed Beta Test for Phantom Blade: Executioners, inviting a selected few to get first dibs on the upcoming KungFuPunk action RPG on mobile. The CBT officially begins this January 28th, and beta testers will receive... | Read more »
‘Infinite Galaxy’ First Anniversary: Cel...
Cultivating a new generation of valiant commanders across 240 countries worldwide, Infinite Galaxy has quenched players’ thirst to explore the vastness of space – and there are only more intergalactic adventures to embark on from here on out. Camel... | Read more »
War and Order: How to brave the cold in...
War and Order's 6th-anniversary celebrations are underway, and all in good time too - this season not only brings about fabulous festivities, but it also lets players experience the harsh winter in an entirely new way. [Read more] | Read more »
‘Hidden Folks+’ Is This Week’s New Apple...
The original Hidden Folks from Adriaan de Jongh is an excellent hidden objects game featuring hand drawn visuals. It is an absolute joy to play, and it has now released on Apple Arcade in the form of Hidden Folks+ () as an App Store great. If you’... | Read more »
Mini Metro’s First Big Update of 2022 Ad...
Last year saw great updates for Dinosaur Polo Club’s Mini Metro ($3.99) which is also available on Apple Arcade as an App Store Great. | Read more »

Price Scanner via MacPrices.net

Apple has clearance 2020 13″ MacBook Airs ava...
Apple has clearance, Certified Refurbished, 2020 13″ Intel-based MacBook Airs in stock today starting at only $719 and up to $370 off original MSRP. Each MacBook features a new outer case, comes with... Read more
The cheapest iPhones for sale today at Apple...
Apple has restocked Apple Certified Refurbished iPhone 8 models starting at only $359. Each refurbished iPhone comes with a fresh external case, standard Apple 1-year warranty, and free shipping.... Read more
14″ MacBook Pro with Apple M1 Max CPU now in...
Looking for a new 14″ MacBook Pro with an Apple M1 Max CPU? Stock is finally trickling into Apple resellers. B&H has Silver 14″ M1 Max MacBook Pros in stock today for $2899 including free 1-2 day... Read more
14″ MacBook Pros with Apple M1 Pro CPUs are i...
Amazon is reporting stock of 14″ MacBook Pros with M1 Pro CPUs today with a $50 discount. Shipping is free, and delivery is available by February 1st for most configurations. Be sure to make your... Read more
Apple has restocked 13″ M1 MacBook Pros for $...
Apple has restocked a full line of 13″ M1 MacBook Pros available Certified Refurbished, starting at only $1099 and up to $230 off original MSRP. These are the cheapest M1 MacBook Pros for sale today... Read more
Apple’s AirPods Max headphones are on sale fo...
Amazon has Silver, Blue, and Space Gray Apple AirPods Max headphones on sale today for $100 off MSRP. Shipping is free, and all models are in stock today. Their price is the lowest currently... Read more
Open a new line of service at Verizon and get...
Verizon is giving away 64GB Apple iPhone 12 minis or your choice of an iPhone 11 to customers who choose one of these phones and open a new line of service. Offer is available online only, and no... Read more
Open-box 13″ M1 MacBook Airs now available st...
QuickShip Electronics has open-box return 13″ M1 MacBook Airs in stock and on sale for $200-$400 off MSRP on their eBay store right now with free express delivery. According to QuickShip, “The item... Read more
Verizon’s 2022 iPad promo: $100-$310 off any...
Verizon has cellular-capable iPads on sale for $100-$310 off MSRP when purchased with an Unlimited service plan. Sale price is applied to your account monthly over a 24 or 30 month period, depending... Read more
Sunday Sale: Apple AirPods are on sale for up...
Amazon has Apple AirPods on sale for $10-$100 off MSRP today, depending on the model. All are in stock today with free delivery: – AirPods Max headphones (Blue): $449 $100 off MSRP – AirPods Max... Read more

Jobs Board

Registered Nurse (RN) Employee Health PSJH -...
…is calling for a Registered Nurse (RN) Employee Health PSJH to our location in Apple Valley, CA.** We are seeking a Registered Nurse (RN) Employee Health PSJH to be Read more
Systems Administrator - Pearson (United State...
…and troubleshoot Windows operating systems (workstation and server), laptop computers, Apple iPads, Chromebooks and printers** + **Administer and troubleshoot all Read more
IT Assistant Level 1- IT Desktop Support Anal...
…providing tier-1 or better IT help desk support in a large Windows and Apple environment * Experience using IT Service Desk Management Software * Knowledge of IT Read more
Human Resources Business Partner PSJH - Provi...
…**is calling a** **Human Resources Business Partner, PSJH** **to our location in Apple Valley, CA.** **Applicants that meet qualifications will receive a text with Read more
Manager Community Health Investment Programs...
…is calling a Manager Community Health Investment Programs PSJH to our location in Apple Valley, CA.** **Qualified candidates will be invited to do a self-paced video Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.