TweetFollow Us on Twitter

Reminder DA
Volume Number:4
Issue Number:3
Column Tag:Forth Forum

Time Manager Reminder DA

By Jörg Langowski, MacTutor Editorial Board, Grenoble, France

Jörg Langowski is a bio-chemical engineer for a french concern and is a founding and current board member of MacTutor. He can be reached at EMBL, c/o I.L.L. 156x, Grenoble, Cedex, France F-38042. We encourage European authors to contact Jörg directly about submissions to MacTutor.

“Using the Time Manager”

One thing I always wanted to have on my Mac is some utility that reminds me of an appointment, no matter what I’m doing on the machine at any given time. On our VAX, for example, there is this great program called Reminder which sits in the background and will beep at you when your next appointment arrives.

In the new system (128K ROMs and up) there exists a set of routines called the Time Manager. I thought it would be a good idea to show you their usage in developing a Reminder utility similar to the one on the VAX. In the process, I’ll show you how to work with modeless dialogs from a DA, how to call memory manager dependent traps from a time manager task, and some more.

The Time Manager

The Time manager is used to execute a task at a predetermined time. Its routines are documented in IM Vol. 4. All time manager tasks are described by entries in the time mamager queue, where each element has the following format:

header TMtask 14 allot
0 CONSTANT qLink
4 CONSTANT qType
6 CONSTANT tmTask
10 CONSTANT tmCount

That means, the queue entry looks just like a regular queue element, with two 4-byte fields, tmTask and tmCount, relevant to our task. tmTask contains a pointer to the routine to be executed, and tmCount is used by the system to count down the elapsed time. When it has reached zero, the task at tmTask will be executed.\

Three routines are provided by the time manager: InsTime, called with a pointer to the queue element in A0, will insert this queue element into the time manager queue. PrimeTime, with the queue element pointer in A0 and a 32-bit count in D0, will schedule the routine specified in that queue element to be executed after count milliseconds have elapsed. RmvTime, with a pointer to the queue element in A0, will remove the queue element. The Mach2 interface to these routines is given at the beginning of listing 1.

Fig. 1 Our Reminder DA lets Mac Widows post alerts for late night programmers!

Programming the Reminder utility

The strategy to follow seems very simple: we create a desk accessory that allows us to enter a message text and a delay time, that desk accessory will then setup a queue element with a pointer to a routine that displays an alert box containing that string.

Thinking about it, programming such a utility is not quite so simple. First of all, the routine passed to the time manager for execution cannot be part of the desk accessory. We’d like to enter appointments that are due in several hours or days (32 bits of milliseconds, unsigned, give a maximum possible delay of 49.7 days), and we’ll most probably have left the application where the desk accessory was started by then. Under MultiFinder this doesn’t matter, but under Finder, the desk accessory would have been closed, leaving the task pointer point to anything but the desired code.

My first thought was to use a ‘stick-around’ desk accessory that would automatically restart itself after an involuntary close, like I described earlier. But it is actually much easier to put a copy of the routine to be executed into a small block of system heap, leaving it independent of the DA. Then, one has to take caution that the routine, once executed, will remove its own queue entry and dispose of its own memory.

The second problem is that a time manager task may be executed at any time, interrupting whatever else is being done at that moment. For the same reason as in the case of VBL tasks, we may not call any routines from the time manager task that can move things around in the heap. If we did, there would be a chance that the interrupt occurs right in the middle of a memory manager operation, or while a handle hangs around dereferenced somewhere.

The time manager task must therefore be rather simple. I use the same trick as I described for the ‘stick-around’ DA, patching SystemTask from the scheduled routine. The next time SystemTask is called (which should happen rather soon in any benign application) the patch routine will be executed, which then can do the more involved stuff such as drawing an alert box.

Now look at the first part of the example: the routine that is executed by the time manager is contained between the markers mytask and mytask.end. The first bytes of this block contain the queue element. The name string ‘Reminder’ follows for debugging purposes. Some local variable space is reserved, where the original SystemTask trap address, the alert ID and the alert message can be kept. The SystemTask patch routine alertMe follows. It will display a note alert with the message in parameter ^0, unlock the alert, remove the time manager queue element and dispose of the memory allocated for itself.

Fig.2 After time has elapsed, an alert pops up!

alertMe is patched into SystemTask by the following routine, wakeMe, which is the one first executed by the time manager. A pointer to wakeMe will be contained in the tmTask field of the queue element at the beginning of the block. Since we do not know yet where this routine will be located, we’ll have to install the pointer after moving the code into the system heap.

As you see, the code between mytask and mytask.end is completely self-contained (as long as the ALRT resource can be found). We may therefore move any number of these little code blocks into the system heap and install their queue elements using the time manager; each will be executed at its scheduled time and display its little message. Appointment ‘objects’, so to say.

The desk accessory

The DA is used to install the tasks. It is a very simple DA which just draws up a modeless dialog box with two editable text items. The dialog window will have the driver reference number in its windowKind field, so that the system will handle mouse down events in the close box and drag region. Only when the event is passed through to the DA, windowKind will be temporarily set to 2 (dialog window), so that IsDialogEvent and DialogSelect work correctly.

When the OK button in the dialog box has been clicked, the dialog handler will be invoked. This routine converts the string in item 4 to a number, the delay in seconds, and gets the message to be displayed after this delay (item 3). These parameters are passed to install.wakeup, together with the alert ID. install.wakeup gets the wakeup routine described above from the resource file and installs a copy of it in the system heap. It saves a pointer to the wakeup routine in the tmTask field of the queue element, stores the alert ID and the message string at their appropriate positions and then schedules the routine for execution by calling InsTime and PrimeTime.

Things missing

The desk accessory described here is already quite useful ‘as is’. However, one could include some improvements that I leave as an exercise for you (or me, for that matter):

- Input of the appointment time in standard date format.

- Keeping a list of appointments that can be displayed and edited.

- Saving this list to a file every time it is changed; this file is then checked on system startup and the pending appointments rescheduled automatically.

I wish you good luck with those experiments; now, some mail that I recently received.

Feedback Dept.

“Dear Jörg,

I read your recent column in MacTutor with great interest and would like to obtain the addresses for Serge Rostan and also for Winsoft. [Serge Rostan, “TechnoPro”, rue Faraday, F-78180 Montigny le Bretonneux, France, phone (33) 1 30 45 26 62, and Winsoft, 34, boulevard de l’Esplanade, F-38000 Grenoble, France, phone (33) 76 87 56 01 - JL].

We are in the process of completing a book on fonts for the Macintosh for European and many other non-Roman languages. It will also show specimens of over 2000 bit-mapped and several hundred PostScript fonts.

If you can suggest any font vendors that do not advertise in US Macintosh magazines, it would be very helpful [not off the top of my head, but I’ll look around - JL].

As you may know, Apple refuses to sell European keyboards in the US, even to certified developers. Users here must cultivate acquaintances overseas and buy them indirectly. Do you know whether Apple tries to prevent the export of such keyboards from Europe? We would like to be able to list a commercial source for such keyboards in our book, but do not want to cause difficulties for anyone there. If they are readily available for export, we would appreciate the name of a recommended source.

[You address a problem that I’ve encountered myself. There seems no way for Macintosh developers in France to get other than French keyboards through the developer program. However, there is at least one Apple dealer in Grenoble who sells the US keyboard on request; we have several international research institutions here, so there’s a market. I’ll send you addresses of some Apple dealers in Germany and France that you might be able to order from.

I don’t think there are any export restrictions imposed by Apple on non-US keyboards into the US (unless you re-sell them to Colonel Kh...). The problem most probably is the bureaucracy that inevitably builds up in a large corporation, even one like Apple that for a while tried to maintain some ‘non-conformistic hacker’ kind of image. Which it is trying to forget at a rapid rate, I presume. Someone, it seems, must have set a guideline that in country X only systems localized for X will be sold, with few exceptions. The only way I get the most recent US system updates is through US sources, too. Funniest of all: The MacII system that I finally got a week ago (yes, I love it), has English documentation, US system disks (but 4.1, not 4.2, which is not officially released at the time I write this), but no way can I get a US keyboard. Probably the people at Apple France just wanted to be nice and ship me as many US parts as possible, but then they had only French keyboards. What a nuisance to have all the numbers on the top row...]

Lastly, Apple also tries to limit the availability of any Script Manager code or fonts it has developed to the country for which it was developed! This seems strange given that the Macintosh is touted as a Multinational machine. Apple has made Kanji and Arabic available through APDA, but feels that they are sufficient for the testing purposes intended. They have also developed a Chinese, a Hebrew and a Greek. The Chinese is distributed from Hong Kong and the Hebrew and Greek are distributed from Paris. I have written to the Paris office to no avail after a conversation with Mark Davis at Apple, the creator of the Script Manager. Do you know of a way for someone in the US to get these fonts from Paris? Actually, I am more interested in finding out the arrangement of characters in the coding table than I am in the font, but the exact status of ‘dead’ keys might be hard to discern accurately without actually having the font in hand.

Best regards,

Tim Ryan, SourceNet, Santa Barbara, CA “

[You address a very timely issue, that’s why I have your letter printed immediately without having the answers on hand yet. I’ll forward your mail with my comments to Apple France. I’m actually quite optimistic that you can get the Script Manager versions that you want. JL]

One comment to the letter from Peter Adamson, MT V4#1, p.11: The Pascal equivalent to the Mach2 PAUSE is actually WaitNextEvent; much like PAUSE under Mach2, WaitNextEvent will transfer control to the next MultiFinder task under certain circumstances. If you have a very long event loop, you may try to intersperse WaitNextEvents with event masks of zero, so that they’ll always return a null event. That should transfer control to the next task under MultiFinder. Only the crucial WaitNextEvent - the one with the BIG case statement behind it - would be called with a non-zero event mask. This is all untested, so don’t blame me if it doesn’t work.

See you next month.

Listing 1: Appointment reminder using the time manager
\ ***** Time manager example - a ‘reminder’ utility
\ J. Langowski December 87 
\
\ Strategy: write a driver that sets up a dialog which allows 
\ to enter a time & message to display after that time. After 
\ the appointment has been entered, the driver sets up a 
\ time manager call for that appointment.
\ The time manager routine installs a SystemTask trap 
\ patch which at the next occasion will draw an alert box 
\ containing the message to be displayed. 
\
\ Note that we have to use the patch rather than calling 
\ the alert routine directly from our time manager task,
\ since we can’t be sure we’re not in the middle of a 
\ memory manager operation when it is called.
\

only forth also assembler also mac

CODE InsTime ( tmTaskPtr | -- )
 MOVE.L (A6)+,A0
 _InsTime
 RTS
END-CODE MACH

CODE PrimeTime ( tmTaskPtr count | -- )
 MOVE.L (A6)+,D0
 MOVE.L (A6)+,A0
 _PrimeTime
 RTS
END-CODE MACH

CODE RmvTime ( tmTaskPtr | -- )
 MOVE.L (A6)+,A0
 _RmvTime
 RTS
END-CODE MACH

4ascii MENU constant “menu
4ascii PROC constant “proc

\ *** compiler support words for external definitions *** 
: :xdef 
 create -4 allot
 $4EFA w, ( JMP )
 0 w,  ( entry point to be filled later )
 0 ,   ( length of routine to be filled later )
 here 6 - 76543
;

: ;xdef { branch marker entry | -- }
 marker 76543 <> abort” xdef mismatch”
 entry branch - branch w!
 here branch - 2+ branch 2+ !
; 
 
: xlen 4 + @ ; ( get length word of external definition )

( *** driver header block *** )

 0 CONSTANT drvrFlags
 2 CONSTANT drvrdelay 
 4 CONSTANT drvrEMask
 6 CONSTANT drvrMenu
 8 CONSTANT drvrOpen
10 CONSTANT drvrPrime
12 CONSTANT drvrCtl
14 CONSTANT drvrStatus
16 CONSTANT drvrClose
18 CONSTANT drvrname
50 CONSTANT DAlength

\ *** compiler support words for DA and driver definitions 
: :DA 
 create -4 allot
 here 87654 ( start of DA block, and marker )
 50 allot   ( length of block )
;

: ;DA { DAstart marker Ropen Rprime Rctl Rstatus Rclose
 Rflags Rdelay Remask Rmenu Rname | -- }
 marker 87654 <> abort” DA definition mismatch”
 Ropen  DAStart - DAStart drvrOpen + w!
 Rprime DAStart - DAStart drvrPrime + w!
 Rctl   DAStart - DAStart drvrCtl + w!
 Rstatus  DAStart - DAStart drvrStatus + w!
 Rclose DAStart - DAStart drvrClose + w!
 Rflags DAStart drvrFlags + w!
 Rdelay DAStart drvrDelay + w!
 Remask DAStart drvrEmask + w!
 RMenu  DAStart drvrMenu + w!
 Rname count dup DAStart drvrName + c!
 DAStart drvrName + 1+ swap 
 dup 31 > if drop 31 then cmove 
 here DAstart -    DAStart DAlength + !
; 
 
: DAlen DAlength + @ ;
\ get length word of external definition

\ **** DA glue macros

CODE DA.prelude
 LINK A6,#-512 \ 512 bytes of local Forth stack
 MOVEM.L A0-A1,-(A7) \ save registers
 MOVE.L  A6,A3 \ setup local loop return stack
 SUBA.L   #256,A3  \ in the low 256 local stack bytes
 MOVE.L  A0,-(A6)  \ parameter block
 MOVE.L  A1,-(A6)\ device control entry
 RTS  \ just to indicate the MACHro stops here 
END-CODE MACH

CODE DA.epilogue
 MOVE.L  (A6)+,D0\ return code
 MOVEM.L (A7)+,A0-A1 \ restore registers
 UNLK A6
 RTS
END-CODE MACH

CODE DA.Jiodone
 MOVE.L  (A6)+,D0\ return code
 MOVEM.L (A7)+,A0-A1 \ restore registers
 UNLK A6
 move.l JIODone,A0
 movem.l d4-d7/a4-a6,-(a7)
 jsr    (a0)
 movem.l(a7)+,d4-d7/a4-a6
 RTS
END-CODE MACH

.TRAP _newptr,sys$A51E

%0000000101001010 CONSTANT DAEmask

$1B4 CONSTANT SystemTask

\ ____________________________________________
\ time manager and systemTask patch routine
\ this routine must reside in a block allocated 
\ in the system heap through a pointer. 
\ ____________________________________________

header myTask 14 allot
6 CONSTANT taskPtr
HEADER myName
 DC.B   9,0,’Reminder’
header myTrap 4 allot
header myAlert 4 allot
header myString 256 allot

: alertMe 
 MOVEM.LA0-A4/A6/D0-D7,-(A7)
 LINK A6,#-128 \ 128 bytes of local Forth stack
 (call) frontwindow windowkind + @
 2 <> IF
 [‘] myTrap @ SystemTask (call) SetTrapAddress
 [‘] myString 0 0 0 (call) paramText
 [‘] myAlert @ 0 (call) noteAlert drop
 [‘] myAlert @ (call) freeAlert
 [‘] myTask RmvTime
 [‘] myTask (call) DisposPtr drop
 THEN
 UNLK A6
 MOVEM.L(A7)+,A0-A4/A6/D0-D7
;

: wakeMe
 SystemTask (call) GetTrapAddr [‘] myTrap !
 [‘] alertMe SystemTask (call) SetTrapAddr
;

header mytask.end
‘ wakeme ‘ mytask - CONSTANT *wakeme \ task offset
‘ myAlert ‘ mytask - CONSTANT *myAlert \ alertID 
‘ myString ‘ mytask - CONSTANT *myString \ alert string

\ ___________________________________________
\ desk accessory code starts here.
\ ___________________________________________

:DA reminder 
 .ALIGN

( *** main desk accessory routines *** )
header myRes0 4 allot\ local res ID=0 offset 
header dlgText 256 allot

\ redefinition of cmove to make it 
\ available locally

CODE cmove
 move.l (a6)+,d0
 move.l (a6)+,a1
 move.l (a6)+,a0
 tst.l  d0
 ble.s  @2
@1 move.b (a0)+,(a1)+
 subq.l #1,d0
 bne.s  @1
@2 rts
END-CODE

\ ___________________
\ wakeup routine installation
\ ___________________

: install.wakeup 
 { delay alrtID msg | procHdl hSize taskBlock -- }
 
 “proc [‘] myRes0 @ (call) GetResource -> procHdl
 procHdl (call) getHandleSize -> hSize
 hSize MOVE.L (A6)+,D0
 _newPtr,sys
 MOVE.L A0,-(A6) -> taskBlock
 procHdl @ taskBlock hSize cmove
 procHdl (call) releaseResource
   \ we have made a local copy of the wakeup routine
 taskBlock dup *wakeMe + swap taskPtr + !
 msg taskBlock *myString + 256 cmove
 alrtID taskBlock *myAlert + !
 alrtID (call) CouldAlert
 taskBlock InsTime
 taskBlock delay PrimeTime
 \ now the wakeup routine will wake up after
 \ the scheduled delay.
;

: getDrvrID { dCtlEntry | -- num }
 dCtlEntry dCtlRefNum + w@ l_ext
 1+ negate
;

: ownResID ( resID drvrID )
 5 shl + -16384 +
;
: Open { parblk dce | DAWind Res0 -- returncode }
 5 (call) sysbeep 
 \ to get attention if automatically opened
 0 dce getDrvrID ownResID -> Res0
 dce dCtlWindow + @ -> DAWind
 DAWind 0= IF ( not open already )
 Res0 [‘] myRes0 !
 Res0 0 -1 (call) getNewDialog -> DAWind
 DAWind  dce dCtlWindow + !  
 \ store dialog pointer
 DAWind  dce dCtlRefNum + w@  
 swap windowKind + w!
 ELSE
 DAWind (call) selectWindow
 THEN
 0
;
: Close { parblk dce | -- returncode }
 dce dCtlWindow + 
 dup @ (call) DisposDialog  
 0 swap ! ( so that Open will work again )
 0
;
: dialog-handler 
 { dlgPtr itemHit | 
 itemType hItem rBox seconds -- }

\ we get here if the OK button in the dialog
\ has been hit, therefore itemHit is always =1 
\ - in our case. But it is nice to have itemHit
\ available, to be more general. 
\ item #3 contains the appointment message
\ item #4 contains the delay in seconds
\ (decimal number string)

 dlgPtr 4 ^ itemType ^ hItem ^ rBox (call) GetDItem
 hItem [‘] dlgText (call) GetIText
 [‘] dlgText (call) StringToNum -> seconds
 seconds 0> IF
 dlgPtr 3 ^ itemType ^ hItem ^ rBox 
 (call) GetDItem
 hItem [‘] dlgText (call) GetIText
 seconds 1000 w* 
 [‘] myres0 @ [‘] dlgText install.wakeup
 ELSE 10 (call) sysbeep
 THEN
;

: Ctl { parblk dce | 
 DAWind event-rec dlgPtr itemHit -- returncode }
 dce dCtlWindow + @ -> DAWind

 parblk csCode + w@ l_ext 
 CASE
 accEvent OF
 2 DAWind windowKind + w! 
 \ set to dialog window 
 parblk csParam + @ -> event-rec
 event-rec (call) IsDialogEvent
 IF  event-rec ^ dlgPtr ^ itemHit
 (call) Dialogselect
 IF dlgPtr itemHit dialog-handler THEN
 THEN
 DAWind  dce dCtlRefNum + w@  
 swap windowKind + w! 
 \ reset windowkind
 ENDOF

 ENDCASE
 0
;
: DrOpen DA.Prelude Open DA.Epilogue ;
: DrClose DA.Prelude Close DA.Epilogue ;
: DrCtl DA.Prelude Ctl DA.JioDone ;
: DrStatus ;
: DrPrime ;

‘ DrOpen ‘ DrPrime ‘ DrCtl ‘ DrStatus ‘ DrClose
$7400 \ need lock, need time, need goodbye, ctl calls
60 DAEmask 0 \ delay mask menu
“ Reminder” \ name
;DA


( write resource to file ) 
: $create-res ( str-addr - errcode )
 call CreateResFile
 call ResError L_ext
;
: $open-res { addr | refNum - refNum or errcode }
 addr call OpenResFile -> refNum
 call ResError L_ext
 ?dup IF ELSE refNum THEN
; 
: close-res ( refNum - errcode )
 call CloseResFile
 call ResError L_ext
;
: make-res { addr len rtype ID name | -- }
 addr len call PtrToHand 
 abort” Could not create resource handle”
 rtype ID name call AddResource
;
: write-out { filename | refnum -- } 
 filename $create-res 
 abort” That resource file already exists”
 filename $open-res
 dup 0< abort” Open resource file failed”
 -> refnum
 refnum call UseResFile
 [‘] reminder dup DALen
 “drvr 12 “ Reminder” make-res
 [‘] myTask [‘] mytask.end over - 
 “proc -16000 “ wakeUp” make-res
 “proc -16000 call GetResource
 dup 80 call SetResAttrs  
 ( 64: sysheap + 16: locked )
 call ChangedResource
 refnum close-res 
 abort” Could not close resource file”
;
: make-DA
 “ Reminder.rsrc” $delete drop
 “ Reminder.rsrc” write-out
;
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

BusyCal 3.7.2 - Powerful calendar app wi...
BusyCal is the powerful, flexible, reliable calendar app for macOS. It's packed with time-saving features and compatible with all leading cloud services including iCloud, Google, Exchange and more.... Read more
BusyContacts 1.4.2 - Fast, efficient con...
BusyContacts is a contact manager for OS X that makes creating, finding, and managing contacts faster and more efficient. It brings to contact management the same power, flexibility, and sharing... Read more
iShowU Instant 1.3.0 - Full-featured scr...
iShowU Instant gives you real-time screen recording like you've never seen before! It is the fastest, most feature-filled real-time screen capture tool from shinywhitebox yet. All of the features you... Read more
Capo 3.8 - Slow down and learn to play y...
Capo lets you slow down your favorite songs so you can hear the notes and learn how they are played. With Capo, you can quickly tab out your songs atop a highly-detailed OpenCL-powered spectrogram... Read more
Viber 11.7.0 - Send messages and make fr...
Viber lets you send free messages and make free calls to other Viber users, on any device and network, in any country! Viber syncs your contacts, messages and call history with your mobile device, so... Read more
Drive Genius 5.3.1 - $79.00
Drive Genius features a comprehensive Malware Scan. Automate your malware protection. Protect your investment from any threat. The Malware Scan is part of the automated DrivePulse utility. DrivePulse... Read more
CorelDRAW 21.2.0.708 - Graphic design so...
CorelDRAW - professional graphic design software for vector illustration, layout, and so much more. Get started quickly and easily with a wealth of intuitive tools, built-in learning materials,... Read more
Navicat Premium Essentials 12.1.27 - Pro...
Navicat Premium Essentials is a compact version of Navicat which provides basic and necessary features you will need to perform simple administration on a database. It supports the latest features... Read more
OmniFocus 3.4.3 - GTD task manager with...
OmniFocus is an organizer app. It uses projects to organize tasks naturally, and then add tags to organize across projects. Easily enter tasks when you’re on the go, and process them when you have... Read more
Microsoft OneNote 16.30 - Free digital n...
OneNote is your very own digital notebook. With OneNote, you can capture that flash of genius, that moment of inspiration, or that list of errands that's too important to forget. Whether you're at... Read more

Latest Forum Discussions

See All

Breakout: Dark Prison is a fast-paced ac...
Breakout: Dark Prison is an action RPG from LaterSoft. Set in the aftermath of a deadly virus outbreak your daughter has been taken from you because she has an immunity to the illness in her DNA. Not being a fan of experimentation on children –... | Read more »
Apple Arcade in review
This weekend, Apple Arcade will officially be one month old. That means anyone who signed up for the free trial on day one has a decision to make: Stick with the service and shell out $5 a month, or cancel and go about your merry way. | Read more »
Alluris is a choose-your-own adventure g...
Alluris is an RPG that the developer's are calling a swipe-your-own adventure game. This is because the game incorporates a Reigns-style - swiping left or right - selection mechanic to make all the decisions you'd usually expect to make across... | Read more »
Hello Hero All Stars receives update wit...
The first Hello Hero game hit global platforms in 2013 and proved a huge success, with developer Fincon adding two more entries to this popular series of casual RPG games since. Released in June this year, Hello Hero All Stars brings many of the... | Read more »
Zombieland: Double Tapper, a cartoon idl...
Zombieland: Double Tapper is the idle RPG tie-in to the upcoming Zombieland: Double Tap. Oddly, it's one of two different Zombieland games launching today, with the other being the Switch title Zombieland: Double Tap - Road Trip. [Read more] | Read more »
Rusty Lake's The White Door launche...
Rusty Lake and Second Maze's intriguing point-and-click adventure game, The White Door, is now up for pre-order on the App Store. This one sees you playing as Robert Hill, a mental health patient who is suffering from severe memory loss. The game... | Read more »
Hellrule is an auto-runner inspired by G...
Hellrule is an upcoming auto-runner game from independent developer Pedrocorp where players will take control of a dapperly dressed gentlemen who comes equipped with a razor-sharp umbrella for slicing up his foes. The game will be available for... | Read more »
Grobo is a gravity bending puzzle platfo...
Grobo is a 2D puzzle platformer that marks the first release from developers Hot Chocolate Games. You'll find yourself manipulating gravity as you make your through this title that's available now for iOS and Android. [Read more] | Read more »
Adrenaline, Compulsive Entertainment’s h...
Compulsive Entertainment’s high-octane arcade racer, Adrenaline, has now made its way to the App Store following a successful launch on Google Play. It’s a ton of challenging, fast-paced fun, boasting easy-to-learn controls and a varied selection... | Read more »
Mario Kart Tour is adding Super Mario Ga...
Earlier today on Twitter, Nintendo announced that Mario Kart Tour is getting a new racer and track. Fans of Super Mario Galaxy will be pleased to hear that Rosalina is the first post-launch character being added, while the iconic Rainbow Road is... | Read more »

Price Scanner via MacPrices.net

11″ WiFi iPad Pros on sale today for up to $2...
Amazon has new 2018 Apple 11″ WiFi iPad Pros in stock today and on sale for up to $250 off Apple’s MSRP. These are the same iPad Pros sold by Apple in its retail and online stores. Be sure to select... Read more
Apple offers clearance 2018 15″ 6-Core MacBoo...
Apple has clearance 2018 15″ 6-Core Touch Bar MacBook Pros, Certified Refurbished, available starting at only $1999. Each model features a new outer case, shipping is free, and an Apple 1-year... Read more
Apple continues to offer refurbished 2019 21″...
Apple has Certified Refurbished 2019 21″ & 27″ iMacs available starting at $929 and up to $350 off the cost of new models. Apple’s one-year warranty is standard, shipping is free, and each iMac... Read more
Verizon offers free iPhone 7 for customers wh...
Verizon is offering a free 32GB iPhone 7 for new or existing customers who open a new line of service, no trade-in required. Cost of the phone is credited to your account monthly for 24 months. The... Read more
13″ 2.4GHz 4-Core MacBook Pros remain availab...
Apple has a full line of Certified Refurbished 2019 13″ 2.4GHz 4-Core Touch Bar MacBook Pros available starting at $1529 and up to $300 off MSRP. Apple’s one-year warranty is included, shipping is... Read more
Lease one iPhone Xs, Xr, or X at Sprint and g...
Purchase an Apple iPhone X, Xr, Xs, or Xs Max at Sprint, and get a 64GB iPhone Xr for free. Requires 2 new lines or 1 upgrade-eligible line and 1 new line. The fine print: “iPhone Xs (64 GB) $37.50/... Read more
How to use your Apple Education discount to s...
Purchase a new MacBook Pro or MacBook Air using Apple’s Education discount, and take up to $200 off MSRP. All teachers, students, and staff of any educational institution with a .edu email address... Read more
Base 2019 13″ 1.4GHz 4-Core MacBook Pro on sa...
Amazon has the new 2019 13″ 1.4GHz/128GB 4-Core Space Gray Touch Bar MacBook Pro on sale for $100 off Apple’s MSRP. This is the same MacBook Pro sold by Apple in its retail and online stores: – 2019... Read more
Save up to $30 on Apple’s AirPods at these re...
Amazon is offering discounts on new 2019 Apple AirPods ranging up to $30 off MSRP. Shipping is free: – AirPods with Charging Case: $144 $15 off MSRP – AirPods with Wireless Charging Case: $169 $30... Read more
Save $15 on Apple Watch Series 5 models on Wa...
Walmart has new Apple Watch Series 5 models on sale for $15 off Apple’s MSRP on their online store. Choose free shipping or free local store pickup (if available). Sale prices for online orders only... Read more

Jobs Board

*Apple* Mobile App Developer - eiWorkflow So...
…eiWorkflow Solutions, LLC is currently looking for a consultant for the following role. Apple Mobile App Developer Tasks the role will be performing: ? Mobile App Read more
Essbase Developer - *Apple* - Theorem, LLC...
Job Summary Apple is seeking an experienced, detail-minded Essbase developer to join our worldwide business development and strategy team. If you are someone who Read more
Best Buy *Apple* Computing Master - Best Bu...
**738230BR** **Job Title:** Best Buy Apple Computing Master **Job Category:** Store Associates **Location Number:** 000233-Almeda-Store **Job Description:** The Core Read more
Best Buy *Apple* Computing Master - Best Bu...
**738182BR** **Job Title:** Best Buy Apple Computing Master **Job Category:** Sales **Location Number:** 000036-Independence MO-Store **Job Description:** **What Read more
*Apple* Mobility Pro - Best Buy (United Stat...
**741450BR** **Job Title:** Apple Mobility Pro **Job Category:** Store Associates **Location Number:** 000168-Mentor-Store **Job Description:** At Best Buy, our Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.