GoodbyE Kiss

by Dan Weston

I'd like to inform the Mac community of a bug in the generic desk accessories that appear in my book, The Complete Book of Macintosh Assembly Language Programming, Vol I. Kirk Austin pointed out to me that the desk accessories crashed when receiving a goodbye kiss. The goodbye kiss is supposed to let your desk accessory clean up after itself if the application over which the accessory is running is terminated. For example, if your DA maintained open disk files or messed with low memory globals, you would normally close the files and reset the globals when a user closed the desk accessory. The goodbye kiss is provided by the Mac system software for those cases where the user quits an application without first closing the desk accessories. The underlying application doesn't need to be concerned with the goodbye kiss; it is handled totally by the Mac system software as it reinitializes the heap for the next program.

If you want your desk accessory to receive the goodbye kiss you must set bit #12 of the first word in the DA header. When an application terminates, the system software looks at each open desk accessory and sends a goodbye kiss if the appropriate bit is set in the DA header.

The goodbye kiss is a good idea. It prevents your desk accessory from being blown away without warning. The problem is that Inside Macintosh doesn't document how the goodbye kiss is implemented. In my book, I said that the goodbye kiss invoked the desk accessory's close routine. Now, after investigating a little further as a result of Kirk's letter, I find that the goodbye kiss doesn't invoke the close routine. Instead, the goodbye kiss is a control call with CSCode = -1. This causes big problems for my DA code because I use a jump table based on the belief that CSCode will ALWAYS be between 64 and 73. When the -1 CSCode hits the jump table it heads for ozone city; reach for the reset button.

The solution is to put a special case at the beginning of the control routine to watch for the goodbye control call and route it around the jump table (or just disable the goodbye call in the header, as Kirk did).

The modified code section follows:

;--------------------------------- 
; Control handles the control messages, which are the heart
; of the driver. Code values range from 64-73 (*** and -1
; for goodbye kiss ***) enter with pointer to DCE in A1 
; and pointer to Paramblock in A0 

Control 
 
 MOVEM.LA3-A4,-(SP); preserve A3 - A4  
 MOVE.L A1,A4    ; keep DCE ptr in A4 
 MOVE.L A0,A3    ; keep Pblock ptr in A3
 MOVE.W CSCode(A3),D0; get control opCode Pblock 
 ;******* 
 CMP.W  #-1,D0   ; is this the goodbye kiss? 
 BEQ    DoGoodbye; goodbye routine 
 ;******* 
 SUB.W  #64,D0   ; adjust range to 0-9 
 ADD.W  D0,D0    ; multiply by 2 for table 
 MOVE.W ControlTable(D0),D0 ; offset to routine 
 JMP    ControlTable(D0)  ; jump to it  

;---------- Offset table for Control routines --------- 
; **almost** all possible control messages that can be sent to
; a DA are here. All the routines mentioned here should 
; return by branching to CtlDone. 

ControlTable:
   
DC.W  DoEvent-ControlTable; an event (64) 
DC.W  DoPeriodic-ControlTable ; a periodic interupt (65) 
DC.W  DoCursor-ControlTable ; adjust cursor on DA wind (66) DC.W
 DoMenu-ControlTable ; menu selection (67) 
DC.W  DoUndo-ControlTable ; undo (68)  
DC.W  CtlDone-ControlTable; *** code 69 is not used *** DC.W   DoCut-ControlTable
 ; cut (70)
DC.W  DoCopy-ControlTable ; copy (71) 
DC.W  DoPaste-ControlTable; paste (72) 
DC.W  DoClear-ControlTable; clear (73)  

;--------------------------------------------   
CtlDone:  
 MOVE.L A4,A1    ; return DCE ptr to A1
 MOVE.L A3,A0    ; return PBlock ptr to A0
 MOVEM.L(SP)+,A3-A4; A3 - A4 restored 

 MOVE.W #0,D0    ; no error 
 RTS    ; go back to calling program 

;----------------------------------------------------   
DoGoodBye:
 MOVE.L A4,A1    ; return DCE ptr to A1
 MOVE.L A3,A0    ; return PBlock ptr to A0
 MOVEM.L(SP)+,A3-A4; A3 - A4 restored  
 MOVE.W #0,D0    ; no error
 MOVE.L JIODone,-(SP); return vector for asynch calls 
 RTS    ; go back to calling program 
 
 BRA.S  CtlDone  
;-------------------------------------------------------- 

One other detail that is important to note is that the goodbye kiss is an asynchronous control call. All other calls to desk accessories are synchronous, which means that they can return with a simple RTS. Asynchronous calls, on the other hand, must return via the JIODone routine. The low memery global JIODone, holds a pointer to this system routine, which clears the request from the I/O queue. We move this pointer onto the stack and then RTS. This routes our return through the JIODone routine.

Thanks to Kirk for bringing this to my attention. If anyone else has bugs to report from the book I'd love to hear about them. As best I can, I'll fix the bugs and post the information here in Mactutor.