TweetFollow Us on Twitter

Forth Blocks
Volume Number:1
Issue Number:10
Column Tag:Forth Forum

"Converting Forth Blocks to Ascii Text"

"Accuracy in Modula-2 Reviewed"

By Jörg Langowski, Chemical Engineer, Fed. Rep. of Germany, MacTutor Editorial Board

With the advent of other Forth systems than MacForth, and Forth-related packages such as NEON, a utility is needed that lets us quickly convert the MacForth 'Blocks' format into a standard ASCII text file and back. NEON, for instance, expects its input from a normal text file. Also this Journal expects its input from a MacWrite file, and after I have written an example program, cutting it out of the Forth screens and pasting it into my column is quite cumbersome.

So here is a routine that does this job automatically (it contains some ideas out of a program on one Call-A.P.P.L.E. public domain disk). At the same time we are going to learn something about the Standard File Interface package, which is undocumented (but fully usable) in MacForth 1.1.

What do we need to know to convert files from Blocks to Text format and back? The type of a Blocks file is BLKS and the creator M4TH, a Text file such as saved by 'text only' MacWrite or MDS Edit is of type TEXT and creator MACA (this probably stands for Mac Ascii). In principle, both files contain ASCII text, which, however, is organized differently.

The format of a Blocks file

MacForth blocks files consist of screens , each of which contain 16 lines of 64 characters. One line is always 64 characters long and padded with blanks after the last character. This format is a relic from early FORTH times and - in my opinion - rather obsolete. But since the MacForth editor uses it, we have to live with it. The length of a file is of course very simply related to the number of screens; each screen occupies exactly 1024 bytes.

Text files, on the other hand, contain lines of ASCII characters which are separated by carriage returns (CR).

One very simple thing that one can try out to communicate between the two types of files is to change type and creator of a Blocks file to TEXT and MACA, hoping that it is recognized by Edit, for example. When I tried this, it would show a file that had only one line (of course, since there are no CRs). So we do have to read the Blocks file, line by line, and create a new text file to which we write those lines.

Reading Forth blocks

A Forth block in a file is accessed through the word BLOCK, which accepts the block number on top of stack and returns the address of a buffer that contains the block. The block is automatically read in if it is not already there.

The position of a line in the block is at (64 * line number). The word >LINE.START in the program example returns the address of a line in a given block. We then remove trailing blanks from this line, add a CR at the end and write it to the Text file (which we have opened before). This is what the word COPY.BLOCK does, which is called from the main menu: It traverses the Blocks file line by line and writes the Text file.

ASCII to Blocks conversion

The reverse direction is a little bit more complicated. The total number of lines in a blocks file is known exactly from its size, so we know ahead of time how many screens we have to convert; also a Text file can be extended arbitrarily by just adding lines. Not so the other way around: a Blocks file must be extended by appending blocks before writing to them, and the end of a Text file is known only when an end-of-file occurs.

In the example, each text line is read into the string variable TEXT.BUF with the character count in the first byte and the actual line in the following bytes. This string is then copied into a new line in the buffer; when 11 lines have been processed in this way, the buffer is written out to disk (UPDATE FLUSH) and the Blocks file extended by one block. The last five lines of each block stay blank for easier editing. Some editing is necessary because the block boundaries will often split your definitions.

Choosing input and output files - the standard file package

So the principle of this utility routine has been set up. But we still have to open the files that we want to work on. To make file access more comfortable, let's use the standard Macintosh file package to select those files.

You've seen the dialog boxes that make up the interface to this package many times. Whenever you are supposed to select a file for input, a Mac application that conforms to the User Interface standards will show you a list of files to select from and option buttons that let you change drives, eject disks or quit the operation.

When you select a file for output (or save) you are presented with an input box with a default file name:

and when the file name that you give already exists on that disk, the standard file package will ask for reconfirmation to overwrite that file.

All these functions are built into two toolbox routines, SFGetFile and SFPutFile. MacForth provides built-in interfaces to those routines, the words (GET.FILE) and (PUT.FILE). The Forth words expect less parameters than the corresponding toolbox traps.

(GET.FILE) needs, from bottom to top of stack:

- a point (2*16 bit) where the top left of the dialog box is to be located;

- the address of a prompt string (zero for no prompt);

- the address of a list of file types to be displayed;

- the number of different file types;

- the address of a reply record.

(PUT.FILE) needs:

- the top left point;

- the address of a prompt string;

- the address of a string which may contain the default file name and later contains the actual file name;

- the address of a reply record.

Information about the user's response to the dialog box is contained in the reply record. The format is:

- 2 bytes boolean, true if OK, false if Cancel button was clicked;

- 4 bytes of file type information;

- 2 bytes integer, contain the volume reference number (important if volume was changed);

- 2 bytes integer, file version number, not used here;

- 64 bytes that contain the file name in Mac string format (count byte plus characters).

The list of file types is an array of 4 byte integers; each 4-byte cell contains one valid type designator, such as PICT, TEXT, DATA, etc. On calling (GET.FILE), only those files corresponding to one of the designators will be displayed. Invisible files will be displayed, too.

In our program, input and output files are set up using the standard file interface by the words TEXT.OPEN, BLOCK.OPEN, TEXT.CREATE and BLOCK.CREATE. After the dialog has been processed, the volume reference number (which might have been changed from the default volume) is moved into the file's FCB and the type and creator fields are set depending on whether a Text or a Blocks file is written. Thereafter, the actual file conversion takes place.

During the execution of the conversion routines the activate event is switched off. If you don't do this, the main Forth window would be activated again after the first file dialog has been processed, executing an ABORT and jumping back to the 'ok' prompt, quitting your program. Try this out and see what happens when you leave out line 6 in the CHANGE.MENU definition.

With that little routine, creating MacWrite listings from your Forth programs will be easy now.

Floating point glitches in Modula-2

Even though I am responsible for Forth, I must make one more Modula comment.

Watch out when you're using math!

I have become extremely careful in this respect. The 32-bit routines are fast, true. In order to be useful, they should also give correct results (within rounding errors). This is not so. Try the example in listing 2 (WindowIO is a module of my own that just sets up a standard window for I/O). The program just keeps adding smaller and smaller numbers to 1.0, which I did originally as an accuracy test. The output is shown there, too. Sometimes the output routine seems to fail, sometimes the addition itself. And I thought this was a system I could use for some of my calculations in the lab oh well. No more comments.

Surprisingly enough, though, a non-linear curve fitting program that I wrote in Modula seems to work well, without major problems. It may be that the bug shows up only when the numbers are close to integers (???). Any comments from readers with similar experiences are appreciated, any help even more. (Richard Ohran, are you reading this? If not, a bug report will follow.)

Listing 1: Converting text to blocks files

( Forth <-> Ascii Conversion)              ( © 1985 MacTutor by J. Langowski 
)

: tx-blks ;

variable ifile#  -1 ifile# ! 
variable ofile# -1  ofile# !    
: ifile ifile# @ ;  : ofile ofile# @ ;

hex 4D414341 constant "maca decimal
create ="blks      "blks ,
create ="textdata  "text , "data ,

18 field +fcb.name    22 field +fcb.vrefnum
32 field +fcb.type    36 field +fcb.creator

( standard file reply record fields )
00 field +good    : @good  +good w@ ;
02 field +ftype   : @ftype +ftype @ ;
06 field +vrefnum : @vrefnum +vrefnum <w@ ;
10 field +fname

create ireply 80 allot    
ireply +fname constant iname
create oreply 80 allot    
oreply +fname constant oname
variable screen#        variable cur.line#
create text.buf 100 allot 
99 constant text.read.limit
5 constant ch.menu

: moverefnum  ( file#\reply -- )
    @vrefnum  swap >fcb +fcb.vrefnum w! ;

: get.input.name 
      >r >r >r
      100 100 xy>point  0   r>  r>  r@
      (get.file) page r> @good 
      0= if abort then  ;

: get.save.name
      page >r >r >r  
      100 100 xy>point  r>  r>  r@
      (put.file) r> @good 
      0= if abort then ;

: text.open  
    next.fcb ifile# ! 
    page ." Text file to convert:"
    ="textdata 2 ireply get.input.name
    iname ifile assign 
    ifile ireply moverefnum
    ifile open   ?file.error
    ifile rewind ?file.error ;

: block.open
    next.fcb ifile# ! 
    page ." Blocks file to convert:"
    ="blks 1 ireply get.input.name
    iname ifile assign 
    ifile ireply moverefnum
    ifile open  ?file.error  ifile select ;

: block.create 
   next.fcb ofile# !
   " Mac Tutor Blocks" 
   oname over c@ 1+ cmove
   " Save as:" oname oreply get.save.name
   oname ofile assign
   ofile oreply moverefnum ofile delete
   ofile create.blocks.file ?file.error
   ofile open ?file.error  ofile select
   2 ofile append.blocks  
   1 screen# !   0 cur.line# !
   0 block b/buf bl fill update flush ;

:  text.create 
   next.fcb ofile# !
   " Mac Tutor Text" oname over c@ 1+ cmove
   " Save as:" oname oreply get.save.name
   oname ofile assign    
   ofile oreply moverefnum ofile delete
   ofile create.file ?file.error
   ofile open ?file.error  ofile rewind
   ofile get.file.info
   "text ofile >fcb +fcb.type !
   "maca ofile >fcb +fcb.creator !
   ofile set.file.info  ;

: >line.start ( block\line -- addr of line)
  64 * swap block + ;

: write.line 
    >line.start 64 -trailing
    over over + 13 swap c!  ( add CR )
    1+  ofile write.text  ;

: write.screen
    dup 16 0 do dup i ( screen\line )
    over over . 2 spaces . cr ( debug )
    write.line  loop drop ( n ) ;

: copy.block  ifile get.eof b/buf /
    0 do  i . cr i write.screen
      do.events drop loop ;

: read.line  ifile current.position
   text.buf 1+  text.read.limit  
   ifile  read.text
   ifile current.position swap -  
   text.buf  c!  ;

: copy.line 
  read.line  ?eof not
  if cur.line# @ dup .
     64 * screen# @ dup . cr 
     block +  text.buf 1+  swap
     text.buf c@ 1- cmove  
     1 cur.line# +!  cur.line# @ 10 >
     if 0 cur.line# !   update flush
        1 screen# +!  1 ofile append.blocks
     then  do.events drop true
  else update flush false then ;

: copy.text  begin copy.line not until ;

: >text block.open text.create copy.block ;

: >block text.open block.create copy.text ;

: change.menu
    0 " Change" ch.menu new.menu
    " Forth->Ascii;Ascii->Forth;"  
    ch.menu append.items draw.menu.bar
    ch.menu menu.selection:
    1 activate.event scale -1 xor events !
    0 hilite.menu
     case  1 of  >text      endof
           2 OF  >block     endof endcase
    events on do.events abort ;

change.menu

Listing 2: Modula 2 FP 'accuracy test'

MODULE Accuracy;

FROM InOut IMPORT ReadCard, WriteCard, 
        WriteString, WriteLn, ClearScreen;
FROM RealInOut IMPORT ReadReal, GWriteReal;
FROM WindowIO IMPORT SetupWindow;
FROM EventManager IMPORT Button;
VAR  a,b : REAL;  
 
BEGIN
SetupWindow
("Accuracy test",40,40,350,450,4,9);
a := 1.0; b := 1.0;
WriteString 
("        a           b           a+b"); WriteLn;

REPEAT 
  b := b/10.0;
  GWriteReal(a,12); GWriteReal(b,12);
  GWriteReal(a+b,12); WriteLn;
  WHILE Button() DO END;
UNTIL (b = 0.0);

REPEAT UNTIL Button();

END Accuracy.

Listing 3: Output of the Accuracy program

(terminated before underflow occurred). Note that b is sometimes printed as zero, although a+b seems to be correct; and for some smaller values of b (1.0E-19 to 1.0E-25) a+b starts to behave very strange.

        a          b          a+b
    1.000000   0.1000000      1.100000
    1.000000   0.01000000     1.010000
    1.000000   0.00000000     1.001000
    1.000000   0.00010000     1.000100
    1.000000   0.00001000     1.000010
    1.000000   0.00000100     1.000001
    1.000000   0.00000010     1.000000
    1.000000   1.0000E-08     1.000000
    1.000000   1.0000E-09     1.000000
    1.000000   1.0000E-10     1.000000
    1.000000   1.0000E-11     1.000000
    1.000000   0.0000E-13     1.000000  ?
    1.000000   1.0000E-13     1.000000
    1.000000   1.0000E-14     1.000000
    1.000000   1.0000E-15     1.000000
    1.000000   1.0000E-16     1.000000
    1.000000   1.0000E-17     1.000000
    1.000000   0.0000E-19     1.000000  ?
    1.000000   1.0000E-19     2.844674  ???
    1.000000   1.0000E-20     1.184467  ??
    1.000000   1.0000E-21     1.018447  ??
    1.000000   0.0000E-23     1.001845  ??
    1.000000   1.0000E-23     1.000184  ?
    1.000000   1.0000E-24     1.000018  ?
    1.000000   1.0000E-25     1.000002  ?
    1.000000   0.0000E-27     1.000000  ?
    1.000000   1.0000E-27     1.000000
    1.000000   1.0000E-28     1.000000
    1.000000   1.0000E-29     1.000000
    1.000000   1.0000E-30     1.000000
    1.000000   1.0000E-31     1.000000
    1.000000   1.0000E-32     1.000000
    1.000000   1.0000E-33     1.000000
    1.000000   1.0000E-34     1.000000
    1.000000   1.0000E-35     1.000000
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

VOX 3.5.5 - Music player that supports m...
VOX just sounds better! The beauty is in its simplicity, yet behind the minimal exterior lies a powerful music player with a ton of features and support for all audio formats you should ever need.... Read more
WiFiSpoof 3.9 - Change your WiFi MAC add...
WiFiSpoof quickly and easily allows you to change your WiFi MAC address via hot-key or the system menu bar. Startup optimizations Fixed an issue with getting the correct Address for some devices... Read more
FileMaker Pro 19.6.3.302 - Quickly build...
FileMaker Pro is the tool you use to create a custom app. You also use FileMaker Pro to access your app on a computer. Start by importing data from a spreadsheet or using a built-in Starter app to... Read more
RapidWeaver 9.0.0 - Create template-base...
RapidWeaver is a next-generation Web design application to help you easily create professional-looking Web sites in minutes. No knowledge of complex code is required, RapidWeaver will take care of... Read more
Burn 3.1.6 - Easily burn data, audio, vi...
Burn... There are a lot of ways to approach burning discs. Burn keeps it simple, but still offers a lot of advanced options. Create data discs with advanced data settings like, file permissions, the... Read more
XMind Pro 22.11.3656 - Popular mind mapp...
XMind Pro claims to be the most popular mind-mapping tool on the planet. You can use it to work through an individual brainstorming session and it will record and collect inspirations as you go. It... Read more
A Better Finder Rename 11.58 - File, pho...
A Better Finder Rename is the most complete renaming solution available on the market today. That's why, since 1996, tens of thousands of hobbyists, professionals and businesses depend on A Better... Read more
Duet 3.2.0.0 - Use your iPad as an exter...
Duet is the first app that allows you to use your iDevice as an extra display for your Mac using the Lightning or 30-pin cable. Note: This app requires a iOS companion app. Release notes were... Read more
iStat Menus 6.70 - Monitor your system r...
iStat Menus lets you monitor your system right from the menubar. Included are 8 menu extras that let you monitor every aspect of your system. Features: CPU - Monitor cpu usage. 7 display modes,... Read more
Opera 95.0.4635.25 - High-performance We...
Opera is a fast and secure browser trusted by millions of users. With the intuitive interface, Speed Dial and visual bookmarks for organizing favorite sites, news feature with fresh, relevant content... Read more

Latest Forum Discussions

See All

Here’s Your Stinkin’ Proof of Life – The...
Yes, we are alive. After taking most of December off from recording we did our big end of year show with the intention of coming back in full force in the new year, but instead we just sort of… took another month off. I really apologize to those who... | Read more »
TouchArcade Game of the Week: ‘1 Bit Sur...
Well, if you’ve been following TouchArcade for a while and you generally have an idea of what our tastes are, then this week’s pick shouldn’t really be much of a surprise. Cool retro-style pixel graphics? Dungeon crawling mechanics? Roguelike... | Read more »
SwitchArcade Round-Up: Reviews Featuring...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for February 3rd, 2023. We start things off with a review of Fashion Police Squad from our pal Mikhail. Gosh, he’s quite the keener. After that, we look at the dozen or so new releases... | Read more »
The 10 Best Arcade Archives Beat-Em-Ups...
A little while ago, we put up a list of our favorite shoot-em-ups in Hamster’s Arcade Archives line-up. There are hundreds of games available thanks the weekly releases, so it can be a little hard to find the cream of the crop if you’re coming in a... | Read more »
Cyan announces iOS port for Myst to cele...
One of the best things about old games being remastered and ported is it gives people the chance to try those old games that were slightly too difficult when they were younger, and thanks to indie studio Cyan, mobile users can now experience the... | Read more »
‘Castle Crumble’ From ‘Spire Blast’ Deve...
Spire Blast developers Orbital Knight have released Castle Crumble () on Apple Arcade today. If you played Spire Blast you will right at home here, and I think I like it more based on the first few levels I played. It features cannonballs, magic... | Read more »
SwitchArcade Round-Up: ‘Life is Strange...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for February 2nd, 2023. We’ve actually got a little news to look at today, and that’s where we’ll start things. There are also a ton of new games, some of them very good (Life is Strange... | Read more »
‘Dead Space’ Remake Steam Deck Review –...
Need for Speed Unbound was one of the first new current generation only games to impress me on Steam Deck. I’ve played many games that have been ported to PC from other platforms and also games built for PC from the start, but it is always great... | Read more »
The Stunning Remake of ‘Myst’ Is Coming...
Indie developer Cyan who developed the 2021 reimagining of the classic Myst have just announced that it is coming to iOS as Myst Mobile. Myst Mobile will bring the complete experience to iPhone and iPad devices in the future. Considering the... | Read more »
Psychedelic Horror Experience ‘Happy Gam...
Amanita Design’s psychedelic horror experience Happy Game is out now on iOS and Android worldwide following its debut on Nintendo Switch and PC platforms a little while ago. Happy Game is a standard paid game on iOS and Android, and not included... | Read more »

Price Scanner via MacPrices.net

Deal Alert! 13″ M2 Midnight MacBook Air with...
Tiger Direct is continuing their Apple fire sale with this new 13″ M2 MacBook Air with 16GB of RAM and a 512GB SSD, in Midnight, for only $858.99 including $7 shipping. Their price is an amazing $841... Read more
Deal Alert! 13″ M2 Midnight MacBook Air with...
Tiger Direct is continuing their Apple fire sale with this new 13″ M2 MacBook Air with 16GB of RAM and a 256GB SSD, in Midnight, for only $707.99 including $7 shipping. Their price is a whopping $692... Read more
Deal Alert! 13″ M2 MacBook Pros with 16GB of...
Tiger Direct continues their Apple Fire Sale (see our home page for these latest amazing deals) by offering a $650 discount on new 13″ M2 MacBook Pros with 16GB of RAM and 256GB SSDs: – 13″ M2... Read more
Deal Alert! 13″ M2 MacBook Air with 16GB RAM...
Tiger Direct is continuing their Apple fire sale with this new 13″ M2 MacBook Air with 16GB of RAM and a 256GB SSD, in Space Gray, for only $757.99 including $7 shipping. Their price is a whopping $... Read more
Deal Alert! Apple iPad fire sale continues, n...
Apple retailer Tiger Direct continues to offer fire sale prices on new 2022 10th-generation iPads with prices as low as 50% off MSRP. This is am amazing deal, and we don’t know how long it will last... Read more
Deal Alert! Select Apple M1 10.9″ iPad Airs o...
Tiger Direct is offering a 48% discount on select Apple M1-powered 10.9″ iPad Airs. This is an amazing sale, and we don’t know how long it will last. Their prices are the lowest available among the... Read more
Deal Alert! Apple Studio Display with Nano-Te...
Tiger Direct has the Apple Studio Display (Nano glass, Tilt & Height Adjustable Stand) on sale for $1059 off Apple’s MSRP for a limited time. Shipping is free: – Studio Display (Nano glass, Tilt... Read more
Deal Alert! Apple 10th-generation 64GB WiFi i...
Tiger Direct has the Apple 10th-generation 64GB WiFi iPad (in Silver) in stock today and on sale for $224.99 shipped. Their price is $225 (50%) off Apple’s MSRP. That’s an amazing deal, and we... Read more
New sale at Sams Club: Take $60 off every App...
Sams Club has Apple Watch Series 8 models on sale for $60 off Apple’s MSRP from now through Valentine’s Day 2023. $45 Sams Club Membership required. Note that sale prices are for online orders only,... Read more
Apple to update HomePod mini, AirPods Max, an...
Analyst Ming-Chi Kuo, in his latest post, predicts that Apple will update their ‘acoustic’ products next year sometime. He believes that it will be in the middle of 2024 before Apple will release the... Read more

Jobs Board

Hair Stylist - *Apple* Blossom Mall - JCPen...
Hair Stylist - Apple Blossom Mall Location:Winchester, VA, United States (https://jobs.jcp.com/jobs/location/191170/winchester-va-united-states) - Apple Blossom Read more
Optometrist- *Apple* Valley, CA- Target Opt...
Optometrist- Apple Valley, CA- Target Optical Date: Feb 3, 2023 Brand: Target Optical Location: Apple Valley, CA, US, 92308 **Requisition ID:** 796045 At Target Read more
Sales Floor Associate - *Apple* Blossom Mal...
Sales Floor Associate - Apple Blossom Mall Location:Winchester, VA, United States (https://jobs.jcp.com/jobs/location/191170/winchester-va-united-states) - Apple Read more
Sales Floor Assistant - *Apple* Blossom Mal...
Sales Floor Assistant - Apple Blossom Mall Location:Winchester, VA, United States (https://jobs.jcp.com/jobs/location/191170/winchester-va-united-states) - Apple Read more
*Apple* Tech Support Analyst - Sesame Worksh...
Sesame Workshop is looking for an Apple Tech Support Analyst. We're looking for someone with an enthusiastic personality, articulate communication skills and a Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.