TweetFollow Us on Twitter

Using Regions
Volume Number:1
Issue Number:3
Column Tag:QuickDraw from MacPascal

Using the Region

By Chris Derossi

In the last column, we were introduced to the simple access to QuickDraw from MacPascal. We found that the procedures for graphic drawing were easily called, using predefined routines and data structures. The concepts of cartesian coordinates, points, and lines were very important when dealing with QuickDraw. In this month’s column, we will begin to explore the next step of QuickDraw complexity: the region.

Whereas a line (actually, a line segment) is a subset of points in one dimension, a region is a subset of points in two dimensions. When you draw a line with QuickDraw, the points from one endpoint of the line to the other are said to be part of the line. Points lying past either endpoint are not part of the line. Points off to the side of the line can never be part of the line, and are ignored; they are not part of the line.

A similar concept is true for regions. When you have a region in a plane, the QuickDraw coordinate plane for example, some of the points are part of the region and the rest are not part of the region. There are no points that are both, and no points that are neither. Points that are part of the region are said to be inside the region, while the rest are outisde the region.

The points inside a region do not have to be contiguous. That is, points or groups of points that comprise the region do not have to be adjacent. For the time being, we will call a group of points in the QuickDraw plane an area. A region may consist of zero, one, or several distinct areas.

For the most part, regions can be manipulated in the same manner as any other QuickDraw object. Just like circle and rectangles, regions can be framed, painted, erased, inset, offset, and filled. However, the marvelous aspect of regions is their shape. Regions can be any shape or combination of shapes, large, small, or empty. A region is empty when there are no points inside of it.

To describe or represent a region, its outline is defined. For example, to describe a circular region, one would only need to indicate the outline of the circle, not all of its interior points. Similarly, a rectangular region is represented as a framed rectangle. More complex shapes for regions can be defined using various combinations of simple shapes. A ‘T’ shaped regions could be described as the outline of two rectangles that just touch. It is important to realize, though, that the actual boundaries of a region are infinitely thin.

Because a region divides the plane into only two sets of points, those inside the region, and those outside the region, there can be no points that lie on the boundary of the region. For that reason, there is a distinction between coordinate points and graphic points. Coordinate points lie between graphic points and vice versa. Lines from one coordinate point to another have no width, so the graphic points it separates are actually adjacent.

Illustration #1 shows some graphic points on a coordinate plane. Notice that a graphic point is to the ‘right’ and ‘below’ its corresponding mathematical coordinate. As mentioned before, any points with adjacent coordinates will be drawn on the screen as a single, solid area. The coordinate line separating them is only mathematical, and does not actually exist. A region’s boundary is defined in terms of coordinate points, and no graphics points in the plane lie on the boundary.

When regions are defined in MacPascal, the procedure OpenRgn is first called to allocate the memory needed for the region. Then, the boundary of the region is defined by calling normal QuickDraw drawing routines, such as FrameRect, FrameOval, and FrameRoundRect. Only the outlines of the shapes are important; i.e. PaintRect acts just like FrameRect.

The outlines are summed together to form the boundary of the region. No drawing is performed because the boundaries are only mathematical, and do not involve real graphic points. When the entire outline is defined, a call to CloseRgn is made to stop the region definition. CloseRgn creates a handle to the new region, and passes it back in a variable of type RgnHandle. (Note: the variable must have first been initialized with a call to NewRgn.) All subsequent references to the region are done through its handle.

After OpenRgn has been called to start a new region, the region is empty. Then, areas are added to the region as the boundaries for those areas are ‘drawn’. But, if a boundary encloses an area that is already part of the region, that area is changed to be outside of the region. If it is enclosed again, it is re-added to the region, and so on. In other words, areas are exclusive-ored with the exisitng region. Areas enclosed an odd number of times are part of the region, while areas enclosed an even number of times are not part of the region.

Illustration #2 shows a situation in which overlapping areas caused ‘holes’ in the region. Illustration #2a shows the region shaded, with the rest not shaded. Illustration #2b breaks the areas down. Area #0 was never enclosed, so it is not part of the region. Areas #1 were enclosed once each, and are part of the region. The areas numbered #2 were each enclosed twice, once from each of two circles; they are not part of the region. Finally, area #3 was enclosed three times and is part of the region.

It is frequently easier to define a region in terms of one area minus another instead of a sum of areas. For example, illustration #3 can be described as a series of four rectangles, or as one large rectangle minus the smaller, inside rectangle. The second way is easier and more intuitive. QuickDraw’s method of exclusive-oring areas allows area to be added to and subtracted from regions.

Let us now put aside regions to talk about something else: clipping. Clipping is a graphics term that refers to drawing within certain boundaries. The easiest way to learn about clipping is to think of an example: anything drawn inside one window on the Macintosh should stay within that window and not get drawn outside of it. If the window is too small, the part of the drawing that is beyond the current edges of the window should not be drawn on the screen. The part of the drawing that is not actually drawn is said to have been clipped.

Clipping can be thought of as looking through the viewfinder of a camera. You can only see a portion of the world even though there is stuff beyond the edges of your sight. In order to emulate reality, and to create the effect of windows and such, everything drawn on the Mac is clipped, making each window and even the Mac screen a viewfinder on the whole picture.

There are two ways to do clipping. First, whoever is doing the drawing makes sure that nothing gets drawn beyond the appropriate boundaries. Second, anything desired is drawn without regards to boundaries, and clipping is controlled by the low level draw routines. This means that every point that is drawn is checked for boundary limitations. Because this is done for every single point, it happens very often. If the clipping operation were slow, the graphic output on the Mac would take forever. The name QuickDraw is partially derived from its ability to handle operations like this very rapidly.

In general, this means that each separate window or drawing area on the Mac may consider itself the entire coordinate plane. QuickDraw makes sure that only the appropriate things are actually displayed, and that they fit within the proper bounds.

Many times, though, the clipping area is not rectangular like a window. (Clipping Area or Clipping Region refers to the areas where drawing occurs. The stuff outside of the clipping area is what is actually clipped.) Many times a window may be ‘underneath’ several other windows, and have only an unusually shaped portion visible. Nevertheless, the drawing in that window must be clipped to that unusual area. That’s where regions come in.

Each window (or QuickDraw port) has an associated Clipping Region. It is this region that defines what will be displayed, and what will be clipped. For most normal windows, this region is simply rectangular, but when the window is partially obscured, the region may become more complicated. In addition, the clipping region of a window may be changed to suit the needs of the situation.

For example, you might want to fill or erase a region of a window without affecting anything else in the window. This could be done in pieces, or by setting the clipping region to the desired region and filling or erasing the whole window. Note that the clipping region only affects subsequent drawing, and has no effect on previously drawn graphics.

This month’s MacPascal program is a demonstration of the use of regions, and the effects of using clipping regions. It shows clearly how to define regions, how to set the clipping region, and what happens when drawing is clipped.

Before we take a brief step-by-step look at the program, there are some general comments that should be made. First, in order to remain as compatible as possible with other Pascal/QuickDraw interfaces, calls that normally require a Rect parameter are not supplied four integers. Instead, SetRect is used to assign values to the rectangle’s coordinates.

Second, when you type this program into your Mac and try to execute it, you might run out of memory; the data structures for regions take up lots of room. If this happens, try deleting the comments, closing all the windows, and ejecting unneeded diskettes to free up some memory. Users of 512K Macs should not have any problems.

The program begins by doing a ‘uses QuickDraw2’. The library QuickDraw1 contains all the routines and data structures that we have used so far and is ‘used’ automatically. The routines and data structures for regions, however, reside in QuickDraw2 and must be included explicitly.

The RgnHandle that we use throughout the program is called My_Rgn. Also, a Rect called Big_Rect is declared. The constants WordsPerLine, NumLines, and LineHite are declared and set. These values will be used later to determine that amount and density of text to draw.

The main program calls only two procedures: SetUp and MakeRgns. SetUp puts away all of the MacPascal windows with HideAll, puts away the cursor with HideCursor, and displays the drawing window after setting its coordinates with SetDrawingRect. In addition, SetUp draws three lines, dividing the window into six areas. SetUp also initializes My_Rgn with NewRgn and assigns the coordinates of the drawing window to Big_Rect.

MakeRgns is simply a series of calls to the six separate region demonstration procedures. The program was structured this way so that each region could be its own procedure and so modifications were easier. When all six region procedures have finished, the memory space used by My_Rgn is deallocated with DisposeRgn, and the clipping region of the drawing window set back to full size.

The six region procedures each call upon three utility procedures called DrawWords, Use_Region, and ClearRgn. DrawWords uses DrawString to draw the word ‘Regions’ several times according to the constants declared at the beginning. The final display of the words is clipped according to each different clipping region. ClearRgn sets the window’s clipping region back to the full window so that drawing of titles, etc won’t be clipped. Use_Region draws the outline of the current My_Rgn with FrameRgn and then shrinks it so that the outline lies outside of the region. This is to prevent later drawing from drawing over the outline. Then, the cliiping region of the window is set to equal My_Rgn with SetClip.

Five of the six region procedures follow the same general outline. First, ClearRgn is called to reset the clipping region. Next, a title is drawn for the region. Finally, the region is defined and used to clip the text created with DrawWords. Several aspects of regions and clipping are demonstrated.

The final region procedure is slightly different. As before, it resets the clipping region and draws a title. Then, it shades in the sixth rectangle with gray to provide for contrast later. Next, a region is defined and used in the same manner as the other five procedures. This region is then cleared to white, yielding a binocular-type window effect. After this is done, a small circle is animated. The circle is bounced in an imaginary rectangle that is somewhat larger than the region. The animation routine just continues the circle on its present course until it strikes a side of the imaginary rectangle. Then, a new course is chosen at random for it, and it continues.

Because the circle is sometimes not within the region, it is automatically clipped. This gives the effect of multiple planes that are stacked, with a window in the top one looking through to the bouncing ball. The clipping is performed automatically, and it is transparent to the animation routine. The animation ceases when the mouse button is pressed.

The power of QuickDraw can be seen when one considers the versatility of regions. The entire concept of multiple, independent windows, used extensively in the Macintosh, is based on the foundations of arbitrary clipping regions. Further, the QuickDraw clipping regions allow programs and applications to output to the screen regardless of the screen situation. This is a key factor in multi-tasking, and simultaneous application execution. (i.e. desk accessories.)

There are additional aspects of regions and QuickDraw that have yet to be covered, like calculations, ports, etc. The next column will focus on these final features, concluding our overall introduction to QuickDraw. We will find that this basic background in QuickDraw will continue to aid us throughout the excursions into other areas of MacPascal such as windows, dialog boxes, and menus. Ciao.

program Regions;

{ Regions is a MacPascal demostration program}
{ that provides six examples of the workings of}
{ the regions of QuickDraw.    }
{  -- by Chris Derossi}

 uses
  QuickDraw2;  {QuickDraw2 contains the stuff for regions.}

 const
{ These constants determine the amount and density of the}
{ words used to show region clipping}

  WordsPerLine = 6;
  NumLines = 10;
  LineHite = 15;

 var
  My_Rgn : RgnHandle;  { This is our working region, used everywhere}
  Big_Rect : Rect;  { This is a rectangle that is the whole drawing window}

 procedure SetUp;

{ SetUp clears the screen to a full sized drawing window and uses}
{ DrawLine to mark it off into six sections. It also inits our region}
{ and sets Big_Rect to the full window.}

 begin
  HideCursor;
  HideAll;
  SetRect(Big_Rect, 0, 20, 527, 357); {Full screen size}
  SetDrawingRect(Big_Rect);
  ShowDrawing;                      {Show only the drawing window}
  DrawLine(0, 149, 527, 149);
  DrawLine(176, 0, 176, 337);
  DrawLine(352, 0, 352, 337);
  My_Rgn := NewRgn;        {Init our working region}
 end;

 procedure DrawWords (X, Y : integer);

{ DrawWords draw several lines of words starting at (X,Y) according}
{ to globally declared constants}

  var
   s : string;
   a, b : integer;

 begin
  s := ‘Regions ‘;
  for a := 0 to NumLines do
   begin
    MoveTo(X, Y + a * LineHite);  {Start a new line in column Y}
    for b := 1 to WordsPerLine do
    DrawString(s);
   end;
 end;

 procedure Use_Region;

{ This procedure draws an outline of our region, then shrinks it so that}
{the outline is not in the region, and sets the drawing window’s clipping}
{region to equal our region}

 begin
  FrameRgn(My_Rgn);        { Draw the outline of our region}
  InsetRgn(My_Rgn, 1, 1);  { Shrink it}
  SetClip(My_Rgn);            { Set the drawing window’s clipping region}
 end;

 procedure ClearRgn;

{ In order to use the entire drawing window, this procedure sets the}
{clipping region to the whole window, using Big_Rect}

 begin
  RectRgn(My_Rgn, Big_Rect); {Make our region a rectangle, screen size.}
  SetClip(My_Rgn);
 end;

 procedure DoRegion1;

{ This creates the first region, which is just a circle}

  var
   r : Rect;

 begin
  ClearRgn;
  MoveTo(25, 140);
  DrawString(‘Simple Region’);

  begin  {Create a region}
   OpenRgn;
   SetRect(r, 20, 20, 120, 120);
   FrameOval(r);
   CloseRgn(My_Rgn);
  end;

  Use_Region;
  DrawWords(0, 0);
 end;

 procedure DoRegion2;

{ This is region number 2. This is a concatination of 3 shapes.}

  var
   r : Rect;

 begin
  ClearRgn;
  MoveTo(225, 140);
  DrawString(‘Any Shape’);

  OpenRgn;   {Start a new region}
  SetRect(r, 220, 65, 300, 85);
  FrameRect(r);
  SetRect(r, 180, 30, 220, 120);
  FrameOval(r);
  SetRect(r, 300, 30, 340, 120);
  FrameOval(r);
  CloseRgn(My_Rgn);

  Use_Region;
  DrawWords(176, 0);
 end;

 procedure DoRegion3;

{ Region number 3. Two overlapping regions form a ‘hole’.}

  var
   r : Rect;

 begin
  ClearRgn;
  MoveTo(410, 140);
  DrawString(‘Holes’);

  OpenRgn;
  SetRect(r, 380, 20, 480, 120);
  FrameOval(r);
  SetRect(r, 410, 50, 450, 90);     {Completely inside the first shape}
  FrameRoundRect(r, 18, 18);
  CloseRgn(My_Rgn);

  Use_Region;
  DrawWords(352, 0);
 end;

 procedure DoRegion4;

{ Region 4. This creates a region which shows the effect of }
{partially overlapping region areas.}

  var
   r : Rect;
 begin
  ClearRgn;
  MoveTo(40, 310);
  DrawString(‘Overlapping’);

  OpenRgn;
  SetRect(r, 30, 180, 130, 280);
  FrameOval(r);   { Draw a simple circle }
  SetRect(r, 5, 215, 155, 245);
  FrameRect(r);    { Draw a rectangle over the circle }
  CloseRgn(My_Rgn);

  Use_Region;
  DrawWords(0, 149);
 end;

 procedure DoRegion5;

{ Region 5. Regions do not have to be contiguous. This procedure creates}
{a region with three separate areas.}

  var
   r : Rect;
 begin
  ClearRgn;
  MoveTo(220, 310);
  DrawString(‘Disjoint Areas’);

  OpenRgn;
  SetRect(r, 190, 160, 270, 230);
  FrameOval(r);
  SetRect(r, 280, 160, 340, 240);
  FrameRect(r);
  SetRect(r, 190, 255, 340, 285);
  FrameRoundRect(r, 18, 18);

  CloseRgn(My_Rgn);
  Use_Region;
  DrawWords(176, 150);
 end;

 procedure DoRegion6;

{ Region 6. This procedure illustrates the effect of continuous clipping}
{associated with any drawing, even animation.}

  var
   r : Rect;

  procedure Animate;

{ Animate, called only by DoRegion6, bounces a ball in the general area}
{of region 6, showing that the clipping occurs constantly, with now need}
{for special instructions. The animation stops when the mouse button 
is}
{pressed.}

   var
    X, Y, dX, dY : integer;

  begin
   X := 353; { Arbitrary starting position. }
   Y := 220;
   dX := 3;    { Arbitrary beginning velocity. }
   dY := 0;
   repeat
    PenPat(white);    { Use white for drawing to }
    PaintCircle(X, Y, 5);  { erase ball at current position }
    X := X + dX;  { upgrade position }
    Y := Y + dY;
    if (X < 353) or (X > 510) or (Y < 175) or (y > 265) then
    begin  { The ball has hit a “wall” and should bounce }
    X := X - dX;  { Move the ball back to its last legal position }
    Y := Y - dY;
    repeat
    dX := ((random mod 3) - 1) * 7;                   { Choose new random 
velocities,}
    dY := ((random mod 3) - 1) * 7; {with each being -7,0, or 7 }
    until (dX <> 0) or (dY <> 0); { zero velocity is illegal }
    end
    else  { new ball position is okay. }
    begin
    PenPat(black);
    PaintCircle(X, Y, 5);   { Draw the ball in the new position }
    end;
   until Button;    { Stop when the button is pressed }
  end;

 begin  { Region6 }
  ClearRgn;
  SetRect(r, 353, 150, 530, 290);
  FillRect(r, gray);    { Use a gray background for contrast }
  MoveTo(375, 310);
  DrawString(‘Continuous Clipping’);

  OpenRgn;
  SetRect(r, 357, 185, 432, 255);
  FrameOval(r);
  SetRect(r, 432, 185, 507, 255);
  FrameOval(r);
  CloseRgn(My_Rgn);

  Use_Region;
  SetRect(r, 353, 150, 530, 290);
  FillRect(r, white);   { Erase the inside of the region, using auto-clipping}
  Animate;  { Do the bouncing ball }
 end;

 procedure MakeRgns;

{ This is a brute force way to call all six regions, but it allows us 
to}
{break the regions down into separate procedures.}

 begin
  DoRegion1;
  DoRegion2;
  DoRegion3;
  DoRegion4;
  DoRegion5;
  DoRegion6;
  ClearRgn;
  DisposeRgn(My_Rgn);  { Free the memory used for our region }
  ShowCursor;   { We need the cursor! }
 end;

begin   { Regions }
 SetUp;
 MakeRgns;
end.



 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Trend Micro 11.0.2062 - An essential sec...
Trend Micro Antivirus provides essential security for macOS with real-time malware detection and mitigation in an affordable solution with a simple, intuitive interface. However, be aware that more... Read more
Backblaze 7.0.2.490 - Online backup serv...
Backblaze is an online backup service designed from the ground-up for the Mac. With unlimited storage available for $6 per month, as well as a free 15-day trial, peace of mind is within reach with... Read more
Pro Video Formats 2.2.1 - Updates for pr...
Pro Video Formats includes support for the following professional video codecs: Apple Intermediate Codec Apple ProRes AVC-Intra 50 / 100 / 200 / 4:4:4 / LT AVC-LongG XAVC XF-AVC DVCPRO HD HDV XDCAM... Read more
Boom 3D 1.3.11 - $19.99
Boom 3D is a revolutionary app with 3D Surround Sound and phenomenally rich and intense audio that is realistic and works on any headphones. Features 3D surround sound Built-in audio player... Read more
Final Cut Pro 10.5.2 - Professional vide...
Redesigned from the ground up, Final Cut Pro combines revolutionary video editing with a powerful media organization and incredible performance to let you create at the speed of thought.... Read more
Chromium 89.0.4389.72 - Fast and stable...
Chromium is an open-source browser project that aims to build a safer, faster, and more stable way for all Internet users to experience the web. Version 89.0.4389.72: Complete list of changes can... Read more
iMovie 10.2.3 - Edit personal videos and...
With a streamlined design and intuitive editing features, iMovie lets you create Hollywood-style trailers and beautiful movies like never before. Browse your video library, share favorite moments,... Read more
OmniPlan 4.2.5 - Professional-grade proj...
With OmniPlan, you can create logical, manageable project plans with Gantt charts, schedules, summaries, milestones, and critical paths. Break down the tasks needed to make your project a success,... Read more
Compressor 4.5.2 - Adds power and flexib...
Compressor adds power and flexibility to Final Cut Pro X export. Customize output settings, work faster with distributed encoding, and tap into a comprehensive set of delivery features. Features:... Read more
Motion 5.5.1 - Create and customize Fina...
Motion is designed for video editors, Motion 5 lets you customize Final Cut Pro titles, transitions, and effects. Or create your own dazzling animations in 2D or 3D space, with real-time feedback as... Read more

Latest Forum Discussions

See All

Frogger in Toy Town's latest update...
Konami Digital Entertainment has announced today that their Apple Arcade title Frogger in Toy Town has been updated to introduce a new ranked Endurance Mode. This new game variant's arrival is also accompanied by a few other changes. [Read more] | Read more »
Mitoza is surreal adventure toy you can...
The folks behind the Rusty Lake games have just put a new title onto the App Store. Second Maze, Rusty Lake's collaborative publishing brand, has just brought this 10 year old adventure game from Gal Mamalya to mobile. The best part about all of... | Read more »
Pocket Gamer Awards 2021: You have five...
Three weeks ago our sister site, Pocket Gamer, entered the voting stage for the upcoming Pocket Gamer Awards 2021 and is now in the final stretch. You only have a few hours left to vote for the games you’ve enjoyed on mobile in the past year, as... | Read more »
Patty Stack is a casual arcade game, ava...
Patty Stack is a casual arcade title that's available now for iOS and Android. It's the debut game from developer Feeka Games tasks players with making an increasingly giant burger tower. Think of it as Tower Bloxx but more edible. [Read more] | Read more »
Distract Yourself With These Great Mobil...
There’s a lot going on right now, and I don’t really feel like trying to write some kind of pithy intro for it. All I’ll say is lots of people have been coming together and helping each other in small ways, and I’m choosing to focus on that as I... | Read more »
Genshin Impact Guide - Gacha Strategy: W...
This is part 2 of our Genshin Impact gacha strategy guides. See part 1 here. You can check out more guides for Genshin Impact here. | Read more »
Slashy Camp is a new endless runner insp...
Blue Wizard Digital has released Slashy Camp onto iOS and Android after it spent a short amount of time in early access. [Read more] | Read more »
Kinder World is a relaxing game about lo...
Lumi Interactive is releasing a game called Kinder World later this year on iOS and Android, which is all about looking after houseplants. [Read more] | Read more »
Steam Link Spotlight - Fights in Tight S...
Steam Link Spotlight is a feature where we look at PC games that play exceptionally well using the Steam Link app. Our last entry was on Hades. Read about how it plays using Steam Link over here. | Read more »
Lyxo, the light-based puzzler for mobile...
Vienna-based independent game studio Emoak has just released its unique light-based puzzler for iOS and Android. Founded in 2014 by Tobias Sturn, the company is also the creative force behind the infinite climbing game Paper Climb, as well as the... | Read more »

Price Scanner via MacPrices.net

Weekend Sale: $100 off Apple iPad Magic Keybo...
Amazon has Apple iPad Magic Keyboards on sale for $100 off MSRP for a limited time. Amazon’s prices are the lowest available for iPad Magic Keyboard from any Apple reseller this weekend: – Magic... Read more
Gazelle now offering a full line of refurbish...
Gazelle is now offering a full range of discounted, refurbished, unlocked Apple iPhone 12 models starting at $649. iPhones are offered in Fair, Good, and Excellent conditions, and multiple colors are... Read more
These are the latest discounted iPhones Apple...
Apple has a range of Certified Refurbished iPhones available right now starting at only $339. Apple includes a standard one-year warranty, new outer shell, and shipping is free. According to Apple, “... Read more
Save up to $64 on new M1 MacBook Airs at Expe...
Apple reseller Expercom has 2020 13″ M1 MacBook Airs on sale for $51-$64 off Apple’s MSRP with prices starting at $947.96. In addition to their MacBook Air sale prices, take $50 off AppleCare+ when... Read more
Discounts available on 16″ MacBook Pros with...
Upgrade a 16″ 6-Core or 8-Core MacBook Pro from 16GB of standard RAM to 32GB at Adorama, and save $100-$210 over Apple’s price for this custom option: – 16″ 6-Core MacBook Pro/32GB RAM: $2699, save $... Read more
10.9″ iPad Airs on sale for $50-$70 off Apple...
Amazon has new 2020 10.9″ Apple WiFi iPad Airs in stock and on sale today for up to $70 off MSRP with prices starting at $549. Note that Amazon’s sale price might be restricted to certain colors (see... Read more
Apple restocks 2020 27″ 5K iMacs for up to $3...
After an initial offering in January, Apple has restocked a full line of Certified Refurbished 2020 27″ 5K iMacs starting at $1529 and up to $350 off original MSRP. Apple’s one-year warranty is... Read more
Sale! 16″ 8-Core MacBook Pro for $2449, $350...
Apple reseller Adorama has the 16″ 2.3GHz 8-Core Space Gray MacBook Pro in stock and on sale today for $2449 including free shipping. Their price is $350 off Apple’s MSRP for this model, and it’s the... Read more
Roundup of 13″ Multi-Core Intel MacBook Pro s...
Apple resellers are offering significant sales & deals this week on 2020 13″ MacBook Pros with 10th generation Intel CPUs. Take up to $250 off Apple’s MSRP, get free fast shipping, and/or pay no... Read more
64GB iPhone 8 Plus available for $379 at Appl...
Apple has the 64GB iPhone 8 Plus in Space Gray & Gold colors available for $379 today, Certified Refurbished. Each phone is unlocked and comes with Apple’s standard 1-year warranty and free... Read more

Jobs Board

Geek Squad Advanced Repair *Apple* Professi...
**795178BR** **Job Title:** Geek Squad Advanced Repair Apple Professional **Job Category:** Store Associates **Store Number or Department:** 001406-Allen Park-Store Read more
Geek Squad *Apple* Consultation Professiona...
**796549BR** **Job Title:** Geek Squad Apple Consultation Professional **Job Category:** Store Associates **Store Number or Department:** 001800-Hot Springs-Store Read more
*Apple* Mobility Specialist - Best Buy (Unit...
**796014BR** **Job Title:** Apple Mobility Specialist **Job Category:** Store Associates **Store Number or Department:** 001776-Woodmore Towne Centre-Store **Job Read more
Systems Architect, *Apple* Production Engin...
…package beginning on your first day? If so, we hope you'll keep reading! The Apple Sales Engineering and account team is looking for a stellar presales engineer with Read more
Systems Engineer, Webscale, *Apple* Retail,...
…beginning on your first day? If so, we hope you'll keep reading! The Apple Sales Engineering team is looking for a pre-sales engineer with Enterprise engineering Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.