TweetFollow Us on Twitter

Start-up ad
Volume Number:1
Issue Number:3
Column Tag:ASSEMBLY

Start-up ad

By David E. Smith

Corvus called the other day and said they were sending 20 megabyte hard disks to various dealers and asked if I would like to put something about MacTutor on them. The problem was, they needed it the next day! So by 3 in the morning I had my double clickable start-up ad ready to express mail for the Corvus sampler. Thinking others might appreciate this little gem, I’ve used it as the basis for my column this month. It combines our application shell program from the December issue with our icon converter program from last month’s issue, with some new material on menus and events.

WHAT THIS PROGRAM DOES

What we have here is a simple start-up program that can be set by the finder option as the program that gets executed when the disk first boots up. The program opens a window and draws an advertisment for MacTutor, as shown above in figure 1. When the close box is clicked, the finder is called. Such a program can be useful for the front end of your product development disk as a catchy way of introducing your product when the disk is booted up. You can modify the text to advertise your product, or make a clickable birthday card for your favorite Mac hacker. I gave a Mac Disk to a friend for Christmas and included this program with modified text to wish him a Merry Christmas everytime he started up his computer.

TOOLBOX FEATURES

Our program may seem simple in operation, but it’s already complex in toolbox features as listed below:

1. Drag window capability with window updating after drag.

2. Clickable close box exit.

3. Standard menu bar with apple, file and edit menus enabled.

4. Quit command in the file menu as an alternate return to the finder.

5. Text and box drawing using quickdraw.

Although the apple and edit pop-up menus are implemented, the support code for them is not here, so full support of the desk accesories will have to wait until next month. Everything required for a standard Macintosh program is here except text editing support, which is required for cut and paste. Only the quit option in the file menu actually does something. What we want to concentrate on here is the menu bar set-up.Then it is a minor problem to complete the stub routines to handle the individual apple and edit menu functions.

MENUS AS RESOURCES

As we noted last month, resources suffer from almost no documentation and this includes menus as resources. Another problem is that there are several ways to create and maintain menus. They can be created from the program itself, or read in from a resource file. The resource file option can be either created using the RMaker, resource editor if it ever shows up, or by using the assembler. When creating menus from program code, the combination _NewMenu, _AppendMenu, and _InsertMenu traps are used. The _AppendMenu trap reads in the menu information from the local data area at the end of your program code, and the format of the menu items is well documented in the IM docs in the Menu Manager section. In fact, you can easily build your own RMaker using the append menu trap.

APPEND MENU FORMAT

; This commmented code shows how you
;  would do menus using in line code
;  instead of resources. Place this code 
;  in your menu set-up routine.

PEA APPLEMENU    ;menu set-up in code
_NewMenu;make new menu
MOVE.L (SP),D7   ;save menu handle
 ;keep on stack
PEA APPLEMENUITEMS ;apple menu items 
_AppendMenu ;add to apple menu
MOVE.L D7,-(SP)  ;menu handle
CLR.W -(SP) ;add to end
_InsertMenu ;insert menu items

;  This commented code shows how you would 
; set up resources in code for use with 
; _AppendMenu instead of using a resource
; file with _GetRMenu. Place this section
; in your data block.
;
APPLEMENU:
 DC.B 1
 DC.B 20;apple symbol title
 DC.B 0
 
APPLEMENUITEMS:  
 DC.B 21
 DC.B   ‘ABOUT THIS PROGRAM...’
 DC.B 0

; The remaining menu items would be
; desk accesories, which are added  to
; this menu with another trap call.

Menu items from Resources

The reason for going through the above formats for using the append trap is because we DID NOT use it in our program! Instead, we used resources to define the menu and menu items and the _GetRMenu trap to read in the menu resource and set-up the menu bar. The resources can be created either by the RMaker utility, which is well documented, at least for making menus, or by the assembler, which is not documented at all and is not the same format as the RMaker input syntax. After much trial and error I finally got the assembled resource file to work. It seems the assembler creates the binary format of each resource exactly as it is described in the IM docs. The trouble is, not all of the resources have their internal format documented. It is my guess that the RMaker program takes a high level description of the menu resources and translates that description into the same binary format. So in a sense, using the assembler meant we were our own RMaker!

Event Processing

The next major addition to this program is the event processing. Our event loop has been expanded from our simple application shell of the first issue. This time we use a jump table to process all the possible system events that could occour as a result of calling _SystemTask trap.This is done by using the event number returned from _GetNextEvent as an index into a table of offsets for handling each possible event. The big picture of how event processing works is shown in figure 2. In our program, the only event we do anything with is a mouse button down event. All the other entries in our event table return to the GetEvent loop.

Where’s the mouse?

When the mouse button is pressed, and we branch by way of the event table to the ButtonDown routine, we first have to find out where the mouse is. This requires a SECOND table of offsets to branch to different routines depending on where the mouse was when the button was pressed. Our second table is called the WindowTable and it is indexed by the region number returned from _FindWindow, which has located the mouse for us. In this table, we have placed three routines; one for if the mouse is in the menu bar, another if the mouse is in the go-away region of the window, and finally, a third if the mouse is in the drag region of the window.

The drag region routine is easy. We just call _DragWindow trap to move the window. But we also have to re-draw our ad or some of it will be erased when the window is moved. Fortunately all of our ad is drawn in a single subroutine called QDSTUFF, which can be called at any time, including after a drag window operation. And so as if by magic, the ad is restored.

The go-away region is also simple to handle. We just exit our program and return to the finder. The hard task is the menu bar region. Now we have to find out which menu we are in and go through another set of branches to handle each menu item.

Menu Bar Processing

We now come to our third and fourth levels of event processing. The third level is our routine Menubar, which we branch to when we find out the mouse is in the menu bar. Now we have to find out which menu the mouse is in. This is done by calling _MenuSelect trap. The returned menu Id and menu item id identify the menu and the associated menu item where the mouse was clicked. Since we have three menus, Apple, File and Edit, we have three more branches to a routine for each menu. At this point, only the File menu item is processed. We check if the quit option was selected and exit the program. If we were in the apple menu, we would need to make a fourth level branch to a routine for handling either the About option or the desk accesories. This code we have not added yet. Instead Inapplemenu and Ineditmenu just return to the first level of our event processing.

What about the Ad?

We’ve spent so much time just checking out the mouse, we nearly forgot about our ad! The QDSTUFF subroutine draws our ad in our window in the quickest, most brute force way. We simply call _DrawString from quickdraw to draw strings in our window to describe our product. A few boxes liven it up. The nice thing about _DrawString is that it doesn’t require character counting! Just specify the location and away it goes. A few different fonts also help.

Make a good Icon!

Any advertisement needs a good icon and ours is shown on the column masthead. We learned how to create this icon on the desktop in our last issue. To review, we create the icon using the icon editor supplied by Apple. Then we run the icon binary file through our Icon Converter program to create assembly source code. Our resource file has an Include statement that will then merge in this assembly source file for the icon into our resource file. When we assemble the resource file and link it with the program code, we get a nice icon on the desktop. Refer to last month’s issue for the Icon Converter program source code.

Next time we will complete our event processing with the About dialog box, desk accesory support and the remaining support code for our edit menu items. Have some good ideas on assembly programming? Send them to MacTutor and share them with others!

; EXAMPLE ASSEMBLY PROGRAM 
; MENUBAR  (MacTutor 1-3)
; VERSION 26 DEC 84
; (C) 1984 MacTec by David E. Smith

;    Macro subset for Toolbox stuff

MACRO _InitGraf =  DC.W $A86E|
MACRO _InitWind =DC.W $A912| 
MACRO _NewWindow = DC.W $A913|
MACRO _setport = DC.W $A873|
MACRO _InitFont =DC.W $A8FE|
MACRO _InitMenu =DC.W $A930|
MACRO _InitDialog =DC.W $A97B|
MACRO _TEInit   =DC.W $A9CC|
MACRO _Initpack =       DC.W $A9E5|
MACRO _FlushEvents = DC.W $A032|
MACRO _InitCursor =DC.W $A850|
MACRO _GetNextEvent =DC.W $A970|
MACRO _FrameRect = DC.W $A8A1|
MACRO _TextFont =  DC.W $A887|
MACRO _TextFace =  DC.W $A888|
MACRO _TextSize =  DC.W $A88A|
MACRO _MoveTo =  DC.W $A893|
MACRO _DrawString =  DC.W $A884|
MACRO _PenSize = DC.W $A89B|
MACRO _EraseRect = DC.W $A8A3|
MACRO _GetRMenu =DC.W $A9BF|
MACRO _InsertMenu =DC.W $A935|
MACRO _DrawMenuBar = DC.W $A937|
MACRO _Debugger =  DC.W $A9FF|
MACRO _NewMenu = DC.W $A931|
MACRO _AppendMenu =DC.W $A933|
MACRO _AddResMenu =DC.W $A94D|
MACRO _FindWindow =DC.W $A92C|
MACRO _DragWindow =DC.W $A925|
MACRO _SystemTask =DC.W $A9B4|
MACRO _MenuSelect =DC.W $A93D|
MACRO _HiLiteMenu =DC.W $A938|

;      DECLARE LABELS EXTERNAL

XDEF  START          ; required for linker 
 
;     LOCAL EQUATES
 
MouseDown equ  1
MaxEvents equ  12
AllEvents equ  $0000FFFF
 
;     MAIN PROGRAM SEGMENT

 DC.W ‘MINE’;find start of program
 
; -- SAVE THE WORLD ------------
 
START:   MOVEM.L D0-D7/A0-A6, -(SP)
  LEA SAVEREGS,A0
  MOVE.LA6,(A0)   ; local var
  MOVE.LA7,4(A0) ; stack ptr
 
; --INITIALIZE ALL MANAGERS--------

; SET UP QUICKDRAW GLOBALS
 
PEA -4(A5);push qd global ptr
_InitGraf      ;init quickdraw global 
   
;---- SET UP REMAINING MANAGERS  --

_InitFont        ; init font manager
_InitWind   ; init window manager
_InitMenu   ; init menu manager
 
CLR.L -(SP) ; kill the restart 
_InitDialog ; init dialog manager
 
_TEInit ; init text edit (ROM) 
 
MOVE.W  #2,-(SP)   ;  set-up
_Initpack         ; init package mgr

MOVE.L  #AllEvents,D0    ;all events
_FlushEvents      ;flushed
 
_InitCursor      ; make cursor the arrow


;  SET UP MENU BAR WITH POP-UP MENUS

CLR.L -(SP) ;returned menu handle
MOVE.W #1,-(SP)  ;push menu ID 1 Apple
_GetRMenu ;get menu from resource
LEA APPLEMENU,A0    ; copy apple menu handle 
MOVE.L (SP),(A0)   ; to local data block
MOVE.L (SP), -(SP) ;menu handle desk acc.
 ;menu handle on stack
CLR.W -(SP) ;push 0 for append
_InsertMenu ;add menu item 

MOVE.L #’DRVR’, -(SP);load all DRVR type 
_AddResMenu ;add desk accessories


CLR.L -(SP) ;return menu handle
MOVE.W #2,-(SP)  ;push menu ID 2 File
_GetRMenu ;get menu from resource
 ;leave handle on stack
CLR.W -(SP) ;append to menu
_InsertMenu ;the File stuff

CLR.L -(SP) ;return menu handle
MOVE.W #3,-(SP)  ;push menu ID 3 Edit
_GetRMenu ;get menu from resource
 ;leave handle on stack
CLR.W -(SP) ;append to menu
_InsertMenu ;the File stuff

_DrawMenuBar;our menu bar!

;-- SET UP NEW HEAP WINDOW ----
 
CLR.L -(SP)           ;return window ptr
CLR.L -(SP)          ;window record ptr.
PEA WBOUNDS              ;window rectangle 
PEA WINDTITLE            ; window title
MOVE.W #$100,-(SP)    ; true = visible 
MOVE.W #0,-(SP)           ; doc type window
MOVE.L #-1,-(SP)          ; window in front
MOVE.W #$100,-(SP)    ; true=closebox
MOVE.L #0, -(SP)         ; reference value 
_NewWindow                ; make new window
 
; --  ACTIVATE THIS NEW WINDOW ------

LEA WPOINTER,A0         ; copy window ptr 
MOVE.L (SP),(A0)        ; to stacksave
_setport                   ;current window

; --  SET UP WINDOW DISPLAY  --------

BSRQDSTUFF;draw text with QD

;  -------- EVENT LOOP ------------
 
GetEvent:

_SystemTask ;check out desk acc.
CLR-(SP);returned event 
MOVE  #AllEvents,-(SP)  ;mask all events
PEAEventRecord   ; event record block
_GetNextEvent    ;go check the mouse 
MOVE  (SP)+,D0   ;get event result 
CMP#0,D0;if 0 then no event 
BEQGetEvent ;loop until it happens

; JUMP TABLE OF EVENT PROCESSING
 
CLR.L D0
MOVE  What,D0  ;what to do! (event number)
CMP#MaxEvents,D0 ;event no. >11?
BGEGetEvent ;yes so ignore it
ADDD0,D0;multiply by 2
MOVE  EventTable(D0),D0
JMPEventTable(D0);execute event

EventTable:

 DC.W GetEvent-EventTable ;null event 
 DC.W ButtonDown-EventTable ;mouse down 
 DC.W GetEvent-EventTable ;mouse up
 DC.W GetEvent-EventTable ;key down event
 DC.W GetEvent-EventTable ;key up event
 DC.W GetEvent-EventTable ;auto key
 DC.W GetEvent-EventTable  ;update event
 DC.W GetEvent-EventTable ;Disk Event
 DC.W GetEvent-EventTable ;activate event
 DC.W GetEvent-EventTable ;Abort
 DC.W GetEvent-EventTable ;Network
 DC.W GetEvent-EventTable ;I/O Driver
 ;application events would  follow
 
; note that linker error may result if 
; the table entry is >128 

; -  EVENT PROCESSING ROUTINES --------

ButtonDown:

CLR-(SP);result of findwindow
MOVE.L  Point,  -(SP);push mouse coordinates
PEAWWindow;push holder for handle
_FindWindow ;where was mouse click?
CLR.L D0
MOVE (SP)+,D0    ;pop region number
ADDD0,D0;multiply by 2
MOVE  WindowTable(D0),D0
JMPWindowTable(D0) ;do mouse down event

WindowTable:;table of mouse events
 
 DC.W GetEvent-WindowTable;in desk (none of following)
 DC.W Menubar-WindowTable ;in menu bar 
 DC.W GetEvent-WindowTable;in system window
 DC.W GetEvent-WindowTable;in content region
 DC.W Drag-WindowTable    ;in drag region
 DC.W GetEvent-WindowTable;in grow region
 DC.W Exit-WindowTable    ;in go-away region 

Drag:   ;mouse in drag window

MOVE.L  WWindow,-(SP);push window pointer
MOVE.L  Point, -(SP) ;push mouse coordinates
PEADRAGWINDOW  ;window boundry to drag
_DragWindow ;move window
BSRQDSTUFF;update window text
JMPGetEvent ;return to event loop

Menubar:

CLR.L -(SP) ;returned menu choice
MOVE.L  Point,-(SP);mouse position
_MenuSelect ;Find menu selected
MOVE  (SP)+,D5 ;pop menu ID to D5
MOVE  (SP)+,D6 ;pop menu item ID to D6
CLR-(SP);select all menus
_HiLiteMenu ;unhilite them all

CMP#1, D5 ;apple menu?
BEQInapplemenu 
CMP#2, D5 ;file menu?
BEQInfilemenu
CMP#3,D5;edit menu?
BEQIneditmenu
BRAGetEvent ;no place else

Inapplemenu:

BRAGetEvent ;no place else

Infilemenu:

CMP#1,D6;quit?
BNEGetEvent ;no, try again
BRAExit ;yes, exit


Ineditmenu:

BRAGetEvent ;no place else

Exit:

JMPTofinder ;return to finder

; -- END OF MAIN --------------

; -- QDSTUFF SUBROUTINE ----------

QDSTUFF:

; This subroutine is a static
; window display of text for our
; ad. It would more properly be
; placed in a resource file as
; strings, but when in a hurry...

LEAtop,A0 ;set-up our globals
 ;window frame size.
MOVE.W #10,   (A0) ;TOP
MOVE.W #30,  2(A0) ;LEFT
MOVE.W #250, 4(A0) ;BOTTOM
MOVE.W #400, 6(A0) ;RIGHT 

PEA top                    ;window rectangle
_FrameRect;draw rectangle

MOVE.W #1, -(SP)          ;FONT
_TextFont
MOVE.W #12, -(SP);style
_TextFace
MOVE.W #24, -(SP);SIZE
_TextSize
MOVE.W #40, -(SP)       ; h
MOVE.W #50, -(SP);v
_MoveTo ;set pen location
PEA ‘MacTutor’
_DrawString

MOVE.W #0, -(SP) ;chicago
_TextFont
MOVE.W #0, -(SP) ;normal
_TextFace
MOVE.W #12, -(SP);12 point size
_TextSize
MOVE.W #40, -(SP);H
MOVE.W #80, -(SP);V
_MoveTo
PEA ‘The Macintosh Programming Journal’
_DrawString

MOVE.W #40, -(SP);H
MOVE.W #110, -(SP) ;V
_MoveTo
PEA ‘AT LAST! A no-nonsense, no fluff Journal’
_DrawString

MOVE.W #40, -(SP);H
MOVE.W #130, -(SP) ;V
_MoveTo
PEA ‘devoted to programming ON the Mac, FOR the Mac!’
_DrawString

MOVE.W #40, -(SP);H
MOVE.W #150, -(SP) ;V
_MoveTo
PEA ‘Subscribe to MacTutor, and learn how to create’
_DrawString

MOVE.W #40, -(SP);H
MOVE.W #170, -(SP) ;V
_MoveTo
PEA ‘this assembly language program, including the icon!’
_DrawString

MOVE.W #40, -(SP);H
MOVE.W #190, -(SP) ;V
_MoveTo
PEA ‘So do not delay. Send for the ONLY Technical ‘
_DrawString

MOVE.W #40, -(SP);H
MOVE.W #210, -(SP) ;V
_MoveTo
PEA ‘publication that teaches the Mac technology!’
_DrawString

MOVE.W #80, -(SP);H
MOVE.W #230, -(SP) ;V
_MoveTo
PEA ‘Send $24 for 12 issues to:’
_DrawString

LEAtop,A0
MOVE.W #215,   (A0);TOP
MOVE.W #250,  2(A0);LEFT
MOVE.W #290, 4(A0) ;BOTTOM
MOVE.W #450, 6(A0) ;RIGHT 
PEA top                    ;window rectangle
_EraseRect;clear rectange
PEA top
_FrameRect;draw rectangle

MOVE.W #2, -(SP) ;WIDTH
MOVE.W #2, -(SP) ;HEIGHT
_PenSize

LEAtop,A0
MOVE.W #218,   (A0);TOP
MOVE.W #253,  2(A0);LEFT
MOVE.W #287, 4(A0) ;BOTTOM
MOVE.W #447, 6(A0) ;RIGHT 
PEA top                   ;window rectangle
_FrameRect;draw rectangle

MOVE.W #280, -(SP) ;H
MOVE.W #230, -(SP) ;V
_MoveTo
PEA ‘MacTutor’
_DrawString


MOVE.W #280, -(SP) ;H
MOVE.W #245, -(SP) ;V
_MoveTo
PEA ‘P.O. Box 400’
_DrawString


MOVE.W #280, -(SP) ;H
MOVE.W #260, -(SP) ;V
_MoveTo
PEA ‘Placentia, CA  92670’
_DrawString


MOVE.W #280, -(SP) ;H
MOVE.W #275, -(SP) ;V
_MoveTo
PEA ‘Or call (714) 630-3730’
_DrawString

RTS

; -------- MOVBALL SUBROUTINE  ----------

MOVBALL:
;  place some animation in this routine 
;  while waiting for an event.
RTS

; -- RESTORE THE WORLD --------

Tofinder:  LEA SAVEREGS,A0  ; get back
    MOVE.L   (A0),A6 ; local var
    MOVE.L 4(A0),A7;restore stack 
    MOVEM.L (SP)+,D0-D7/A0-A6 
 
; ---- RETURN TO FINDER --------

        RTS      ; return to finder

; ----LOCAL DATA AREA ----------

APPLEMENU:DC.L 0
 
SAVEREGS: DCB.L   2,0     ;set  save area

WPOINTER: DC.L     0      ;store window pt

WBOUNDS:DC.W   40  ;rectangle TOP
 DC.W    2;LEFT
 DC.W    335;BOTTOM
 DC.W    508;RIGHT
 
WINDTITLE:  DC.B    42  ; title length
            DC.B    ‘MacTutor: The Macintosh Programming Journal’,0
      
DRAGWINDOW: DC.W 30;RECTANGLE
 DC.W 1
 DC.W 350
 DC.W 510

EventRecord:
 
 What:  DC.W    0;what event number
 Message: DC.L    0;ptr. to msg
 When:  DC.L    0;Time event posted
 Point:   DC.L    0;mouse coordinates
 Modify:  DC.W    0;state of keys 
 WWindow: DC.L 0   ;Find window’s result

 
; --   APPLICATION GLOBALS  ----------
 
top:    DS.W1
left:   DS.W1
bottom: DS.W1
right:  DS.W1

; ----   END OF PROGRAM -------------


; MENUBAR_RSRC.ASM
; resource file for the MENUBAR 
; created using the assembler
; signature is creator tag 
;
RESOURCE ‘DAVE’ 0 ‘IDENTIFICATION’

 DC.B 18, ‘AD FOR MACTECH 1-3’
 
.ALIGN 2
RESOURCE ‘BNDL’ 128 ‘BUNDLE’

 DC.L ‘DAVE’;NAME OF SIGNATURE
 DC.W 0,1 ;DATA (DOESN’T CHANGE)
 DC.L ‘ICN#’;ICON MAPPINGS
 DC.W 0 ;NUMBER OF MAPPINGS-1
 DC.W 0,128 ;MAP 0 TO ICON 128
    
 DC.L ‘FREF’;FREF MAPPINGS
 DC.W 0 ;NUMBER OF MAPPINGS-1
 DC.W 0,128 ;MAP 0 TO FREF 128

RESOURCE ‘FREF’ 128 ‘FREF 1’
 
 DC.B ‘APPL’, 0, 0, 0
 
.ALIGN 2
RESOURCE ‘ICN#’ 128 ‘MY ICON’

; FIRST APPLICATION ICON BIT MAP

INCLUDE LOGO.ICON.ASM

; MENU BAR RESOURCES

.ALIGN 2
RESOURCE ‘MENU’ 1 ‘apple menu’

 DC.W 1 ;MENU  ID
 DC.W 0 ;WIDTH HOLDER
 DC.W 0 ;HEIGHT HOLDER
 DC.L 0 ;RESOURCE ID HOLDER FOR STD. MENU 
 DC.L $1FF  ;ENABLE ALL ITEMS
 DC.B 1 ;TITLE LENGTH
 DC.B 20; APPLE SYMBOL
 
 DC.B 21;MENU ITEM LENGTH
 DC.B  ‘ABOUT THIS PROGRAM...’
 DC.B 0 ; NO ICON
 DC.B 0 ; NO KEYBOARD EQUIVALENT
 DC.B 0 ; MARKING CHARACTER
 DC.B 0 ; STYLE OF ITEM’S TEXT
 DC.B 0 ; END OF MENU ITEM
 
.ALIGN 2
RESOURCE ‘MENU’ 2 ‘file menu’

 DC.W 2 ;MENU  ID
 DC.W 0 ;WIDTH HOLDER
 DC.W 0 ;HEIGHT HOLDER
 DC.L 0 ;RESOURCE ID HOLDER 
 DC.L 3 ;ENABLE ALL ITEMS
 DC.B 4 ; TITLE LENGTH
 DC.B ‘File’; file menu 
 
 DC.B 6 ;MENU ITEM LENGTH
 DC.B  ‘Quit/Q’
 DC.B 0 ; NO ICON
 DC.B 0  NO KEYBOARD EQUIVALENT
 DC.B 0 ; NO MARKING CHARACTER
 DC.B 0 ; STYLE OF ITEM’S TEXT
 DC.B 0 ; END OF MENU ITEM
 
.ALIGN 2
RESOURCE ‘MENU’ 3 ‘edit menu’

 DC.W 3 ;MENU  ID
 DC.W 0 ;WIDTH HOLDER
 DC.W 0 ;HEIGHT HOLDER
 DC.L 0 ;RESOURCE ID HOLDER
 DC.L $7B ;ENABLE ALL ITEMS except 2
 DC.B 4 ; TITLE LENGTH
 DC.B ‘Edit’; edit menu 
 
 DC.B 6 ;MENU ITEM LENGTH
 DC.B  ‘Undo/Z’
 DC.B 0 ; NO ICON
 DC.B 0 ; NO KEYBOARD EQUIVALENT
 DC.B 0 ; NO MARKING CHARACTER
 DC.B 0 ; STYLE OF ITEM’S TEXT
 DC.B 9 ;MENU ITEM LENGTH
 DC.B  ‘--------’
 DC.B 0 ; NO ICON
 DC.B 0 ; NO KEYBOARD EQUIVALENT
 DC.B 0 ; NO MARKING CHARACTER
 DC.B 0 ; STYLE OF ITEM’S TEXT
 
 DC.B 5 ;MENU ITEM LENGTH
 DC.B  ‘Cut/X’
 DC.B 0 ; NO ICON
 DC.B 0 ; NO KEYBOARD EQUIVALENT
 DC.B 0 ; NO MARKING CHARACTER
 DC.B 0 ; STYLE OF ITEM’S TEXT
 
 DC.B 6 ;MENU ITEM LENGTH
 DC.B  ‘Copy/C’
 DC.B 0 ; NO ICON
 DC.B 0 ; NO KEYBOARD EQUIVALENT
 DC.B 0 ; NO MARKING CHARACTER
 DC.B 0 ; STYLE OF ITEM’S TEXT
 
 DC.B 7 ;MENU ITEM LENGTH
 DC.B  ‘Paste/V’
 DC.B 0 ; NO ICON
 DC.B 0 ; NO KEYBOARD EQUIVALENT
 DC.B 0 ; NO MARKING CHARACTER
 DC.B 0 ; STYLE OF ITEM’S TEXT
 
 DC.B 5 ;MENU ITEM LENGTH
 DC.B  ‘Clear’
 DC.B 0 ; NO ICON
 DC.B 0 ; NO KEYBOARD EQUIVALENT
 DC.B 0 ; NO MARKING CHARACTER
 DC.B 0 ; STYLE OF ITEM’S TEXT
 
 DC.B 0 ; END OF MENU ITEMS
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Capture One 15.3.1 - RAW workflow softwa...
Capture One is a professional RAW converter offering you ultimate image quality with accurate colors and incredible detail from more than 400 high-end cameras - straight out of the box. It offers... Read more
Connect Fonts 23.0.3 - Font management s...
Connect Fonts is the creative professional's font manager. Every professional font manager should deliver the basics: spectacular previews, powerful search tools, and efficient font organization. You... Read more
CleanMyMac X 4.11.0 - Delete files that...
CleanMyMac X makes space for the things you love. Sporting a range of ingenious new features, CleanMyMac lets you safely and intelligently scan and clean your entire system, delete large, unused... Read more
Firefox 102.0 - Fast, safe Web browser.
Firefox offers a fast, safe Web browsing experience. Browse quickly, securely, and effortlessly. With its industry-leading features, Firefox is the choice of Web development professionals and casual... Read more
Hopper Disassembler 5.6.1 - Binary disas...
Hopper Disassembler is a binary disassembler, decompiler, and debugger for 32- and 64-bit executables. It will let you disassemble any binary you want, and provide you all the information about its... Read more
Skim 1.6.11 - PDF reader and note-taker...
Skim is a PDF reader and note-taker for OS X. It is designed to help you read and annotate scientific papers in PDF, but is also great for viewing any PDF file. Skim includes many features and has a... Read more
Alfred 4.6.7 - Quick launcher for apps a...
Alfred is an award-winning productivity application for OS X. Alfred saves you time when you search for files online or on your Mac. Be more productive with hotkeys, keywords, and file actions at... Read more
Transmit 5.8.7 - Excellent FTP/SFTP clie...
Transmit is an excellent FTP (file transfer protocol), SFTP, S3 (Amazon.com file hosting) and iDisk/WebDAV client that allows you to upload, download, and delete files over the internet. With the... Read more
Adobe Lightroom Classic 11.4.1 - Import,...
You can download Lightroom for Mac as a part of Creative Cloud for only $9.99/month with Photoshop, included as part of the photography package. The latest version of Lightroom gives you all of the... Read more
MarsEdit 4.5.9 - Quick and convenient bl...
MarsEdit is a blog editor for OS X that makes editing your blog like writing email, with spell-checking, drafts, multiple windows, and even AppleScript support. It works with with most blog services... Read more

Latest Forum Discussions

See All

Apple Arcade Weekly Round-Up: Major Upda...
Apple recently revealed July’s upcoming Apple Arcade releases in a new App Store Story, and this week’s new release is My Bowling 3D+ featuring offline and online multiplayer support, and more. It arrives from the developers of Pro Darts 2022+ and... | Read more »
Downhill Mountain Biking Game ‘Descender...
Just over three years ago in May of 2019 developer RageSquid and publisher No More Robots released a quirky downhill mountain biking game called Descenders on PC and Xbox One. Bemoaning a lack of “extreme sports" titles in recent years led RageSquid... | Read more »
SwitchArcade Round-Up: ‘Monster Hunter R...
Hello gentle readers, and welcome to the SwitchArcade Round-Up for June 30th, 2022. Thursday is once more upon us, and that means a bunch of new releases to look at. We start things off with DLC for some very big games, Monster Hunter Rise and... | Read more »
‘HOOK 2’ Review – A Sharp Left Hook From...
The original HOOK ($1.99) had a very simple idea behind it. You were presented with a tangled mess of hooks and loops, and you needed to remove each one without snagging any others. Extremely simple at first, but as the puzzles rolled along,... | Read more »
‘Dicey Dungeons’ Mobile Version Launchin...
After a very long wait, Terry Cavanagh’s dungeon crawling roguelite deckbuiler hybrid experience Dicey Dungeons is coming to mobile platforms next week alongside a huge free DLC pack on all platforms. This DLC will be included in the mobile... | Read more »
Distract Yourself With These Great Mobil...
Every day, we pick out a curated list of the best mobile discounts on the App Store and post them here. This list won't be comprehensive, but it every game on it is recommended. Feel free to check out the coverage we did on them in the links below... | Read more »
‘Danganronpa S: Ultimate Summer Camp’ is...
If you’ve been following Danganronp over the last few years, Spike Chunsoft celebrated its anniversary by bringing the series to mobile in the form of anniversary editions. After the first two released, there was a long delay for V3, but it finally... | Read more »
Out Now: ‘HOOK 2’, ‘Incoherence’, ‘Juras...
Each and every day new mobile games are hitting the App Store, and so each week we put together a big old list of all the best new releases of the past seven days. Back in the day the App Store would showcase the same games for a week, and then... | Read more »
Upcoming Mobile MMO RPG Shooter ‘Avatar:...
This past January a contingent of developers made up of Archosaur Games, Tencent, Lightstorm Entertainment, and Disney announced a new mobile game set in James Cameron’s Avatar universe titled Avatar: Reckoning. | Read more »
Culinary Platformer ‘Chefy-Chef’ Coming...
If your name is Chefy, it’s pretty much a given that you should be a chef. Such is the case with Chefy-Chef, a game from Bug Studio about a chef named Chefy who must travel to all sorts of exotic locations using a magical refrigerator in an effort... | Read more »

Price Scanner via MacPrices.net

July 4th sale at Verizon: Apple AirPods Pro f...
Verizon has Apple AirPods Pro on sale for $179.99 on their online store as part of their Fourth of July sale. Their price is $70 (28%) off Apple’s MSRP, and it’s among the lowest prices currently... Read more
Apple is now selling Certified Refurbished Ma...
Apple has added a full line of standard-configuration Mac Studios available in their Certified Refurbished section starting at only $1799 and ranging up to $400 off MSRP. Each Mac Studio comes with... Read more
Open-box 14″ M1 Pro MacBook Pros in stock tod...
QuickShip Electronics has open-box return Space Gray 14″ M1 Pro MacBook Pros in stock and on sale for $300-$450 off MSRP on their eBay store today. According to QuickShip, “The item in this listing... Read more
Can Being An iPhone User Really Determine Whe...
FEATURE: – If you’re traveling on the road today for the July 4th holiday, you might want to keep your Apple smartphone locked up inside the car’s glove compartment for your (and, everyone else’s)... Read more
2nd generation 4K Apple TVs with Siri remote...
Apple has restocked a full line of Certified Refurbished 2nd generation 32GB and 64GB 4K Apple TVs with Siri remotes for $30 off the cost of new models. Apple’s standard one-year warranty is included... Read more
Back in stock: Apple Watch Series 7 models fo...
Apple has restocked Certified Refurbished Apple Watch Series 7 WiFi-only models in their online store for $60-$70 off MSRP, starting at $339. Each Watch includes Apple’s standard one-year warranty, a... Read more
July 4th Sale at Expercom: $200 off any 16″ M...
Apple reseller Expercom has 16″ M1 Pro and M1 Max MacBook Pros available for $200 off MSRP as part of their July 4th sale. In addition to their MacBook Pro sale prices, take $50 off AppleCare+ when... Read more
10.2″ Apple iPads (WiFi models) are on sale f...
Amazon has Apple’s 9th generation 10.2″ WiFi iPads on sale for up to $20-$50 off MSRP for a limited time. Their prices are the lowest price currently available for one of these iPads. All models are... Read more
10-Core M1 Pro 14″ MacBook Pros on sale for $...
B&H Photo is offering $200 discounts on Apple’s new 14″ M1 Pro MacBook Pros with 10-Core CPUs (16GB RAM/1TB SSDs). Free 1-2 day shipping is available to most US addresses, and both models are in... Read more
B&H has 16-inch M1 Pro MacBook Pros in st...
New Space Gray 16″ MacBook Pros with Apple’s M1 Pro CPUs are in stock and on sale today at B&H Photo for $200 off Apple’s MSRP. Sale prices are for M1 Pro models with 512GB or 1TB of SSD storage... Read more

Jobs Board

VP, Software Engineering - *Apple* and Andr...
…Client Application Software Engineering team is seeking a VP, Software Engineering for Apple and Android. You will lead the client engineering team building Disney+, Read more
I/S Senior Engineer - *Apple* Systems Engin...
**19647BR** **Position Title:** I/S Senior Engineer - Apple Systems Engineering - Remote **Department:** Information Systems **Location:** Lakeland, FL between Read more
*Apple* IT Support Analyst - 2nd Shift - Zon...
Apple IT Support Analyst - 2nd Shift Professional Services Albany, New York Malta, New York Clifton Park, New York Menands, New York Syracuse, New York Watertown, Read more
Infotainment Certification Test Engineer (XC)...
…integration - CarPlay, android auto, MirrorLink, Baidu Carlife, MFi/iPod certification testing; Apple PPID preparation, Google HUCD and GTM preparation + 3 years of Read more
Workplace Services *Apple* Device Managemen...
…3350 Riverwood Parkway Suite 900, Atlanta, GA, 30339 USA **Workplace Services Apple Device Management** **Role Overview** Carrier is seeking an experienced and Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.