Moving from Microsoft Office VBA to AppleScript:
MacTech's Guide to Making the Transition

Page Prev and Page Next buttons at bottom of the page.

April, 2007
Page 24

The canonic synonym, usually used in preference to the plural, is every [class name], which means the same thing. The usual For Each loop in VBA iterating through every member of a collection translates to a repeat loop in AppleScript, as explained in Chapter 2. (You get a choice between repeat with someObject in (every element) or repeat with i from 1 to (count every element).)

Unlink Fields

First, here is a simple VBA macro operating on the Fields Collection, with a simple translation to AppleScript via a repeat loop on a list:

For Each oField In ActiveDocument.Fields
    oField.Unlink
Next oField

becomes

tell application "Microsoft Word"

     set allFields to (every field of active document)

     repeat with oField in allFields

          unlink oField

     end repeat

end tell

That works. Here follows a small side-issue, which you can skip if you're not interested in the reasons why it can't be optimized further: It would be reasonable to hope that we could optimize this by using AppleScript's ability to have commands act on a whole list at once (see the last section of Chapter 2) and avoid the tedious repeat loop:

tell application "Microsoft Word"

     unlink (every field of active document)

end tell

…but having a command act on a list does not always work: the application developers need to have implemented it. In this case it does not work: you get an error, even when using the explicit get or a variable, that "{field 1 of active document, field 2 of active document, …} does not understand the unlink message." If you check the document, you'll see that the first field was in fact unlinked, but no others: it's just that the unlink command has not been implemented to work on lists. In most cases in Word, Excel and PowerPoint, unlike Entourage, that will be the case. The commands mostly mirror the VBA Methods from which they have been derived, which do not know anything about lists. It's too bad, but outside a few exceptions you might come upon, you'll have to use repeat loops.

In the repeat loop example above that does work, you first need to set a variable (allFields) and refer to that. If you instead try the following, without a variable, even with the explicit get:

     repeat with oField in (get every field of active document)

          unlink oField

     end repeat

you will get an error that some field "does not understand the unlink message". That's because the fields keep getting re-indexed as they get unlinked, skipping every second one, until the index is larger than the number of fields left. You‘d have to do it this way instead:

tell application "Microsoft Word"

     repeat with i from (count (get every field of active document)) to 1 by -1

          set oField to item i of (get every field of active document)

          unlink oField

     end repeat

end tell